;本程序測量溫度范圍：0~125度，精確到0.06；
;綜合接線圖： 
;1 用一根單條數據線把18B20的JP39接到CPU部分的JP53(P3口)的P3.0 
;2用一條4PIN的排線，把數碼管譯碼部份的JP19接到CPU部份
;P0口的JP51的P0.0,P0.1,P0.2,0.3 四個端口。（即插入P0口的上半部分）。 
;3 用一條8PIN的排線。 把數碼管譯碼部份的輸出端JP88,接到數碼管部分的數據口JP5 
;4用一條4PIN的排線，把38譯碼部份的JP22接到CPU部份P0口的JP51
;的P0.4,P0.5,P0.6,07 四個端口。（即插入P0口的下半部分）。此處不太好插入， 小心操作。 
;5 用一條8PIN的排線。 把38譯碼部份的輸出端JP25,接到數碼管部分的顯示位口JP8。
;********************************************************************************
;*  日期:  2007-3-25                                                            *
;*  版本:  3.0                                                                  *
;*  作者:  深圳學林電子有限公司     專業8051單片機教學站                        *
;*  郵箱: sxj1974@163.com                                                       *
;*  網站： http://www.51c51.com     http://www.8951.com    更多例程請登陸網站   *
;********************************************************************************
;*  硬件：此程序在本公司xlisp系列單片機實驗儀運行通過                           *
;********************************************************************************
;* 【版權】 Copyright(C)深圳學林電子有限公司 www.51c51.com  All Rights Reserved *
;* 【聲明】 此程序僅用于學習與參考，引用請注明版權和作者信息！                  *
;********************************************************************************
DAT   BIT P3.0   				;數據通信口
WDLSB DATA 30H 					;讀出的溫度低字節
WDMSB DATA 31H 					;讀出的溫度高字節
;***************************************************************
      ORG 0000H
      LJMP MAIN
      ORG 000BH
      SJMP TIMER0 				;定時顯示

;****************************************************************
						;定時顯示子程序，采用循環掃描方式
						;顯示緩沖區40H~47H
        ORG 0040H
TIMER0:

	MOV P0,40H        			;最后一位值送p0
	ORL P0,#70H				; 點亮最后一位
	CALL T1MS
	MOV P0,41H
	ORL P0,#60H
	CALL T1MS
	MOV P0,42H
	ORL P0,#50H
	CALL T1MS
	MOV P0,43H
	ORL P0,#40H
    MOV TH0,#LOW(65536-10000)  			;定時器10MS中斷
	MOV TL0,#HIGH(65536-10000)
	RETI
T1MS: mov	r5,#00h				;延時子程序
tt:	mov	r6,#9
	djnz	r6,$
	djnz	r5,tt
	ret
;*********************************************************
						;主程序:
MAIN:   MOV SP,#60H
	MOV P2,#0FFH
	MOV R2,#8
	MOV R0,#40H ;
OVER:   MOV @R0,#00H
        INC R0
	DJNZ R2,OVER
	MOV TMOD,#01H
	MOV TH0,#LOW(65536-10000)
	MOV TL0,#HIGH(65536-10000)
	SETB EA
	SETB ET0
	SETB TR0
LOOP:   LCALL DSWD 				;調用讀出DS18B20溫度程序
	SJMP LOOP                                                ; 讀出DS18B20溫度程序
DSWD:
	CLR EA
	LCALL RST
	JNB F0,KEND 				;如果沒有應答，返回主程序
	MOV R0,#0CCH
	LCALL SEND_BYTE 			;跳過ROM匹配
	MOV R0,#44H				;發出溫度轉換命令
	LCALL SEND_BYTE
	SETB EA
	MOV P1,#00001111B
	MOV 48H,#1 				;廷時75ms以上準備讀
SS2:    MOV 49H,#255
SS1:    MOV 4AH,#255
SS0:    DJNZ 4AH,SS0
 	DJNZ 49H,SS1
	DJNZ 48H,SS2
	MOV P1,#11111100B
	CLR EA
	LCALL RST
	JNB F0,KEND
	MOV R0,#0CCH 				;跳過ROM匹配
	LCALL SEND_BYTE
	MOV R0,#0BEH 				;發出讀溫度命令
	LCALL SEND_BYTE
	LCALL READ_BYTE
	MOV WDLSB,A
	LCALL READ_BYTE
	MOV WDMSB,A
	LCALL TRANS12
KEND:   mov p1,#01010101b
	SETB EA
	RET
;**********************************************************
;溫度轉換程序：精確到：0.06 ;
TRANS12:MOV A,30H
	ANL A,#0F0H
	MOV 3AH,A
	MOV A,31H
	ANL A,#0FH
	ORL A,3AH
	SWAP A
	MOV B,#10
	DIV AB
	MOV 43H,A
	MOV 42H,B ;
	MOV DPTR,#TABB
	MOV A,30H
	ANL A,#0FH
	MOV B,#2
	MUL AB
	MOVC A,@A+DPTR
	MOV 41H,A
	MOV A,30H
	ANL A,#0FH
	MOV B,#2
	MUL AB
	INC A
	MOVC A,@A+DPTR
	MOV 40H,A
	RET
TABB:   DB 0,0,0,6,1,2,1,8,2,5,3,1,3,7,4,3,5,0
	DB 5,6,6,2,6,8,7,5,8,1,8,7,9,3
;*************************************************

SEND_BYTE: 					;發送一個字節程序
	MOV A,R0
	MOV R5,#8
SEN3: 	CLR C
	RRC A
	JC SEN1
	LCALL WRITE_0
	SJMP SEN2
SEN1:   LCALL WRITE_1
SEN2: 	DJNZ R5,SEN3                    	; 循環8次，寫一個字節
	RET
READ_BYTE: 					;讀一個字節程序
	MOV R5,#8
READ1:  LCALL READ
	RRC A
	DJNZ R5,READ1                   	; 循環8次，讀一個字節
	MOV R0,A
	RET
						;復位程序，如果復位置位F0,沒有就復位F0
RST: 	SETB  DAT
	NOP
	NOP
	CLR DAT
	MOV R6,#250 				;主機發復位脈沖持續3μs×200=600μs
	DJNZ R6,$
	MOV R6,#50
	DJNZ R6,$
	SETB DAT                         	;主機釋放總線，口線改為輸入
	MOV R6,#15
	DJNZ R6,$
	CALL CHCK 				;調用應答檢查程序
	MOV R6,#60
	DJNZ R6,$
	SETB DAT
	RET
CHCK: 	MOV C,DAT
	JC RST0
	SETB F0                          	;檢測到信號，置位F0
	SJMP    CHCK0
RST0: 	CLR F0                           	;未準備好F0復位
CHCK0:  RET

WRITE_0: 				    	;寫0
        CLR DAT
	MOV R6,#30
	DJNZ R6,$
	SETB DAT
	RET
WRITE_1:CLR DAT                             	;寫1
	NOP
	NOP
	NOP
	NOP
    NOP
	SETB DAT
	MOV R6,#30
	DJNZ R6,$
	RET
						;讀一位數據程序
READ: 	SETB DAT                     		;先復位至少1US產生讀起始信號
	NOP
	NOP
	CLR DAT
	NOP
	NOP
	SETB DAT                      		;置位DAT準備接收數據
	NOP
	NOP
	NOP
	NOP
	NOP
	NOP
	NOP
	MOV C,DAT
	MOV R6,#23
	DJNZ R6,$
	RET
	END