;---------------------------------------
;       把緩存器中的內容寫入到1302中
;---------------------------------------
SET1302:
        LCALL  ENABLE
        LCALL  EN_CS
        CLR    T_RST
        CLR    T_CLK
        SETB   T_RST
        MOV    B,#8EH      ;控制寄存器
        LCALL  RTInputByte  ;寫入控制寄存器地址。
        MOV    B,#00H        ;寫操作前WP=0
        LCALL  RTInputByte   ;向控制寄存器中寫入內容。（禁止寫入時間）
        SETB   T_CLK
        CLR    T_RST
        MOV    R0,#Second   ;
        MOV    R7,#7        ;秒 分 時 日 月 星期 年  共7個字節數據。
        MOV    R1,#80H     ; ;1302中秒的地址送入R1。
S13021:
        CLR    T_RST
        CLR    T_CLK
        SETB   T_RST
        MOV    B,R1        ;寫秒 分 時 日 月 星期 年 地址
        LCALL  RTInputByte ;向1302中寫入相應地址。
        MOV    A,@R0       ;寫秒數據
        MOV    B,A
        LCALL  RTInputByte  ;向1302中的相應地址中寫入對應的數據。
        INC    R0
        INC    R1
        INC    R1
        SETB   T_CLK
        CLR    T_RST
        DJNZ   R7,S13021
        CLR    T_RST        ;
        CLR    T_CLK        ;
        SETB   T_RST        ;
        MOV    B,#8EH       ;控制寄存器
        LCALL  RTInputByte  ;寫入控制寄存器地址。
        MOV    B,#80H       ;向控制寄存器中寫入內容,WP=1,寫保護
        LCALL  RTInputByte  ;
        SETB   T_CLK
        CLR    T_RST
        RET

;************************************************************************
;           從DS1302 中讀出時間
;入口參數：時間保存在:Second,Minute,Hour,Day,Month,Week.YearL
;影響資源：A B R0 R1 R4 R7
;************************************************************************
Get1302:
       LCALL  ENABLE
       LCALL  EN_CS
    
        MOV    R0,#Second;
        MOV    R7,#7
        MOV    R1,#81H       ;秒地址
G13021:
        CLR    T_RST
        CLR    T_CLK
        SETB   T_RST
        MOV    B,R1        ;秒 分 時 日 月 星期 年 地址
        LCALL  RTInputByte
        LCALL  RTOutputByte
        MOV    @R0,A         ;秒
        INC    R0
        INC    R1
        INC    R1
        SETB   T_CLK
        CLR    T_RST
        DJNZ   R7,G13021
   
        RET
;**********************************************************
;功    能：寫1302一字節  （內部子程序）
;      入口：B--要寫入的數據。
;**********************************************************
RTInputByte:
        MOV    R4,#8
Inbit1:
        MOV    A,B
        RRC    A
        MOV    B,A
        MOV    T_IO,C
        SETB   T_CLK
        CLR    T_CLK
        DJNZ   R4,Inbit1
        RET
;**********************************************************
;功    能：讀1302一字節  （內部子程序）
;      入口：            出口：A--讀出的字節數據
;**********************************************************
RTOutputByte:
        MOV    R4,#8
Outbit1:
        MOV    C,T_IO
        RRC    A
        SETB   T_CLK
        CLR    T_CLK
        DJNZ   R4,Outbit1
        RET