package org.kingda.book.event
{
	import flash.display.Sprite;
	import flash.events.MouseEvent;

	public class SampleEventFlow extends Sprite
	{
		public function SampleEventFlow() {
			var outter:Sprite = new RectContainer(10,10, 200, 200);
			var middle:Sprite = new RectContainer(30,30, 150, 150);
			var inner:Sprite = new RectContainer(50,50, 100, 100);
			outter.name = "外層容器";
			middle.name = "中層容器";
			inner.name  = "內層容器";
			
			addChild(outter);
			outter.addChild(middle);
			middle.addChild(inner);
			
			inner	.addEventListener(MouseEvent.CLICK, clickHandler);
			middle	.addEventListener(MouseEvent.CLICK, clickHandler);
			//讀者可以將下句注釋去掉，看看middle如何偵聽捕獲階段的事件
			//middle	.addEventListener(MouseEvent.CLICK, clickHandler, true);
			outter	.addEventListener(MouseEvent.CLICK, clickHandler);
		}
		private function clickHandler(evt:MouseEvent):void {
			trace ("事件發生目標：\t" + evt.target.name);
			trace ("正在偵聽事件的當前目標：" + evt.currentTarget.name);
			trace ("事件當前階段：\t" + evt.eventPhase);
			trace ("====================================");
		}
	}
}
import flash.display.Sprite;	
class RectContainer extends Sprite {
	public function RectContainer(x:Number, y:Number, w:Number, h:Number) {
		this.graphics.beginFill(0xFFFFFF*Math.random());
		this.graphics.drawRect(x,y,w,h);
		this.graphics.endFill();
	}
}