Attribute VB_Name = "CBpnFile"
Private Declare Function GetPrivateProfileInt Lib "kernel32" Alias "GetPrivateProfileIntA" (ByVal lpApplicationName As String, ByVal lpKeyName As String, ByVal nDefault As Long, ByVal lpFileName As String) As Long
Private Declare Function GetPrivateProfileString Lib "kernel32" Alias "GetPrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpDefault As String, ByVal lpReturnedString As String, ByVal nSize As Long, ByVal lpFileName As String) As Long
Private Declare Function WritePrivateProfileString Lib "kernel32" Alias "WritePrivateProfileStringA" (ByVal lpApplicationName As String, ByVal lpKeyName As Any, ByVal lpString As Any, ByVal lpFileName As String) As Long

Public ErrorMsg As String
'網絡模型文件名(包括文件路徑)
Public BpnFileName As String
'網絡模型文件名
Public FileName As String
'網絡模型文件名（不含擴展名）
Public FilePre As String
'網絡訓練輸入文件
Public InTrainFile As String
'網絡訓練輸出文件
Public OutTrainFile As String
'網絡仿真輸入文件
Public InSimuFile As String
'網絡仿真輸出文件
Public OutSimuFile As String
'當前文件
Public CurFileName As String

'對屬性進行初始化
Public Function Class_Initialize()
  BpnFileName = vbNullString
  FileName = vbNullString
  FilePre = vbNullString
  InTrainFile = vbNullString
  OutTrainFile = vbNullString
  InSimuFile = vbNullString
  OutSimuFile = vbNullString
  CurFileName = vbNullString
  ErrorMsg = vbNullString
End Function

'指定 BPN 文件名給 CIniFile
Public Sub SpecifyBpn(FilePathName)
  BpnFileName = Trim(FilePathName)
End Sub

'判斷是否已經指定了 BPN 文件名
Private Function NoBpnFile() As Boolean
  NoBpnFile = True
  If BpnFileName = vbNullString Then
     ErrorMsg = "沒有指定 BPN 文件"
     Exit Function
  End If
  ErrorMsg = vbNullString
  NoBpnFile = False
End Function

Public Function WriteString(Section As String, key As String, Value As String) As Boolean
  WriteString = False
  If NoBpnFile() Then
     Exit Function
  End If
  If WritePrivateProfileString(Section, key, Value, BpnFileName) = 0 Then
     ErrorMsg = "寫入失敗"
     Exit Function
  End If
  WriteString = True
End Function

Public Function ReadString(Section As String, key As String, Size As Long) As String
  Dim ReturnStr As String
  Dim ReturnLng As Long
  ReadString = vbNullString
  If NoBpnFile() Then
     Exit Function
  End If
  ReturnStr = Space(Size)
  ReturnLng = GetPrivateProfileString(Section, key, vbNullString, ReturnStr, Size, BpnFileName)
  ReadString = Left(ReturnStr, ReturnLng)
End Function

Public Function ReadInt(Section As String, key As String) As Long
  Dim ReturnLng As Long
  ReadInt = 0
  ReturnLng = GetPrivateProfileInt(Section, key, 0, BpnFileName)
  If ReturnLng = 0 Then
     ReturnLng = GetPrivateProfileInt(Section, key, 1, BpnFileName)
     If ReturnLng = 1 Then
        ErrorMsg = "不能讀取"
        Exit Function
     End If
  End If
  ReadInt = ReturnLng
End Function