!/BACH,LIST
/TITLE, DC CURRENT IN A SLOT               ! 定義工作標題
/FILNAME,Slot_3D,1                          ! 定義工作文件名
KEYW,MAGEDG,1                            ! 指定磁場分析

/PREP7
! 定義分析的參數
L=0.3                  ! 長
D=0.1                  ! 高
W=0.01                ! 寬
MUR=1                ! 相對磁導率
RHO=1.0E-8            ! 電阻率 
FR=3                  ! 在5%滑移時轉動頻率
CURR=2000.0           ! 電流實部
CURI=1000.0           ! 電流虛部
N=20                  ! 寬度方向單元劃分個數
PI=3.1415926
MU0=PI*4.0E-7         ! 真空磁導率
ET,1,117,1              ! 定義單元及選項
MP,MURX,1,MUR       ! 定義材料相對磁導率屬性
MP,RSVX,1,RHO        ! 定義材料電阻率屬性
BLOCK,0,D,0,W,0,L      ! 創建模型,
LSEL,S,LOC,X,D/2       ! 選擇寬度方向上的線
LESIZE,ALL,,,N         ! 設定所選線段上單元個數
LSEL,ALL              ! 選擇所有線
ESIZE,,1                ! 設定全局單元個數
VMESH,ALL            ! 體網格劃分.
FINISH

/SOLU                  ! 進入求解器
ANTYP,HARM           ! 指定諧波磁場分析
HARFR,FR              ! 指定諧波頻率 
NSEL,S,LOC,X,D         ! 選擇X=D處節點
NSEL,A,LOC,Z,0         ! 增加選擇Z=0處節點
NSEL,A,LOC,Z,L         ! 增加選擇Z= L處節點
D,ALL,AZ,0             ! 施加磁力線平行邊界條件
NSEL,S,LOC,Z,0         ! 選擇Z=0處節點
D,ALL,VOLT,0           ! 給所選節點施加零電壓自由度
NSEL,S,LOC,Z,L         ! 選擇Z= L處節點
CP,1,VOLT,ALL          ! 耦合所選節點電壓自由度
*GET,N1,NODE,,NUM,MIN  ! 獲得Z=L處最小節點號
F,N1,AMPS,CURR,CURI     ! 給指點節點施加電流載荷
NSEL,ALL                 ! 選擇所有的節點!
SOLVE
FINISH                  ! 退出求解器
/POST1                  ! 進入通用后處理器
SET,1,1                  ! 讀入實部解!
ETABLE,FXR,FMAG,X    ! 把實部時間平均磁力FX存入單元表中
POWERH                ! 計算時間平均能量損失
SET,,,,1                  ! 讀入虛部解
ETABLE,FXI,FMAG,X     ! 把虛部時間平均磁力FX存入單元表中
SADD,FXRMS,FXR,FXI   ! 通過單元表項相加計算總的時間平均磁力
SSUM                  ! 所有單元表項求和
FINISH

利用以上磁場分析的結果，將磁場分析的結果耦合到下面的熱場分析和結構分析中，下面給出了這兩種耦合場的命令流。
.
/PREP7
ET,1,90
LDREAD,HGEN,,,,2,,RST
BFELIST,ALL,HGEN
FINISH

/PREP7
ET,1,45
LDREAD,FORC,,,,2,,RST
FLIST
FINISH