?//*****************************PSSSlideShow**************************
import pssclasses.SlideShow.*;
//*************************class PlayMenu*****************
//import ColoRDespatcher
import pssclasses.*;
// import interface
import pssclasses.playmenu.interfaces.*;
// package classes
import pssclasses.playmenu.*;
//***********************************define class************************************
class BasisMenuAction extends MovieClip implements Interface_Basic {
	//******************define variables******************
	private var __this:MovieClip;
	// leftMenu
	private var LeftMenu:MovieClip;
	private var BROWSER:MovieClip;
	private var BigPHolder:MovieClip;
	private var BigPhotoPlace:MovieClip;
	private var ScrollPanelBG:MovieClip;
	// movie inside with label
	private var playBut_mc:MovieClip;
	private var playLabel_mc:MovieClip;
	private var playLabelHolder_mc:MovieClip;
	private var preloader:MovieClip;
	// photos and albums
	private var photosArray:Array;
	private var albumDataArray:Array;
	private var partIndex:Number = -1;
	private var albumIndex:Number = -1;
	private var photoIndex:Number = 0;
	private var partID:Number;
	private var albumID:Number;
	private var albumsCount:Number;
	private var partDataArray:Array;
	private var partsCount:Number;
	private var SHOWING:Array = ["PART", "ALBUM", "PHOTOS", "SLIDESHOW"];
	private var SelectPressed:Boolean = true;
	private var CurentIndex:Number = 0;
	private var MinAlbumLimits:Boolean = true;
	private var MaxAlbumLimits:Boolean = true;
	private var prevPhotoGo:Boolean = true;
	private var nextPhotoGo:Boolean = true;
	private var photosCount:Number;
	// hint
	private var bPlayHint:String;
	private var bNextHint:String;
	private var bPrevHint:String;
	// color attributes
	private var alphaOffset:Number = 10;
	private var activColor:Number = 0xFF6600;
	private var activColorAlpha:Number = 255;
	//******************define metods*********************
	private function BasisMenuAction() {
		__this = this;
		BROWSER = __this._parent._parent;
		if (_global.ActivColor) {
			activColor = _global.ActivColor;
		}
		// label movie inside play button     
		playLabel_mc = playBut_mc.playLabel_mc;
		playLabelHolder_mc = playBut_mc.playLabelHolder_mc;
	}
	// ************************setToActiv*****************************
	public function setToActiv(colorActivMC:MovieClip, activity:Number):Void {
		var activeMC:MovieClip = colorActivMC;
		var alphaStep:Number = alphaOffset;
		//make activity
		activeMC.onEnterFrame = function() {
			activeMC._alpha += alphaStep;
			if (activeMC._alpha>=activity) {
				activeMC._alpha = activity;
				//clearInterval(intervalIndex);
				delete activeMC.onEnterFrame;
			}
		};
	}
	// **********************setToPacive**********************************
	public function setToPacive(colorActivMC:MovieClip, passivity:Number):Void {
		var activeMC:MovieClip = colorActivMC;
		var alphaStep:Number = alphaOffset;
		//make passivity
		activeMC.onEnterFrame = function() {
			activeMC._alpha -= alphaStep;
			if (activeMC._alpha<=passivity) {
				activeMC._alpha = passivity;
				delete activeMC.onEnterFrame;
			}
		};
	}
	// **************************set color for activ movie***************************************
	private function setActiveColor(__mc:MovieClip, newcolor:Number, newalpha:Number):Void {
		ColorDispatcher.setColorAndAlpha(__mc, newcolor, newalpha);
	}
	//*****************************show and hide preloader**********************
	public function showPreloader():Void {
		// label movie inside play button
		playLabel_mc._visible = false;
		preloader = playLabelHolder_mc.attachMovie("preloaderLitle", "preloaderLitle", 0);
	}
	public function setProgressLoadig(bytesT:Number, bytesL:Number):Void {
		preloader.setProgressLoadig(bytesT, bytesL);
	}
	public function hidePreloader():Void {
		// label movie inside play button
		playLabel_mc._visible = true;
		preloader.removeMovieClip();
	}
	//*******************************ALBUM AND PHOTO DATA  FROM PSSContentControler class**************************************
	public function setPartsDataArray(partDataArr:Array, AlbumDataArray:Array):Void {
		albumDataArray = AlbumDataArray;
		/*
		photoData.index
		photoData.id
		photoData.name
		photoData.mheight
		photoData.mwidth
		photoData.p_id
		 this.photoData.p_id
		 this.photoData.p_index
		 */
		partDataArray = partDataArr;
		partsCount = partDataArr.length;
		// hide preloader
		hidePreloader();
	}
	public function setPartIndex(pindex:Number):Void {
		if (pindex != undefined) {
			partIndex = pindex;
		}
		albumsCount = albumDataArray[partIndex].length;
		// set showing is PART
		CurentIndex = 0;
		MinAlbumLimits = true;
		MaxAlbumLimits = true;
		// hide preloader
		hidePreloader();
	}
	public function setPhotosArray(photosArr:Array):Void {
		photosArray = photosArr;
		photosCount = photosArray.length;
		// set photo index in 0 
		setPhotoIndex(0, true);
	}
	public function setPhotoIndex(photoInd:Number, setZero:Boolean):Void {
		photoIndex = photoInd;
		if (photoIndex == 0) {
			prevPhotoGo = false;
			nextPhotoGo = true;
		} else if (photoIndex == photosCount-1) {
			prevPhotoGo = true;
			nextPhotoGo = false;
		} else {
			prevPhotoGo = true;
			nextPhotoGo = true;
		}
	}
	// link  BigPhotoHolder class from PhotoBuilder class
	public function setBigPhotoHolder(BigPH:MovieClip, bigPhotoPlace:MovieClip, scrollPanelBG:MovieClip):Void {
		BigPHolder = BigPH;
		BigPhotoPlace = bigPhotoPlace;
		ScrollPanelBG = scrollPanelBG;
		// showing is PART
		CurentIndex = 2;
	}
	public function setLeftMenu(leftMenu:MovieClip):Void {
		LeftMenu = leftMenu;
	}
	public function setAlbumData(pID:Number, aID:Number):Void {
		// set showing is ALBUM
		CurentIndex = 1;
		partID = pID;
		albumID = aID;
	}
	public function setAlbumIndex(aIndex:Number):Void {
		if (aIndex != undefined) {
			albumIndex = aIndex;
		}
		// set showing is ALBUM         
		CurentIndex = 1;
	}
	//********************OPEN BIG PHOTO***********************
	private function firstOpenBigPhoto():Void {
		// blok reBuild albums
		LeftMenu.setShowingSwitch("PHOTO");
		//*******************for photo dop menu***********************
		var BrowserContentHolder:MovieClip = BROWSER.content_mc;
		var scrollPanelBG:MovieClip = BrowserContentHolder.scrollContentPane_mc.BGArea_mc;
		var photoDopMenu:MovieClip = __this._parent.photoMenu_mc;
		photoDopMenu.setToActiv();
		photoDopMenu.setAlbumData(partID, albumID);
		photoDopMenu.setPhotoData(photosArray[photoIndex]);
		//*******end*******for photo dop menu***********************
		var contentHolder:MovieClip = BrowserContentHolder.scrollContentPane_mc.PaneContent_mc;
		// attach big photo holder
		BigPHolder = contentHolder.attachMovie("bigPhotoholder", "bigPhotoholder", 0);
		BigPHolder.setPhotoData(photosArray[photoIndex]);
		LeftMenu.setBigPhotoHolder(BigPHolder);
		// take photos array 
		BigPHolder.setPhotosArray(photosArray);
		// add link on BigPholder to play menu
		setBigPhotoHolder(BigPHolder, contentHolder, scrollPanelBG);
		// **********************set to dop photo menu data***********************
		photoDopMenu.setScrollPanelBG(scrollPanelBG, LeftMenu, BigPHolder);
	}
	//*********END ********OPEN BIG PHOTO***********************
	//*******************open part*********************
	private function openNextPart():Void {
		var partData:Object;
		// showing is PART
		CurentIndex = 0;
		//
		if (partIndex<partsCount-1) {
			partIndex++;
			partData = partDataArray[partIndex];
			LeftMenu.openSubPartMenu(partIndex);
			LeftMenu.openPartSubMenu(partIndex);
			// set  browser label
			BROWSER.setLabel = partData.name;
			SelectPressed = false;
		}
	}
	private function openPrevPart():Void {
		var partData:Object;
		// showing is PART
		CurentIndex = 0;
		//
		if (partIndex != 0 && partIndex>0) {
			partIndex--;
			partData = partDataArray[partIndex];
			LeftMenu.openSubPartMenu(partIndex);
			LeftMenu.openPartSubMenu(partIndex);
			// set  browser label
			BROWSER.setLabel = partData.name;
			SelectPressed = false;
		}
	}
	private function openNextAlbum():Void {
		var checkAlbumInd:Boolean = true;
		var albumData:Object;
		if (partIndex<0) {
			partIndex = 0;
		}
		albumsCount = albumDataArray[partIndex].length;
		if (albumIndex<albumsCount-1) {
			albumIndex++;
			albumData = albumDataArray[partIndex][albumIndex];
			LeftMenu.openSubPartMenu(partIndex);
			LeftMenu.openAlbum(albumData.p_id, albumData.id, albumIndex, partIndex);
			// set  browser label
			BROWSER.setLabel = albumData.p_name+" | "+albumData.name;
			checkAlbumInd = false;
		} else {
			checkAlbumInd = true;
		}
		if (albumIndex == albumsCount-1 && checkAlbumInd) {
			MaxAlbumLimits = false;
			CurentIndex = 0;
			albumIndex = -1;
			if (partIndex == partsCount-1) {
				partIndex--;
			}
		}
	}
	private function openPrevAlbum():Void {
		var albumData:Object;
		var checkAlbumInd:Boolean = true;
		albumsCount = albumDataArray[partIndex].length;
		if (albumIndex != 0) {
			albumIndex--;
			albumData = albumDataArray[partIndex][albumIndex];
			LeftMenu.openSubPartMenu(partIndex);
			LeftMenu.openAlbum(albumData.p_id, albumData.id, albumIndex, partIndex);
			// set  browser label
			BROWSER.setLabel = albumData.p_name+" | "+albumData.name;
			checkAlbumInd = false;
		} else {
			checkAlbumInd = true;
		}
		if (albumIndex == 0 && checkAlbumInd) {
			MinAlbumLimits = false;
			CurentIndex = 0;
			albumIndex = -1;
			partIndex++;
		}
	}
	//******************************next intro and prev intro*****************
	public function introAction():Void {
		var limitDown:Number = SHOWING.length;
		if (CurentIndex<SHOWING.length) {
			CurentIndex++;
		}
		if (SHOWING[CurentIndex] == "ALBUM") {
			albumIndex = -1;
			openNextAlbum();
		}
				if (SHOWING[CurentIndex] == "PHOTOS") {
			//firstOpenBigPhoto();
			PSSSlideShow.setPlace(BROWSER._parent);
			PSSSlideShow.startSlideShow(partIndex,albumIndex, photoIndex,partDataArray,albumDataArray,photosArray)
			CurentIndex--;
		}
		if (SHOWING[CurentIndex] == "SLIDESHOW") {
			PSSSlideShow.setPlace(BROWSER._parent);
			PSSSlideShow.startSlideShow(partIndex,albumIndex,photoIndex,partDataArray,albumDataArray,photosArray)
			CurentIndex--;
		}

	}
	private function nextIntroAction():Void {
		MinAlbumLimits = true;
		if (!MaxAlbumLimits) {
			// showing is PART
			CurentIndex = 0;
			albumIndex = -1;
		}
		if (SHOWING[CurentIndex] == "PHOTOS") {
			if (!nextPhotoGo) {
				// showing is PART
				CurentIndex = 0;
				partIndex--;
				albumIndex = -1;
			}
			if (nextPhotoGo) {
				nextPhotoGo = BigPHolder.nextPhoto();
				prevPhotoGo = true;
			}
		}
		if (SHOWING[CurentIndex] == "ALBUM") {
			openNextAlbum();
		}
		if (SHOWING[CurentIndex] == "PART") {
			openNextPart();
		}
	}
	private function prevIntroAction():Void {
		MaxAlbumLimits = true;
		if (!MinAlbumLimits) {
			// showing is PART
			CurentIndex = 0;
			albumIndex = -1;
		}
		if (SHOWING[CurentIndex] == "PHOTOS") {
			if (!prevPhotoGo) {
				// showing is PART
				CurentIndex = 0;
				partIndex++;
				albumIndex = -1;
			}
			if (prevPhotoGo) {
				prevPhotoGo = BigPHolder.prevPhoto();
				nextPhotoGo = true;
			}
		}
		if (SHOWING[CurentIndex] == "ALBUM") {
			openPrevAlbum();
		}
		if (SHOWING[CurentIndex] == "PART") {
			openPrevPart();
		}
	}
	//**************************update hint language***********************
	public function updateHintLang():Void {
		if (SHOWING[CurentIndex] == "PART") {
			//define  hint                                                             
			bPlayHint = _global.PSS_UI.lib_bplayalbum;
			bPrevHint = _global.PSS_UI.lib_bprevpart;
			bNextHint = _global.PSS_UI.lib_bnextpart;
		} else if (SHOWING[CurentIndex] == "ALBUM") {
			// hint
			//bPlayHint = _global.PSS_UI.lib_bphoto;
			bPlayHint = _global.PSS_UI.lib_play;
			bPrevHint = _global.PSS_UI.lib_bprevalbum;
			bNextHint = _global.PSS_UI.lib_bnextalbum;
		} else if (SHOWING[CurentIndex] == "PHOTOS") {
			bPlayHint = _global.PSS_UI.lib_play;
			bPrevHint = _global.PSS_UI.lib_bprevious;
			bNextHint = _global.PSS_UI.lib_bnext;
		}
	}
	//****end*******************update hint language***********************
	// ****************end class
}