?? st12864a-3.asm
字號:
;/********************************************************************************
;* 標(biāo)題: xl系列單片機實驗儀演示程序 矩陣鍵盤12864液晶顯示鍵值 (帶字庫） *
;* 文件: lcd128JZ.asm *
;* 日期: 2006-1-5 *
;* 版本: 3.0 （試驗通過版）可用xl600-xl1000單片機綜合試驗儀試驗 *
;* 作者: 部分程序參考網(wǎng)上修改而成，本站最終改編測試，特別對原作致敬！ *
;* 郵箱: sxj1974@163.com *
;* 網(wǎng)站： http://www.51c51.com www.8951.com *
;********************************************************************************
;* 描述: *
;* 矩陣鍵盤12864液晶顯示鍵值 (帶字庫） *
;* 矩陣鍵盤定義： *
;* 矩陣鍵盤P1口，P1.0-P1.3為列線,P1.4-P1.7為行線
;*
;* 喇叭接P3.7口， P0口接12864LCD的數(shù)據(jù)口。 *
;********************************************************************************
;* 【版權(quán)】 Copyright(C)深圳市學(xué)林電子有限公司 www.51c51.com *
;* 【聲明】 此程序僅用于學(xué)習(xí)與參考，引用請注明版權(quán)和作者信息！ *
;* 【技術(shù)支持】請訪問http://www.51c51.com/bbs/index.asp 官方論壇 *
;********************************************************************************/
X EQU 26H ;LCD 地址變量
BEEP EQU P3.7
RELAY EQU P1.3
RS EQU P2.0
RW EQU P2.1
EN EQU P2.2
PSB EQU P2.3
RST EQU P2.5
;==================================================
ORG 0000H
JMP MAIN
;==================================================
MAIN:
MOV SP,#40H
MOV A,#00H
MOV R0,#20H
LOOP0: MOV @R0,A ;20H-26H清零
INC R0
CJNE R0,#27H,LOOP0
SETB RST
NOP
SETB PSB ;8位數(shù)據(jù)，并口
CALL SET_LCD ;初始化TS12864A-3
CALL MENU1
CALL MENU2
CALL MENU3
CALL MENU4
LOOP1:
MOV P1,#0F0H
MOV A,P1
CJNE A,#0F0H,LOOP2 ;有鍵按下轉(zhuǎn)LOOP2
JMP LOOP1
LOOP2:
CALL KEY_IN
CALL KEY_CONV
CALL BEEP_BL
JMP LOOP1
;=============================================
; LCD 初始化設(shè)置
;=============================================-
SET_LCD:
CLR EN
MOV A,#34H ;34H--擴充指令操作
CALL WCOM
CALL DELAY1
MOV A,#30H ;30H--基本指令操作
CALL WCOM
CALL DELAY1
MOV A,#0CH ;開顯示，關(guān)光標(biāo)，
CALL WCOM
CALL DELAY1
MOV A,#01H ;清除 LCM 顯示屏
CALL WCOM
CALL DELAY1
RET
;===================================================
;在 LCM 各行顯示信息字符
;===================================================
LCD_SHOW:
CJNE A,#1,LINE2 ;判斷是否為第一行
LINE1: MOV A,#80H ;設(shè)置 LCD 的第一行地址
CALL WCOM ;寫入命令
CALL CLR_LINE ;清除該行字符數(shù)據(jù)
MOV A,#80H ;設(shè)置 LCD 的第一行地址
CALL WCOM ;寫入命令
JMP FILL
LINE2: CJNE A,#2,LINE3 ;判斷是否為第二行
MOV A,#090H ;設(shè)置 LCD 的第二行地址
CALL WCOM ;寫入命令
CALL CLR_LINE ;清除該行字符數(shù)據(jù)
MOV A,#090H ;設(shè)置 LCD 的第二行地址
CALL WCOM
JMP FILL
LINE3: CJNE A,#3,LINE4 ;判斷是否為第三行
MOV A,#088H ;設(shè)置 LCD 的第三行地址
CALL WCOM ;寫入命令
CALL CLR_LINE ;清除該行字符數(shù)據(jù)
MOV A,#088H ;設(shè)置 LCD 的第三行地址
CALL WCOM
JMP FILL
LINE4: CJNE A,#4,LINE5 ;判斷是否為第四行
MOV A,#098H ;設(shè)置 LCD 的第四行地址
CALL WCOM ;寫入命令
CALL CLR_LINE ;清除該行字符數(shù)據(jù)
MOV A,#098H ;設(shè)置 LCD 的第四行地址
CALL WCOM
FILL: CLR A ;填入字符
MOVC A,@A+DPTR ;由消息區(qū)取出字符
CJNE A,#0,LC1 ;判斷是否為結(jié)束碼
LINE5: RET
LC1: CALL WDATA ;寫入數(shù)據(jù)
INC DPTR ;指針加1
JMP FILL ;繼續(xù)填入字符
RET
;=================================================
;清除該行 LCM 的字符
;=================================================
CLR_LINE:
MOV R0,#16 ;
CL1: MOV A,#' '
CALL WDATA
DJNZ R0,CL1
RET
;==================================================
;LCM 顯示工作菜單信息
;==================================================
MENU1:
MOV DPTR,#MENU1A
MOV A,#1 ;在第一行顯示信息
CALL LCD_SHOW
RET
MENU1A: DB "學(xué)林電子有限公司",0
MENU2:
MOV DPTR,#MENU2A
MOV A,#2 ;在第二行顯示信息
CALL LCD_SHOW
RET
MENU2A: DB "矩陣鍵盤值讀取器",0
MENU3:
MOV DPTR,#MENU3A
MOV A,#3 ;在第三行顯示信息
CALL LCD_SHOW
RET
MENU3A: DB "鍵值編碼：- - H",0
MENU4:
MOV DPTR,#MENU4A
MOV A,#4 ;在第四行顯示信息
CALL LCD_SHOW
RET
MENU4A: DB " www.51c51.com ",0
;==============================================
; 寫指令使能子程序
;RS=L,RW=L,D0-D7=指令碼，E=高脈沖
;==============================================
WCOM:
MOV P0,A
CLR RS
CLR RW
SETB EN
CALL DELAY0
CLR EN
RET
;=============================================
;寫數(shù)據(jù)使能子程序
;RS=H,RW=L,D0-D7=數(shù)據(jù)，E=高脈沖
;=============================================
WDATA:
MOV P0,A
SETB RS
CLR RW
SETB EN
CALL DELAY0
CLR EN
RET
DELAY0: MOV R7,#250 ;延時500微秒
DJNZ R7,$
RET
;===============================================
;在 LCM 第三行、第四行顯示字符
;A=ASC DATA, B=LINE X POS
;===============================================
LCDP3: ;在LCD的第三行顯示字符
PUSH ACC ;
MOV A,B ;設(shè)置顯示地址
ADD A,#088H ;設(shè)置LCD的第三行地址
CALL WCOM ;寫入命令
POP ACC ;由堆棧取出A
CALL WDATA ;寫入數(shù)據(jù)
RET
;LCDP4: ;在LCD的第四行顯示字符
PUSH ACC ;
MOV A,B ;設(shè)置顯示地址
ADD A,#098H ;設(shè)置LCD的第四行地址
CALL WCOM ;寫入命令
POP ACC ;由堆棧取出A
CALL WDATA ;寫入數(shù)據(jù)
RET
;========================================================
;矩陣鍵盤鍵值讀取子程序
;(A)=鍵值
;========================================================
KEY_IN: MOV P1,#0F0H ;置列線為0，行線為1
MOV A,P1
ANL A,#0F0H
MOV B,A
MOV P1,#0FH ;置列線為1，行線為0
MOV A,P1
ANL A,#0FH
ORL A,B ;高四位與低四位重新組合
CJNE A,#0FFH,KEY_IN1 ;0FFH為末按鍵
RET
KEY_IN1: MOV B,A
MOV DPTR,#KEYTABLE
MOV R3,#0FFH
KEY_IN2: INC R3
MOV A,R3
MOVC A,@A+DPTR
CJNE A,B,KEY_IN3
MOV A,R3 ;找到，取順序碼
MOV R5,#08H ;延時
CALL DELAY
RET
KEY_IN3: CJNE A,#0FFH,KEY_IN2 ;末完，繼續(xù)查
RET ;0FFH為結(jié)束碼
;===============================================
;編碼轉(zhuǎn)換為 ASCII 碼并顯示
;===============================================
KEY_CONV:
MOV 22H,A
MOV X,#5 ;設(shè)置顯示起始位置
MOV A,22H
ANL A,#0F0H ;取出高四位二進(jìn)制數(shù)
SWAP A ;高四位與低四位互換
PUSH ACC ;壓入堆棧
CLR C ;C=0
SUBB A,#0AH ;減10
POP ACC ;彈出堆棧
JC ASCII0 ;該數(shù)小于10，轉(zhuǎn)ASCII0
ADD A,#07H ;大于10的數(shù)加上37H
ASCII0: ADD A,#30H ;小于10的數(shù)加上30H
MOV B,X
CALL LCDP3
MOV A,22H
ANL A,#0FH ;取出低四位二進(jìn)制數(shù)
PUSH ACC
CLR C
SUBB A,#0AH ;減10
POP ACC
JC ASCII1 ;該數(shù)小于10，轉(zhuǎn)ASCII0
ADD A,#07H ;大于10的數(shù)加上37H
ASCII1: ADD A,#30H ;小于10的數(shù)加上30H
INC X
MOV B,X
CALL LCDP3
RET
;===================================================
;蜂鳴器響一聲子程序
;===================================================
BEEP_BL:
MOV R6,#100
BL1: CALL DEX1
CPL BEEP
DJNZ R6,BL1
MOV R5,#25
CALL DELAY
RET
DEX1: MOV R7,#180
DEX2: NOP
DJNZ R7,DEX2
RET
DELAY: ;延時R5×10MS
MOV R6,#50
D1: MOV R7,#100
DJNZ R7,$
DJNZ R6,D1
DJNZ R5,DELAY
RET
;======================================================
;延時5MS
;======================================================
DELAY1:
MOV R6,#25
DL2: MOV R7,#100
DJNZ R7,$
DJNZ R6,DL2
RET
;======================================================
;鍵值順序碼
;======================================================
KEYTABLE:
DB 0eeH ,077H,0B7H,0D7H, 07bh,0bbh,0dbh ,07dh,0bdh,0ddh, 0e7h,0ebh,0edh, 07eh,0beh,0deh,0ffh
;-----------------------------------------------------
END
?? 快捷鍵說明
復(fù)制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -