32位代碼優化常識

--------------------------------------------------------------------------------
        原作者:  Benny/29A 
        翻譯改寫:hume/冷雨飄心 

關于代碼優化的文章實在太多了,遺憾的是大部分我都沒有看,盡管他們就擺在我的床邊(每當我要看的時候就忍不住打哈欠...嘿嘿).這篇文章較短所以翻了一下. 

代碼優化的含義: 

代碼優化的目標當然是體積小和速度快,但是在通常的情況下二者就象魚和熊掌一樣不能得兼,我們通常尋找的是這二者的折中,究竟應該偏向何方,那就得具體看我們的實際需要. 

但有些常識是我們應該牢記的,下面就結合我們最常遇到的具體情況來漫談一下: 

1.寄存器清0 
        我絕對不想再看到下面的寫法: 
        1)      mov eax, 00000000h                    ;5 bytes 

        看起來上面的寫法很符合邏輯,但你應當意識到還有更加優化的寫法: 
        2)      sub eax, eax                          ;2 bytes 
        3)      xor eax, eax                          ;2 bytes 

        看看后面的字節數你就應該理解為什么要這么作了,除此之外,在速度上也沒有損失,他們一樣快,但你喜歡xor還是sub呢?我是比較喜歡xor,原因很簡單,因為我數學不好.... 

        不過Microsoft比較喜歡sub....我們知道windows運行的慢....(呵呵,當然是玩笑這并不是真正原因X-D!) 

2.測試寄存器是否為0 
        我也不希望看到下面的代碼: 
        1)      cmp eax, 00000000h                    ;5 bytes 
                je _label_                            ;2/6 bytes (short/near) 

        [* 注意很多指令針對eax作了優化,你要盡可能多地實用eax,比如CMP EAX, 12345678h (5 bytes) 
        如果你使用其他寄存器,就是6bytes *] 
        
        讓我們看看,簡單的比較指令居然要用7/11 bytes,No No No,試試下面的寫法: 
        2)      or eax, eax                          ;2 bytes 
                je _label_                            ;2/6 (short/near) 

        3)      test eax, eax                        ;2 bytes 
                je _label_                            ;2/6 (short/near) 

        呵呵,只有4/8 bytes,看看我們可節省多少字節啊3/4字節...那么接下來的問題是你喜歡OR還是TEST呢,就我個人而言,比較喜歡TEST,因為test不改變任何寄存器,并不向任何寄存器寫入內容,這通常能在pentium機上取得更快的執行速度. 
        
        別高興的太早,因為還有更值得我們高興的事情,假如你要判斷的的是eax寄存器,那么看看下面的,是不是更有啟發? 
        4)      xchg eax, ecx                        ;1 byte 
                jecxz _label_                        ;2 bytes 
        在短跳轉的情況下我們比2)和3)又節省了1字節.oh....___... 

3.測試寄存器是否為0FFFFFFFFh 
        一些API返回-1,因此如何測試這個值呢?看你可能又要這樣: 
        1)      cmp eax, 0ffffffffh                  ;5 bytes 
                je _label_                            ;2/6 bytes 
        hey,不要這樣,寫代碼的時候想一想,于是有了下面的寫法: 
        2)      inc eax                              ;1 byte 
                je _label_                            ;2/6 bytes 
                dec eax                              ;1 byte 

        可以節省3 bytes并且執行速度會更快. 

4.置寄存器為0FFFFFFFFh 
        看看假如你是Api的作者,如何返回-1?這樣嗎? 
        1)      mov eax, 0ffffffffh                  ;5 bytes 

        看了上面的不會再這么XXX了吧?看看下面的: 
        2)      xor eax, eax / sub eax, eax          ;2 bytes 
                dec eax                              ;1 byte 
        節省一個字!還有寫法: 
        3)      stc                                  ;1 byte 
                sbb eax, eax                          ;2 bytes 
        這有時還可以優化掉1 byte: 
                jnc _label_ 
                sbb eax, eax                          ;2 bytes only! 
      _label_: ... 

      我們為什么用asm呢?這就是原因. 

5.寄存器清0并移入低字數值 
        1)      xor eax, eax                          ;2 bytes 
                mov ax, word ptr [esi+xx]            ;4 bytes 
        ????--->不會吧,這可能是最多初學者的寫法了,我當然原來也是,看了benny的文章之后我決定改寫

