;USE SSD1815BZ FOR EG9664B
  
	LCD_CS  	EQU  P3.0
	LCD_RST  	EQU  P3.1
	LCD_A0  	EQU  P3.2
	LCD_RW  	EQU  P3.3
	LCD_E   	EQU  P3.4
	XA   		EQU  30H
	XT   		EQU  31H
         
;************************************         
          ORG   0000H         
    START:
          LJMP  MAIN
          ORG  0040H
    MAIN: MOV  SP,#60H

          LCALL LCD_INT
          
      GO: MOV   R0,#00H
          MOV   R1,#00H
          LCALL DISPLAY
          
          MOV   R0,#0FFH
          MOV   R1,#0FFH
          LCALL DISPLAY
          CALL  GEN1
   
          MOV   R0,#0AAH
          MOV   R1,#0AAH
          LCALL DISPLAY
          CALL  GEN2
        
          MOV   R0,#0FFH
          MOV   R1,#00H
          LCALL DISPLAY
         
          MOV   R0,#55H
          MOV   R1,#0AAH
          LCALL DISPLAY
          
          MOV   R0,#00H
          MOV   R1,#00H
          LCALL DISPLAY
          
          MOV   R0,#0AAH
          MOV   R1,#55H
          LCALL DISPLAY
          LJMP  GO

 LCD_INT: 
          CLR  LCD_RST
          NOP
          NOP
          SETB LCD_RST
          MOV  A,#10100010B      ;Set LCD-Bias
          LCALL W_IR
          MOV  A,#00101111B      ;SET Power Control Resister
          LCALL  W_IR
          MOV  A,#00100110B      ;Set Internal Resister Ratio
          LCALL  W_IR
          MOV  A,#10000001B      ;Set contrast Control Resister
          LCALL  W_IR
          MOV  A,#00000101B      ;Set contrast Control Resister 
          LCALL  W_IR
          MOV  A,#11001000B      ;Set COM Re-map
          LCALL  W_IR
          MOV  A,#10100000B      ;set SEG Re-map
          LCALL  W_IR
          MOV  A,#10100110B      ;Set Normal Display
          LCALL W_IR
          MOV  A,#10101111B      ;Set display ON
          LCALL  W_IR 
          RET
 DISPLAY: 
          MOV  R2,#8
          MOV  XA,#10110000B 
    DIS0: MOV  A,XA
          LCALL  W_IR
          MOV  XT,#48          
          MOV  A,#00H
          LCALL W_IR
          MOV  A,#10H
          LCALL  W_IR
    DIS1: MOV A,R0
          LCALL W_DR
          MOV A,R1
          LCALL  W_DR
          DJNZ XT,DIS1
          INC  XA
          DJNZ R2,DIS0
          LCALL DELAY2s
          RET
   W_DR: 
          ;CALL B_CK
          SETB LCD_A0
          CLR  LCD_RW
          SETB LCD_E
          CLR  LCD_CS
          MOV  P1,A
          SETB LCD_CS
          SETB LCD_RW
          RET
    W_IR:
          CALL B_CK
          CLR  LCD_A0
          CLR  LCD_RW
          SETB LCD_E
          CLR  LCD_CS
          MOV  P1,A
          SETB  LCD_RW
          SETB LCD_CS
          RET 
    GEN1:
          MOV  A,#10000001B
          LCALL W_IR
          MOV  A,#00001101B
          LCALL W_IR
          RET
    GEN2:
          MOV  A,#10000001B
          LCALL W_IR
          MOV  A,#00001010B
          LCALL W_IR
          RET

    B_CK: MOV P1,#0FFH
          CLR  LCD_A0
          SETB LCD_RW
     BUSY:
          CLR  LCD_E
          CLR  LCD_CS
          MOV  C,P1.7
          SETB LCD_CS
          SETB LCD_E
          JC   BUSY
          RET
  DELAY2S:
          MOV  R4,#10
     DEL0:MOV  R5,#00
     DEL1:MOV  R6,#00
          DJNZ R6,$
          DJNZ R5,DEL1
          DJNZ R4,DEL0
          RET
        
DELAY60ms:
          MOV  R5,#248
     DEL2:MOV  R6,#00
          DJNZ R6,$
          DJNZ R5,DEL2
          RET
	end