;********************MUBCDADD********************
;本程序實現多字節非壓縮BCD碼加法。
;入口參數: 被加數地址在SADR中,加數地址在DADR中,字節數在CNT中。
;出口參數: 結果首地址在SADR中,字節數在CNT中,進位在STATUS:C中。
;占用資源: W,STATUS,FSR,020H,022H,023H,028H,029H,02AH,一重堆棧。
;說    明: 被加數將被沖掉.     

           IFNDEF       MUBCDADD1

            #DEFINE     MUBCDADD1
MUBCDADD    CLRF        TEMP3       ;進位位清零
            MOVF        SADR,W
            MOVWF       TEMP2       ;保存結果首地址
NEXT2       MOVF        DADR,W
            MOVWF       FSR
            MOVF        INDF,W
            MOVWF       TEMP1       ;暫存加數
            MOVF        SADR,W
            MOVWF       FSR
            MOVF        TEMP1,W
            ADDWF       INDF,F
            BTFSS       STATUS,DC   ;檢查半進位
            GOTO        NODC2
            BTFSC       TEMP3,0     ;低位送來的進位
            INCF        INDF,F      ;此時不可能產生進位
            MOVLW       6           
            ADDWF       INDF,F      ;加6處理
OVER6       MOVLW       0FH
            ANDWF       INDF,F      ;去掉高四位
            BSF         TEMP3,0
            GOTO        DONE1
NODC2       BTFSS       TEMP3,0
            MOVLW       6
            BTFSC       TEMP3,0
            MOVLW       7
            ADDWF       INDF,F
            BTFSC       STATUS,DC   ;DC為1,表明原結果大于9
            GOTO        OVER6
            MOVLW       06H
            SUBWF       INDF,F
            BCF         TEMP3,0
DONE1       INCF        DADR,F
            INCF        SADR,F
            DECFSZ      CNT,F
            GOTO        NEXT2
            MOVF        TEMP2,W
            SUBWF       SADR,W
            MOVWF       CNT         ;恢復字節數
            MOVF        TEMP2,W
            MOVWF       SADR
            RRF         TEMP3,W     ;將進位位移到STATUS:C中
            RETLW       0
           ENDIF