!/BACH,LIST
/TITLE,SIMPLE HALF WAVE RECTIFIER WITH IDEAL DIODE  ! 定義工作標題
/FILNAME,HALF WAVE RECTIFIER,1            ! 定義工作文件名
KEYW,MAGELC,1                             ! 指定電路分析

/PREP7
PI = 4*ATAN(1)                 ! 設(shè)置π參數(shù)
R,1,,135,1,                    ! 定義正弦電壓源實常數(shù)
N,1,-0.85,0.4,0                ! 創(chuàng)建節(jié)點
N,2,-0.85,0.25,0   
RMOD,1,15,0,1                  ! 修改實常數(shù)組1
ET,1,CIRCU124,4,1              ! 定義獨立電壓源單元
TYPE,1                         ! 設(shè)置默認屬性
REAL,1  
!*  
N,3,-0.85,0.325,0              ! 創(chuàng)建節(jié)點
E,1,2,3                        ! 創(chuàng)建正弦電壓源單元
R,2,2500,                      ! 定義電阻實常數(shù)為2500 OHM
N,4,-0.75,0.4,0                ! 創(chuàng)建節(jié)點
N,5,-0.75,0.25,0   
RMOD,2,15,0,2                  ! 修改實常數(shù)組2
ET,2,CIRCU124,0,0              ! 定義電阻單元
TYPE,2                         ! 設(shè)置默認屬性
REAL,2  
E,4,5                          ! 創(chuàng)建電阻單元，阻值為2500 OHM
!
! 下面的命令用來創(chuàng)建二極管單元
!
ET,3,CIRCU125,
R,3 
TYPE,3  
REAL,3     
E,1,4
!
! 為電路施加接地邊界條件
!  
D,2,VOLT,0
D,5,VOLT,0     
ALLSEL
EPLOT
FINISH
!
! 在時間T=0～1.5范圍內(nèi)進行非線性電路求解
!  
/SOLU   
ANTYPE,TRANS                       ! 瞬態(tài)分析
OUTRES,ALL,ALL,
TIME,1.5
AUTOTS,1                           ! 自動時間步長 
DELTIM,0.01,0.01,0.04              ! 時間步長范圍為0.01～0.04s 
CNVTOL,VOLT                        ! 收斂標準
SOLVE   
FINISH

/POST26 
NSOL,2,4,VOLT,,                    ! 定義時間歷程變量
PRVAR,2,                           ! 列出時間歷程變量結(jié)果
/AXLAB,Y,OUTPUT POTENTIAL (VOLT)   ! 修改Y軸坐標標簽
PLVAR,2,                           ! 繪出時間歷程變量