* Figure 33.19 CMOS: Mixed-Signal Circuit Design *
* Using the BSIM4 model *
* Comparison between strong, moderate, and weak inversion *
* using an R-2R (W-2W) based current mirror (see text.) *

*#destroy all
*#run
*#rusage time

**#plot Vbias
*#let ID1=V1#branch*1-Vref#branch
*#let ID2=V2#branch*2-Vref#branch
*#let ID3=V3#branch*4-Vref#branch
*#let ID4=V4#branch*8-Vref#branch
*#let ID5=V5#branch*16-Vref#branch
*#let ID6=V6#branch*32-Vref#branch
*#let ID7=V7#branch*64-Vref#branch
*#let ID8=V8#branch*64-Vref#branch

**#plot ID1 ID2 ID3 ID4 ID5 ID6 ID7 ID8 xlabel Reference-current-uA 
*#let Itot=V2#branch+V3#branch+V4#branch+V5#branch+V6#branch+V7#branch+V8#branch
*#plot Itot vref#branch v1#branch xlog 

*#let Er=100/Vref#branch
*#let ID1ERR=ID1*Er
*#let ID2ERR=ID2*Er
*#let ID3ERR=ID3*Er
*#let ID4ERR=ID4*Er
*#let ID5ERR=ID5*Er
*#let ID6ERR=ID6*Er
*#let ID7ERR=ID7*Er
*#let ID8ERR=ID8*Er

*#plot ID1ERR ID2ERR ID3ERR ID4ERR ID5ERR ID6ERR ID7ERR ID8ERR xlog xlabel Reference-current-uA

*** Top Level Netlist ***
Mbias Vbias Vbias 0 0 NMOS L=5u W=20u 
IREF Vb Vbias DC 1u
VREF VDD Vb DC 0
VDD VDD 0 DC 1.5

V1 VDD VD1 DC 0
V2 VDD VD2 DC 0
V3 VDD VD3 DC 0
V4 VDD VD4 DC 0
V5 VDD VD5 DC 0
V6 VDD VD6 DC 0
V7 VDD VD7 DC 0 
V8 VDD VD8 DC 0

M1  VD1 Vbias 0 0 NMOS L=5u W=20u 
M2  VD2 Vbias VS2 0 NMOS L=5u W=20u
M22 VS2 Vbias 0 0 NMOS L=5u W=40u
M3  VD3 Vbias VS3 0 NMOS L=5u W=20u 
M33 VS3 Vbias VS2 0 NMOS L=5u W=40u
M4  VD4 Vbias VS4 0 NMOS L=5u W=20u
M44 VS4 Vbias VS3 0 NMOS L=5u W=40u
M5  VD5 Vbias VS5 0 NMOS L=5u W=20u 
M55 VS5 Vbias VS4 0 NMOS L=5u W=40u
M6  VD6 Vbias VS6 0 NMOS L=5u W=20u
M66 VS6 Vbias VS5 0 NMOS L=5u W=40u
M7  VD7 Vbias VS7 0 NMOS L=5u W=20u 
M77 VS7 Vbias VS6 0 NMOS L=5u W=40u
M8 VD8 Vbias VS7 0 NMOS L=5u W=20u

*** Control Statements ***
.option post
.DC IREF .1u 100u .05u
 
** BSIM4 MOSFET Model ** 
** Berkeley SPICE3f5 Compatible
** Lmin=0.12 Wmin=0.6 

.MODEL NMOS NMOS LEVEL=54 VERSION=4.0.0 TNOM=27
+ EPSROX=3.9 TOXE=3e-9 TOXP=3e-9 TOXM=3e-9 TOXREF=3e-9 DTOX=0

+ MOBMOD=0 RDSMOD=0 IGCMOD=1 IGBMOD=1 DIOMOD=1 CAPMOD=2
+ RGATEMOD=1 RBODYMOD=1 TRNQSMOD=0 ACNQSMOD=0 FNOIMOD=1
+ TNOIMOD=0 PERMOD=1 GEOMOD=1 PARAMCHK=1 BINUNIT=1

