<!--#include file = "Startup.asp"-->

<%

' ======================
' 功能：刪除新聞
' 描述：新聞刪除后，頁(yè)面轉(zhuǎn)向新聞列表頁(yè)。
'       刪除新聞的同時(shí)，刪除此新聞相關(guān)的上傳文件。
' ======================

Call Header("刪除新聞")
Call Content()
Call Footer()


' 本頁(yè)內(nèi)容區(qū)
Sub Content()

	' 取參數(shù)：新聞ID
	Dim sNewsID
	sNewsID = Trim(Request("id"))

	' 新聞ID有效性驗(yàn)證，防止有些人惡意的破壞此演示程序
	If IsNumeric(sNewsID) = False Then
		GoError "請(qǐng)通過(guò)頁(yè)面上的鏈接進(jìn)行操作，不要試圖破壞此演示系統(tǒng)。"
	End If

	' 從新聞數(shù)據(jù)表中取出相關(guān)的上傳文件
	' 上傳后保存到本地服務(wù)器的路徑文件名，多個(gè)以"|"分隔
	' 刪除文件，要取帶路徑的文件名才可以，并且只要這個(gè)就可以了，原來(lái)存的原文件名或不帶路徑的保存文件名可用于其它地方使用
	Dim sSavePathFileName
	
	sSql = "SELECT D_SavePathFileName FROM NewsData WHERE D_ID=" & sNewsID
	oRs.Open sSql, oConn, 0, 1
	If Not oRs.Eof Then
		sSavePathFileName = oRs("D_SavePathFileName")
	Else
		GoError "無(wú)效的新聞ID，請(qǐng)點(diǎn)頁(yè)面上的鏈接進(jìn)行操作！"
	End If
	oRs.Close

	' 把帶"|"的字符串轉(zhuǎn)為數(shù)組
	Dim aSavePathFileName
	aSavePathFileName = Split(sSavePathFileName, "|")

	' 刪除新聞相關(guān)的文件，從文件夾中
	Dim i
	For i = 0 To UBound(aSavePathFileName)
		' 按路徑文件名刪除文件
		Call DoDelFile(aSavePathFileName(i))
	Next

	' 刪除新聞
	sSql = "DELETE FROM NewsData WHERE D_ID=" & sNewsID
	oConn.Execute sSql

	' 3秒轉(zhuǎn)向新聞列表頁(yè)
	response.write "<p align=center>新聞刪除成功，3秒后自動(dòng)返回新聞列表頁(yè)！<script>window.setTimeout(""location.href='list.asp'"",3000);</script></p>"

End Sub

' 刪除指定的文件
Sub DoDelFile(sPathFile)
	On Error Resume Next
	Dim oFSO
	Set oFSO = Server.CreateObject("Scripting.FileSystemObject")
	oFSO.DeleteFile(Server.MapPath(sPathFile))
	Set oFSO = Nothing
End Sub

%>