?package org.kingda.book.xml
{
	import flash.display.Sprite;

	public class SampleXMLNamespace extends Sprite
	{
		private var enNS:Namespace;
		private var cnNS:Namespace;
		public function SampleXMLNamespace() {
			var dataXML:XML = getData();
			trace("=======");
			
			default xml namespace = cnNS;
			trace (dataXML.data.book);
			/*輸出：
			AS3殿堂之路
			*/
			trace ("+++" + dataXML.enNS::data.enNS::book);
			/*輸出：
			AS3's road
			*/
			trace (dataXML.namespace("en"));
			//輸出：http://books.kingda.org/en/
			trace (dataXML.namespace("cn"));
			//輸出：http://books.kingda.org/cn/
		}
		
		private function getData():XML {
			var originXML:XML = <data>
									<book>AS3殿堂之路</book>
									<site>www.kingda.org</site>
								</data>
			var copyCN:XML = originXML.copy();
			cnNS = new Namespace("cn", "http://books.kingda.org/cn/");
			copyCN.setNamespace(cnNS);
			for each (var i:XML in copyCN.elements()) {
				i.setNamespace(cnNS);
			}
						
			trace (copyCN);
			/*輸出：
			<cn:data xmlns:cn="http://books.kingda.org/cn/">
			  <cn:book>AS3殿堂之路</cn:book>
			  <cn:site>www.kingda.org</cn:site>
			</cn:data>
			*/
			
			var copyEN:XML = originXML.copy();
			enNS = new Namespace("en", "http://books.kingda.org/en/");
			copyEN.setNamespace(enNS);
			copyEN.book = "AS3's road";
			for each (var j:XML in copyEN.elements()) {
				j.setNamespace(enNS);
			}
						
			var bookXML:XML = <books/>;
			bookXML.appendChild(copyCN);
			bookXML.appendChild(copyEN);
			bookXML.addNamespace(enNS);
			bookXML.addNamespace(cnNS);			
			trace (bookXML);
			/*輸出：
			<books xmlns:en="http://books.kingda.org/en/" xmlns:cn="http://books.kingda.org/cn/" xmlns="null">
			  <cn:data>
			    <cn:book>AS3殿堂之路</cn:book>
			    <cn:site>www.kingda.org</cn:site>
			  </cn:data>
			  <en:data>
			    <en:book>AS3's road</en:book>
			    <en:site>www.kingda.org</en:site>
			  </en:data>
			</books>
			*/
				
			return bookXML;
		}
	}
}