一個(gè)很簡(jiǎn)單的鉤子 
相關(guān)的例子:下載>>>  作者：鬼龍之舞 于2008-8-17上傳   

--------------------------------------------------------------------------------

今天將介紹一個(gè)特別的鉤子程序，特別之處在于它非常簡(jiǎn)單，希望能給讀者一些啟發(fā)。我們不會(huì)

介紹復(fù)雜的原理，也不會(huì)涉及諸多的函數(shù)，相關(guān)的只有2個(gè)：SetWindowsHookEx 和 CBTProc 下面就對(duì)

他們分別作一介紹：

HHOOK SetWindowsHookEx(
int idHook, 
HOOKPROC lpfn, 
HINSTANCE hMod, 
DWORD dwThreadId 
); 

第一個(gè)參數(shù):指定鉤子的類型，有WH_MOUSE、WH_KEYBOARD等十多種(具體參見(jiàn)MSDN)
第二個(gè)參數(shù):標(biāo)識(shí)鉤子函數(shù)的入口地址
第三個(gè)參數(shù):鉤子函數(shù)所在模塊的句柄；
第四個(gè)參數(shù):鉤子相關(guān)函數(shù)的ID用以指定想讓鉤子去鉤哪個(gè)線程，為0時(shí)則攔截整個(gè)系統(tǒng)的消息。

簡(jiǎn)單理解就是第一個(gè)參數(shù)告訴系統(tǒng)：請(qǐng)將xxx的消息發(fā)給我。我們選擇的是 WH_CBT 。這個(gè)類型

會(huì)在窗口激活，創(chuàng)建，最小化，最大化，移動(dòng)或者改變大小；完成系統(tǒng)命令；從系統(tǒng)消息隊(duì)列中

移除鼠標(biāo)或者鍵盤事件之前；在取得鍵盤焦點(diǎn)之前；和系統(tǒng)消息隊(duì)列同步之前；

設(shè)置鍵盤焦點(diǎn)之前觸發(fā)。

回調(diào)函數(shù)，CBTProc 原型如下：
LRESULT CALLBACK CBTProc( 
int nCode,
WPARAM wParam,
LPARAM lParam
);

輸入的參數(shù) nCode = HCBT_ACTIVATE 表示是在激活一個(gè)窗口之前，回調(diào)進(jìn)入這個(gè)函數(shù)的。

因此，我們所做的就是：告訴系統(tǒng)，我已經(jīng)hook，請(qǐng)將窗口的某種消息發(fā)給我的xxx程序，然后

我們?cè)趚xx程序中再檢查，當(dāng)遇到我們需要的yyy消息時(shí)就做我們要做的，程序中我們是更換

按鍵上的文字。

;MASMPlus 代碼模板 - 普通的 Windows 程序代碼

.386
.Model Flat, StdCall
Option Casemap :None

Include windows.inc
Include user32.inc
Include kernel32.inc
Include gdi32.inc

includelib gdi32.lib
IncludeLib user32.lib
IncludeLib kernel32.lib
include macro.asm

WinMain PROTO :DWORD,:DWORD,:DWORD,:DWORD
WndProc PROTO :DWORD,:DWORD,:DWORD,:DWORD

.DATA
szClassName db "MASMPlus_Class",0

.DATA?
hInstance dd ?
hHook dd ?

.CODE
START:

invoke GetModuleHandle,NULL
mov hInstance,eax
invoke WinMain,hInstance,NULL,NULL,SW_SHOWDEFAULT
invoke ExitProcess,0

WinMain proc hInst:DWORD,hPrevInst:DWORD,CmdLine:DWORD,CmdShow:DWORD
LOCAL wc :WNDCLASSEX
LOCAL msg :MSG
local hWnd :HWND

mov wc.cbSize,sizeof WNDCLASSEX
mov wc.style,CS_HREDRAW or CS_VREDRAW or CS_BYTEALIGNWINDOW
mov wc.lpfnWndProc,offset WndProc
mov wc.cbClsExtra,NULL
mov wc.cbWndExtra,NULL
push hInst
pop wc.hInstance
mov wc.hbrBackground,COLOR_BTNFACE+1
mov wc.lpszMenuName,NULL
mov wc.lpszClassName,offset szClassName
invoke LoadIcon,hInst,100
mov wc.hIcon,eax
invoke LoadCursor,NULL,IDC_ARROW
mov wc.hCursor,eax
mov wc.hIconSm,0
invoke RegisterClassEx, ADDR wc
invoke CreateWindowEx,NULL,ADDR szClassName,CTXT("http://www.aogosoft.com"),WS_OVERLAPPEDWINDOW,200,200,400,200,NULL,NULL,hInst,NULL
mov hWnd,eax
invoke ShowWindow,hWnd,SW_SHOWNORMAL
invoke UpdateWindow,hWnd

StartLoop:
invoke GetMessage,ADDR msg,NULL,0,0
cmp eax, 0
je ExitLoop
invoke TranslateMessage, ADDR msg
invoke DispatchMessage, ADDR msg
jmp StartLoop
ExitLoop:

mov eax,msg.wParam
ret
WinMain endp

CBTHookProc proc nCode:DWORD,wParam:DWORD,lParam:DWORD
.if (nCode==HCBT_ACTIVATE)
invoke SetDlgItemText,wParam,IDYES,CTXT("&Yes")
invoke SetDlgItemText,wParam,IDNO ,CTXT("&No")
invoke UnhookWindowsHookEx,hHook
.endif 
xor eax,eax
ret
CBTHookProc endp

WndProc proc hWin:DWORD,uMsg:DWORD,wParam :DWORD,lParam :DWORD
.if uMsg==WM_CREATE
invoke MessageBox,hWin,CTXT("Hook之前"),CTXT("Test"),MB_ICONINFORMATION or MB_YESNO
invoke SetWindowsHookEx,WH_CBT,addr CBTHookProc,hInstance,NULL
mov hHook,eax

.if hHook != 0
invoke MessageBox,NULL,CTXT("你是帥哥嗎?"),CTXT("SC++"),MB_ICONINFORMATION or MB_YESNO
.else
invoke MessageBox,NULL,CTXT("無(wú)法安裝HOOK"),CTXT("SC++"),MB_ICONINFORMATION or MB_YESNO
.endif

.elseif uMsg == WM_DESTROY
invoke PostQuitMessage,NULL
.else
invoke DefWindowProc,hWin,uMsg,wParam,lParam
.endif
ret
WndProc endp

END START

Hook之前：



Hook之后：




本文來(lái)自CSDN上鬼龍之舞的blog，在此對(duì)他表示感謝！Zt


【參考1】CBTProc 函數(shù)
http://msdn.microsoft.com/en-us/library/ms644977(VS.85).aspx

【參考2】利用鍵盤鉤子開(kāi)發(fā)按鍵發(fā)音程序
http://www.vckbase.com/document/viewdoc/?id=271

【參考3】安裝鉤子，托管C++中的字符串及其它
http://www.vckbase.com/document/viewdoc/?id=1591



--------------------------------------------------------------------------------
<<<上一篇  歡迎訪問(wèn)AoGo匯編小站:http://www.aogosoft.com 下一篇>>>