為: 
        2)      movzx eax, word ptr [esi+xx]          ;4 bytes 
        收獲2 bytes! 

        下面的 
        3)      xor eax, eax                          ;2 bytes 
                mov al, byte ptr [esi+xx]            ;3 bytes 

        就相應改為: 
        4)      movzx eax, byte ptr [esi+xx]          ;4 bytes 

        我們應當盡可能利用movzx 
        5)      xor eax, eax                          ;2 bytes 
                mov ax, bx                            ;3 bytes 

        因為執行速度不慢并通常能節省字節... 
        6)      movzx eax, bx                        ;3 bytes 

6.關于push,下面是著重代碼體積的優化,因為寄存器操作總要比內存操作要快. 

        1)      mov eax, 50h                          ;5 bytes 

        這樣就小了1 word 

        2)      push 50h                              ;2 bytes 
                pop eax                              ;1 byte 
        
        當操作數只有1字節時候,push只有2 bytes,否則就是5 bytes,記住! 
        下一個問題,向堆棧中壓入7個0 

        3)      push 0                                ;2 bytes 
                push 0                                ;2 bytes 
                push 0                                ;2 bytes 
                push 0                                ;2 bytes 
                push 0                                ;2 bytes 
                push 0                                ;2 bytes 
                push 0                                ;2 bytes 

      占用14字節,顯然不能滿意,優化一下 
        4)      xor eax, eax                          ;2 bytes 
                push eax                              ;1 byte 
                push eax                              ;1 byte 
                push eax                              ;1 byte 
                push eax                              ;1 byte 
                push eax                              ;1 byte 
                push eax                              ;1 byte 
                push eax                              ;1 byte 

        可以更緊湊,但會慢一點的形式如下: 

        5)      push 7                                ;2 bytes 
                pop ecx                              ;1 byte 
      _label_:  push 0                                ;2 bytes 
                loop _label_                          ;2 bytes 

        可以節省7字節.... 

        有時候你可能會從將一個值從一個內存地址轉移到另外內存地址,并且要保存所有寄存器: 

        6)      push eax                              ;1 byte 
                mov eax, [ebp + xxxx]                  ;6 bytes 
                mov [ebp + xxxx], eax                  ;6 bytes 
                pop eax                                ;1 byte 

        試試push,pop 

        7)      push dword ptr [ebp + xxxx]            ;6 bytes 
                pop dword ptr [ebp + xxxx]            ;6 bytes 
7.乘法 
    
        當eax已經放入被乘數,要乘28h,如何來寫? 
        1)      mov ecx, 28h                          ;5 bytes 
                mul ecx                              ;2 bytes 

      好一點的寫法如下: 

        2)      push 28h                              ;2 bytes 
                pop ecx                              ;1 byte 
                mul ecx                              ;2 bytes 

        哇這個更好:: 

        3)      imul eax, eax, 28h                    ;3 bytes 

        intel在新CPU中提供新的指令并不是擺設,需要你的使用. 

8.字符串操作 


        你如何從內存取得一個字節呢? 
        速度快的方案: 
        1)      mov al/ax/eax, [esi]                  ;2/3/2 bytes 
                inc esi                              ;1 byte 

        代碼小的方案: 
        2)      lodsb/w/d                            ;1 byte 

        我比較喜歡lod因為他小,雖然速度慢了點. 
        
        如何到達字符串尾呢? 
      JQwerty's method: 

        9)      lea esi, [ebp + asciiz]              ;6 bytes 
      s_check: lodsb                                ;1 byte 
                test al, al                          ;2 bytes 
                jne s_check                          ;2 bytes 

        Super's method: 

        10)    lea edi, [ebp + asciiz]              ;6 bytes 
                xor al, al                            ;2 bytes 
      s_check: scasb                                ;1 byte 
                jne s_check                          ;2 byte 

      選擇哪一個?Super的在386以下的更快,JQwerty的在486以及pentium上更快,體積一樣,選擇由你. 

9.復雜一點的... 

        假設你有一個DWORD表,ebx指向表的開始,ecx是指針,你想給每個doword加1,看看如何作: 
        1)      pushad                                ;1 byte 
                imul ecx, ecx, 4                      ;3 bytes 
                add ebx, ecx                          ;2 bytes 
                inc dword ptr [ebx]                  ;2 bytes 
                popad                                ;1 byte 

        可以優化一點,但是好像沒人用: 

        2)      inc dword ptr [ebx+4*ecx]            ;3 bytes 

        一條指令就節省6字節,而且速度更快,更易讀,但好像沒有什么人用?...why? 
        還可以有立即數: 
        3)      pushad                                ;1 byte 
                imul ecx, ecx, 4                      ;3 bytes 
                add ebx, ecx                          ;2 bytes 
                add ebx, 1000h                        ;6 bytes 
                inc dwor ptr [ebx]                    ;2 bytes