;編程：在屏幕中間依次顯示“a”~“z”，并可以讓人看清。在顯示的過程中，按下'Esc'鍵后，改變顯示的顏色。

;完整功能代碼：

assume cs:code

stack segment
	db 128 dup (0)
stack ends

data segment
	dw 0,0
data ends

code segment
start:	mov ax,stack
	mov ss,ax
	mov sp,128
	mov ax,data
	mov ds,ax
	mov ax,0
	mov es,ax

	push es:[9*4]
	pop ds:[0]
	push es:[9*4+2]
	pop ds:[2]		;將原來的int 9中斷例程的入口地址保存在ds:0、ds:2單元中

	mov word ptr es:[9*4],offset int9
	mov es:[9*4+2],cs	;在中斷向量表中設(shè)置新的int 9中斷例程的入口地址

	mov ax,0b800h
	mov es,ax
	mov ah,'a'
    s:	mov  es:[160*12+40*2],ah
	call delay
	inc ah
	cmp ah,'z'
	jna s
	mov ax,0
	mov es,ax

	push ds:[0]
	pop es:[9*4]
	push ds;[2]
	pop es;[9*4+2]   	;將中斷向量表中int 9中斷例程的入口恢復(fù)為原來的地址

	mov ax,4c00h
	int 21h

delay:	push ax
	push dx
	mov dx,2000h
	mov ax,0
  s1: 	sub ax,1
	sbb dx,0
	cmp ax,0
	jne s1
	cmp dx,0
	jne s1
	pop dx
	pop ax
	ret

;------以下為新的int 9中斷例程--------------------

int9:	push ax
	push bx
	push es

	in al,60h

	pushf
	pushf
	pop bx
	and bh,11111100b
	push bx
	popf
	call dword ptr ds:[0] 	;對int指令進(jìn)行模擬，調(diào)用原來的int 9中斷例程

	cmp al,1
	jne int9ret

	mov ax,0b800h
	mov es,ax
	inc byte ptr es:[160*12+40*2+1]  ;屬性增加1，改變顏色

int9ret:pop es
	pop bx
	pop ax
	iret

code ends
end start