Flash   equ 0         ; LED狀態
       STOP    equ 1

       SR      equ p1.0      ; 南北紅燈
       SY      equ p1.1      ; 南北黃燈
       SG      equ P1.2      ; 南北綠燈

       ER      equ P1.3      ; 東西紅燈
       EY      equ P1.4      ; 東西黃燈
       EG      equ p1.5      ; 東西綠燈

       ljmp    Start

       org     3

       setb    STOP          ; 南北, 東西均紅燈
       reti

Start:
       mov     SP, #70
       mov     TCON, #01h    ; down edge  IT0
       mov     IE, #81h      ; enable EA, EX0

       setb    SR            ; 南北, 東西均紅燈
       clr     SY
       clr     SG

       setb    ER
       clr     EY
       clr     EG

       clr     STOP
Loop:
       jb      STOP, AllRed

       setb    SR            ; 南北紅燈, 東西綠燈
       clr     SY
       clr     SG

       clr     ER
       clr     EY
       setb    EG

       mov     a, #20
       call    Delay

       jb      STOP, AllRed
       setb    SR            ; 南北紅燈, 東西黃燈閃
       clr     SY
       clr     SG

       clr     ER
       clr     EY
       clr     EG

       clr     Flash
       mov     r7, #9
Loop1:
       mov     c, Flash
       mov     EY, c
       mov     a, #1
       call    Delay
       cpl     Flash
       djnz    r7, Loop1

       jb      STOP, AllRed
       clr     SR            ; 南北綠燈, 東西紅燈
       clr     SY
       setb    SG

       setb    ER
       clr     EY
       clr     EG

       mov     a, #20
       call    Delay

       jb      STOP, AllRed
       clr     SR            ; 東西紅燈, 南北黃燈閃
       clr     SY
       clr     SG

       setb    ER
       clr     EY
       clr     EG

       clr     Flash
       mov     r7, #9
Loop2:
       mov     c, Flash
       mov     SY, c
       mov     a, #1
       call    Delay
       cpl     Flash
       djnz    r7, Loop2

       ljmp    Loop

AllRed:
       setb    SR
       clr     SY
       clr     SG

       setb    ER
       clr     EY
       clr     EG

       clr     STOP
       mov     a, #10
       call    Delay
       ljmp    Loop

Delay: ; 延時子程序
       mov     r1, #80H
       mov     r0, #0
DelayLoop:
       jb      STOP, ExitDelay
       djnz    r0, DelayLoop
       djnz    r1, DelayLoop
       djnz    ACC, Delay
ExitDelay:
       ret

       end