+ NDEP=1.7e17 NGATE=9e19 VTH0=0.42 PHIN=0 XJ=9e-8 NSD=1e20
+ VFB=-0.76 K1=0.33 K2=-1.87e-2 K3=80 K3b=0 W0=2.5e-6 KT1=-0.11
+ KT1L=0 KT2=2.2e-2 LPE0=5.75e-8 LPEB=2.3e-10 DVT0=2.89 DVT1=0.53
+ DVT2=-3.2e-2 DVT0W=0 DVT1W=0 DVT2W=0 DVTP0=7.32e-7 DVTP1=0.12
+ DSUB=0.058 ETA0=0.001 ETAB=0

+ CDSC=2.58e-4 CDSCD=6.1e-8 CDSCB=0 CIT=0 NFACTOR=1.1 VOFF=-0.02 VOFFL=0
+ MINV=0.05 VSAT=9.2e4 AT=3.3e4 U0=4.19e-2 UA=8.7e-16 UB=3.06e-18
+ UC=4.6e-13 UTE=-1.5 UA1=4.31e-9 UB1=7.61e-18 UC1=-5.6e-11
+ RDSW=369.4 RDW=184.7 RSW=184.7 PRWG=3.22e-8 PRWB=6.8e-11 WR=1
+ RDSWMIN=0 RDWMIN=0 RSWMIN=0 PRT=0 A0=1.1 AGS=1e-20 B0=-1e-20
+ B1=0 KETA=-0.047 A1=0 A2=1 DELTA=0.014 PVAG=1e-20 PCLM=6.28e-4
+ PDITS=0.2 PDITSL=2.3e6 PDITSD=0.23 FPROUT=0.2 PDIBLCB=3.4e-8
+ PDIBLC1=0.81 DROUT=0.56 PDIBLC2=9.84e-06 PSCBE1=8.14e8 PSCBE2=9.58e-07

+ LINT=5e-9 WINT=5e-9 DWG=0 DWB=0 WL=0 WW=0 WWL=0
+ WLN=1 WWN=1 LL=0 LW=0 LWL=0 LLN=1 LWN=1

+ XGW=3e-7 XGL=4e-8 NGCON=1 RSHG=0.4 XRCRG1=12 XRCRG2=5
+ DMCG=5e-6 DMCI=5e-6 DMDG=5e-6 DMCGT=6e-7 DWJ=4.5e-8 RSH=6
+ RBDB=15 RBPD=15 RBSB=15 RBPS=15 RBPB=5 GBMIN=1e-10

+ CGSO=7.43e-10 CGDO=7.43e-10 CGBO=2.56e-11 CGSL=1e-14 CGDL=1e-14
+ CKAPPAS=0.5 CKAPPAD=0.5 NOFF=0.9 VOFFCV=0.02 ACDE=1 MOIN=15 XPART=0

+ JSS=1e-4 JSWS=1e-11 JSWGS=1e-10 CJS=5e-4 CJSWS=5e-10 CJSWGS=3e-10
+ PBS=1 PBSWS=1 PBSWGS=1 NJS=1 XTIS=3 MJS=0.5 MJSWS=0.33 MJSWGS=0.33
+ XJBVS=1 BVS=10 IJTHSFWD=1e-2 IJTHSREV=1e-3

+ JSD=1e-4 JSWD=1e-11 JSWGD=1e-10 CJD=5e-4 CJSWD=5e-10 CJSWGD=5e-10
+ PBD=1 PBSWD=1 PBSWGD=1 NJD=1 XTID=3 MJD=0.5 MJSWD=0.33 MJSWGD=0.33
+ XJBVD=1 BVD=10 IJTHDFWD=1e-2 IJTHDREV=1e-3

+ TCJ=1e-3 TCJSW=1e-3 TCJSWG=1e-3 TPB=0.005 TPBSW=0.005 TPBSWG=0.005

+ ALPHA0=7.4e-2 ALPHA1=0.005 BETA0=30 AGIDL=2e-4 BGIDL=2.1e9 CGIDL=2e-4
+ EGIDL=0.8 AIGC=0.043 BIGC=0.0054 CIGC=0.0075 AIGSD=0.043 BIGSD=0.0054
+ CIGSD=0.0075 DLCIG=2.2e-8 AIGBACC=0.043 BIGBACC=0.0054 CIGBACC=0.0075
+ AIGBINV=0.35 BIGBINV=0.03 CIGBINV=0.006 NIGC=1 NIGBACC=1 NIGBINV=3
+ NTOX=1 EIGBINV=1.1 PIGCD=1.0 POXEDGE=1

.end