package com.teknision.kuler
{
	import flash.events.EventDispatcher;
	
	public class KulerAPIUtils extends EventDispatcher
	{
		
		import flash.events.Event;
		import flash.net.*;
		import com.teknision.events.*;
		import com.teknision.vo.*;
		
		private var myXML:XML = new XML();
		private var myLoader:URLLoader;
		
		public function getColorsFromTag(i_tag:String):void{
			
			// Calls out to kuler and pulls back color themes based on search criteria
			var XML_URL:String = "http://kuler.adobe.com/kuler/API/rss/search.cfm?searchQuery="+i_tag+"&startIndex=0&itemsPerPage=3";
			var myXMLURL:URLRequest = new URLRequest(XML_URL);
			myLoader = new URLLoader(myXMLURL);
			myLoader.addEventListener("complete", this.xmlLoaded);
			
		}
		
		// The results brough back from Kuler are XML
		private function xmlLoaded(evtObj:Event):void{
				
		   	var myXMLData:XML = new XML(evtObj.currentTarget.data); 

		   	var kuler_ns:Namespace=myXMLData.namespace("kuler");
		   	var theme:XMLList = myXMLData.channel.item.kuler_ns::themeItem;
		   	var themeArray:Array = new Array();
		   
		   	// Loop over all the themes
		   	for(var i:uint=0;i<theme.length();i++){
		   		
		   		var name:XMLList = theme[i].kuler_ns::themeTitle;
		   		var colors:XMLList = theme[i].kuler_ns::themeSwatches.kuler_ns::swatch.kuler_ns::swatchHexColor;
		   		
				// Create an array of colors (for each theme)
				var colorsArr:Array = new Array();
		  		for(var x:uint=0;x<colors.length();x++){
		  			colorsArr.push(colors[x]);
		 		}
				
				// Attach the name and the color's array for each theme
		 		var newTheme:VOKulerTheme = new VOKulerTheme();
		 		newTheme.name = name;
		 		newTheme.colors = colorsArr;

		   		themeArray.push(newTheme);
		 	}
		   
		   	// dispatch an event when all the themes are added to the themeArray
			var newColorsReceivedEvent:KulerColorsReceivedEvent = new KulerColorsReceivedEvent(KulerColorsReceivedEvent.COLORS_RECEIVED);
			newColorsReceivedEvent.colors = themeArray;		
			this.dispatchEvent(newColorsReceivedEvent);
		    
		}
		
	}
}