?? me500-密碼鎖－專用工具.asm
字號:
;在 LCD 第二行顯示字符
;A=ASC DATA, B=LINE X POS
;---------------------------------------------------
LCDP2: ;在LCD的第二行顯示字符
PUSH ACC ;
MOV A,B ;設置顯示地址
ADD A,#0C0H ;設置LCD的第二行地址
CALL WCOM ;寫入命令
POP ACC ;由堆棧取出A
CALL WDATA ;寫入數據
RET
;-------------------------------------------------------
;ASCII 轉換并顯示子程序
;-------------------------------------------------------
CONV:
MOV X,#9 ;設置顯示起始位置
MOV A,R3
ANL A,#0F0H ;取出高四位二進制數
SWAP A ;高四位與低四位互換
PUSH ACC ;壓入堆棧
CLR C ;C=0
SUBB A,#0AH ;減10
POP ACC ;彈出堆棧
JC ASCII0 ;該數小于10，轉ASCII0
ADD A,#07H ;大于10的數加上37H
ASCII0: ADD A,#30H ;小于10的數加上30H
MOV B,X
CALL LCDP2
MOV A,R3
ANL A,#0FH ;取出低四位二進制數
PUSH ACC
CLR C
SUBB A,#0AH ;減10
POP ACC
JC ASCII1 ;該數小于10，轉ASCII1
ADD A,#07H ;大于10的數加上37H
ASCII1: ADD A,#30H ;小于10的數加上30H
INC X
MOV B,X
CALL LCDP2
RET
;-----------------------------------------------------
DELAY2: MOV R5,#15H
DELAY: ;延時R5×10MS
MOV R6,#50
D1: MOV R7,#100
DJNZ R7,$
DJNZ R6,D1
DJNZ R5,DELAY
RET
;-----------------------------------------------------
DELAY1: ;延時5MS
MOV R6,#25
D2: MOV R7,#100
DJNZ R7,$
DJNZ R6,D2
RET
;------------------------------------------------------
;鍵掃描子程序
;------------------------------------------------------
SCAN_KEY:
SCAN_K: MOV P1,#0F0H
MOV A,P1
CJNE A,#0F0H,KEY_NUM0 ;有鍵按下轉
JMP KEY_END
KEY_NUM0: CALL KEY_IN
CALL BEEP_BL
MOV R5,#04H
CALL DELAY
KEY_END: RET
;-----------------------------------------------------
;反轉法詢鍵值子程序 （A）＝鍵值
;-----------------------------------------------------
KEY_IN: MOV P1,#0F0H ;置列線為0，行線為1
MOV A,P1
ANL A,#0F0H
MOV B,A
MOV P1,#0FH ;置列線為1，行線為0
MOV A,P1
ANL A,#0FH
ORL A,B ;高四位與低四位重新組合
CJNE A,#0FFH,KEY_IN1 ;0FFH為末按鍵
RET
KEY_IN1: MOV B,A
MOV DPTR,#KEYTABLE
MOV R3,#0FFH
KEY_IN2: INC R3
MOV A,R3
MOVC A,@A+DPTR
CJNE A,B,KEY_IN3
MOV A,R3 ;找到，取順序碼
RET
KEY_IN3: CJNE A,#0FFH,KEY_IN2 ;末完，繼續(xù)查
RET ;0FFH為結束碼
;-----------------------------------------------------
KEYTABLE:
DB 0EEH,0EDH,0EBH,0E7H,0DEH ;0,1,2,3,4, 順序碼
DB 0DDH,0DBH,0D7H,0BEH,0BDH ;5,6,7,8,9,
DB 0BBH,0B7H,07EH,07DH,07BH ;A,B,C,D,E,
DB 077H,0FFH ;F 0FF為結束碼
;-------------------------------------------------------
;=================================================
;寫串行E2PROM子程序
;(R1)=欲寫數據存放地址指針
;(R7)=連續(xù)讀字節(jié)數
;24CO1一次可連續(xù)寫8個字節(jié)，12個字節(jié)分兩次寫。
;=================================================
EEPW: PUSH ACC
PUSH PSW
CLR PSW.3
SETB PSW.4
MOV R1,#PASS_NEW
MOV R7,#06H ;連續(xù)寫6個字節(jié)
LCALL START
MOV A,#0A0H ;送器件地址
ACALL SUBS
MOV A,#00H ;送片內字節(jié)地址
ACALL SUBS
AGAIN1:
MOV A,@R1
ACALL SUBS ;調發(fā)送單字節(jié)子程序
INC R1
DJNZ R7,AGAIN1 ;連續(xù)寫6個字節(jié)
LCALL STOP ;發(fā)停止信號
POP PSW
POP ACC
RET
SUBS:
MOV R0,#08H ;發(fā)送單字節(jié)子程序
LOOP: CLR SCLK24
RLC A
MOV SDA,C
NOP
SETB SCLK24
ACALL DELAY24
DJNZ R0,LOOP ;循環(huán)8次送8個bit
CLR SCLK24
ACALL DELAY24
SETB SCLK24
REP: MOV C,SDA
JC REP ;判應答到否，未到則等待
CLR SCLK24
RET
DELAY24:
NOP
NOP
RET
;=========================================================
;讀串行E2PROM子程序EEPR
;(R1)=欲讀數據存放地址指針
;(R7)=連續(xù)讀字節(jié)數
;=========================================================
EEPR: PUSH ACC
PUSH PSW
CLR PSW.3
SETB PSW.4
MOV R7,#06H
MOV R1,#PASS_OLD
LCALL START ;發(fā)開始信號
MOV A,#0A0H ;送器件地址
ACALL SUBS ;調發(fā)送單字節(jié)子程序
MOV A,#00H ;送片內字節(jié)地址
ACALL SUBS
LCALL START ;再發(fā)開始信號
MOV A,#0A1H
ACALL SUBS
MORE: ACALL SUBR
MOV @R1,A
MOV A,#00H
INC R1
DJNZ R7,MORE
LCALL STOP ;送停止信號
POP PSW
POP ACC
RET
SUBR: MOV R0,#08H ;接受單字節(jié)子程序
LOOP2: SETB SCLK24
ACALL DELAY24
MOV C,SDA
RLC A
CLR SCLK24
ACALL DELAY24
DJNZ R0,LOOP2
CJNE R7,#01H,ALOW
SETB SDA ;若是最后一個字節(jié)置SDA=1
AJMP SETOK
ALOW:
CLR SDA ;否則置SDA=0
SETOK: ACALL DELAY24
SETB SCLK24
ACALL DELAY24
CLR SCLK24
ACALL DELAY24
SETB SDA ;應答畢,SDA置1
RET
START:
CLR SDA
ACALL DELAY24
SETB SDA
SETB SCLK24
ACALL DELAY24
CLR SDA
SETB SCLK24
RET
STOP:
CLR SDA
SETB SCLK24
ACALL DELAY24
SETB SDA
ACALL DELAY24
RET
;===============================================
;蜂鳴器響一聲子程序
;===============================================
BEEP_BL:
MOV R6,#100
BL2: CALL DEX1
CPL BEEP
DJNZ R6,BL2
MOV R5,#15
CALL DELAY_BL
RET
DEX1: MOV R7,#180
DE2: NOP
DJNZ R7,DE2
RET
;-------------------------------------------
DELAY_BL: ;(R5)*延時10MS
MOV R6,#50
DL1: MOV R7,#100
DJNZ R7,$
DJNZ R6,DL1
DJNZ R5,DELAY_BL
RET
;-------------------------------------------
END
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -