;********************************************************************************
;*  標題:  偉納電子ME300B單片機開發系統演示程序 - PC與ME300串行通迅程序         *
;*  文件:  wl013.asm                                                            *
;*  日期:  2005-1-20                                                            *
;*  版本:  1.0                                                                  *
;*  作者:  偉納電子 - Freeman                                                   *
;*  郵箱:  freeman@willar.com                                                   *
;*  網站： http://www.willar.com                                                *
;********************************************************************************
;*  描述:                                                                       *
;*         單片機接收主機的數據,然后將數據傳送到P0口, 并傳回給主機;             *
;*         當按下K1時, 單片機發送字串"welcome! www.willar.com\n\r" 給主機       * 
;*                                                                              *
;*  注意：演示此程序需要配合串口調試軟件,且串口調試軟件與ME300軟件不能同時打開。*
;*        串口調試軟件在光盤“工具軟件”目錄下有。                              *
;*                                                                              *
;*  實驗方法：先用ME300軟件將程序寫入單片機，關閉ME300軟件，將ME300的串口切換   *
;*            開關切換到仿真位置（這樣設置后計算機的串口才能與試驗芯片串口通信）*
;*            最后運行串口調試軟件即可實驗。                                    *
;*                                                                              *
;*********************************************************************************
;* 【版權】 Copyright(C)偉納電子 www.willar.com  All Rights Reserved            *
;* 【聲明】 此程序僅用于學習與參考，引用請注明版權和作者信息！                  *
;********************************************************************************

K1	EQU	P1.4			; 按鍵端口
; 變量定義
KEY_S	EQU	50H			; 當前的按鍵狀態			
KEY_V	EQU	51H			; 上次的按鍵狀態


	ORG	0000H
	LJMP	MAIN
	
MAIN:
	MOV	TMOD,#20H		; 定時器1工作于8位自動重載模式,用于產生波特率
	MOV	TH1,#0FDH
	MOV	TL1,#0FDH		; 波特率9600
	
	MOV	SCON,#50H		; 設定串行口工作方式
	ANL	PCON,#0EFH		; 波特率不倍增
	
	SETB	TR1			; 啟動定時器1
	MOV	IE,#0			; 禁止任何中斷

	MOV	KEY_V,#01H		; 
	
MAIN_RX:
	JNB	RI,MAIN_KEY		; 是否有數據到來
	CLR	RI
	MOV	A,SBUF			; 暫存接收到的數據
	MOV	P0,A			; 數據傳送到P0口
	LCALL	SEND_CHAR		; 回傳接收到的數據
	
MAIN_KEY:
	LCALL	SCAN_KEY		;  掃描按鍵
	JZ	MAIN_RX
	LCALL	DELAY_15MS		;  延時去抖動
	LCALL	SCAN_KEY
	JZ	MAIN_RX
	MOV	KEY_V,KEY_S		;  保存鍵值
	LCALL	PROC_KEY		; 鍵處理
	SJMP	MAIN_RX
;===============================================================================
SCAN_KEY:
; 掃描按鍵, (在此實例中僅掃描按鍵K1)	
; 傳入參數: 無
; 返回值:　無
	CLR	A
	MOV	C,K1
	MOV	ACC.0, C
	MOV	KEY_S,A
	XRL	A,KEY_V			; 檢查按鍵狀態是否改變
	RET
;===============================================================================	
PROC_KEY:
; 按鍵處理子程序 --- 發送字符串到PC
; 傳入參數: KEY_V --- 按鍵值
; 返回值: 無	
	JB	K1,END_PROC_KEY	; K1未按下時，直接返回
	MOV	DPTR,#TAB_WWW		; 字串表格地址

SEND_STRING:
	CLR	A
	MOVC	A,@A+DPTR
	JZ	END_PROC_KEY		; 查到00H時,表示字串結束
	ACALL	SEND_CHAR
	INC	DPTR			; 下一字符
	SJMP	SEND_STRING
END_PROC_KEY:
	RET	

;===============================================================================
SEND_CHAR:
; 傳送一個字符
; 傳入參數: ACC(要發送的數據)
; 返回值: 無
	MOV	SBUF,A
	JNB	TI,$			; 等特數據傳送
	CLR	TI			; 清除數據傳送標志
	RET
;===============================================================================
; 掃描按鍵, (在此實例中僅掃描按鍵K1)	
; 傳入參數: 無
; 返回值:　無
DELAY_15MS:
	MOV	R7,#15
DELAY15MS_1:
	MOV	R6,#0E8H
DELAY15MS_2:
	NOP
	NOP
	DJNZ	R6,DELAY15MS_2
	DJNZ	R7,DELAY15MS_1
	RET

	
TAB_WWW:
	DB	"welcome! www.willar.com"
	DB	0AH,0DH		;換行/回車
	DB	00H
	END