;******************字節讀*****25045---->內存*******
;輸入 無，輸出 A
;使用累加器 A
;調用子程序 OUT IN
BY_RD:          CLR P2.1
                CLR P3.4
                MOV A,#03H
                LCALL OUT
                MOV A,#22H
                LCALL OUT
                LCALL IN
                MOV 2CH,A
                LCALL IN
                MOV 50H,A;yjbys,A
                LCALL IN
                MOV 51H,A;p_zys,A
                LCALL IN
                MOV 52H,A;z_qys,A
                LCALL IN
                MOV 53H,A;z_hys,A
                LCALL IN
                MOV 54H,A;q_hys,A
                LCALL IN
                MOV 55H,A;t_wys,A
                LCALL IN
                MOV 56H,A;fhys,A
                LCALL IN
                MOV 57H,A;t_wys,A
                LCALL IN
                MOV 58H,A;fhys,A
                CLR P2.1
                SETB P3.4
                RET
;******************字節寫*******內存----->25045*****
;輸入 無，輸出 無
;使用累加器 A
;調用子程序 OUT DELAY
BY_WR:          MOV A,#12H
                CLR P2.1
                CLR P3.4
                MOV A,#02H
                LCALL OUT
                MOV A,#22H
                LCALL OUT
                MOV A,2CH
                LCALL OUT
                MOV A,50H;yjbys
                LCALL OUT
                MOV A,51H;p_zys
                LCALL OUT
                MOV A,52H;z_qys
                LCALL OUT
                MOV A,53H;z_hys
                LCALL OUT
                MOV A,54H;q_hys
                LCALL OUT
                MOV A,55H;t_wys
                LCALL OUT
                MOV A,56H;fhys
                LCALL OUT
                MOV A,57H;t_wys
                LCALL OUT
                MOV A,58H;fhys
                LCALL OUT
                CLR P2.1
                SETB P3.4
                LCALL WIP
                RET
;**********寫使能**********
;此程序使--可以向EEPROM MEMORY 數組和狀態寄存器寫入
;輸入 無，輸出 無
;使用累加器 A
;調用子程序 OUT
WR_CMD:         CLR P2.1
                CLR P3.4
                MOV A,#06H
                LCALL OUT
                CLR P2.1
                SETB P3.4
                RET
;***********寫狀態寄存器************
;寫狀態寄存器
;輸入 無，輸出 無
;使用累加器 A
;調用子程序 OUT WIP
WS_CMD:         CLR P2.1
                CLR P3.4
                MOV A,#01H
                LCALL OUT
                MOV A,#00H
                LCALL OUT
                CLR P2.1
                SETB P3.4
                LCALL WIP
                RET
;********* "字節寫"***********
;依次將一個字節每一位送出
;輸入 A，輸出 無
;使用累加器 A 寄存器 R0
;調用子程序 無
OUT:            MOV R0,#08H
OUT1:           CLR P2.1
                RLC A
                MOV P2.0,C
                SETB P2.1
                DJNZ R0,OUT1
                CLR  P2.0
                RET
;********"字節讀"***********
;此程序接收一個字節
;輸入 無，輸出 A
;使用累加器 A  寄存器 R0
;調用子程序 無
IN:             MOV R0,#08H
IN1:            SETB P2.1
                CLR P2.1
                MOV C,P2.2
                RLC A
                DJNZ R0,IN1
                RET
;**********讀狀態寄存器**********
;輸入 無，輸出 無
;使用累加器 A
;調用子程序 OUT WIP
RD_CMD:         CLR P2.1
                CLR P3.4
                MOV A,#05H
                LCALL OUT
                LCALL IN
                MOV 30H,A
                SETB P3.4
                RET
;************
RST:            CLR P3.4
                SETB P3.4
                RET
;*****************WIP*************
;此程序檢測寫周期是否完成
;輸入 無，輸出 無
;使用累加器 A 寄存器 R1
;調用子程序 RD-CMD
WIP:            MOV R1,#99H
WIP1:           LCALL RD_CMD
                JNB ACC.0,WIP2
                DJNZ R1,WIP1
WIP2:           RET