MAIN:
LCALL INIT_1820 	;調用復位DS1820子程序
MAIN1:
LCALL GET_TEMPER	;調用讀溫度子程序
LCALL FORMULA 	;通過公式計算,小數點后顯示兩位
LCALL BCD
LCALL DISPLAY 	;調用串口顯示子程序
LCALL DELAY500 	;延時0.5秒
LCALL DELAY500 	;延時0.5秒
LCALL DELAY500 	;延時0.5秒
AJMP MAIN1
（2）DS1820復位初始化程序
INIT_1820:
SETB WDDATA
NOP
CLR WDDATA
;主機發出延時540微秒的復位低脈沖
MOV R0,#36
LCALL DELAY
SETB WDDATA		;然后拉高數據線
NOP
NOP
MOV R0,#36
TSR2:
JNB WDDATA,TSR3	;等待DS1820回應
DJNZ R0,TSR2
LJMP TSR4 			; 延時
TSR3:
SETB FLAG1 		; 置標志位,表示DS1820存在
LJMP TSR5
TSR4:
CLR FLAG1 			; 清標志位,表示DS1820不存在
LJMP TSR7
TSR5:
MOV R0,#06BH
TSR6:
DJNZ R0,TSR6 		;復位成功!時序要求延時一段時間
TSR7:
SETB WDDATA
RET
（3）讀出轉換后的溫度值
GET_TEMPER:
SETB WDDATA 		; 定時入口
LCALL INIT_1820 	;先復位DS1820
JB FLAG1,TSS2
RET 				; 判斷DS1820是否存在?若DS1820不存在則返回
TSS2:
MOV A,#0CCH 		; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#44H 		; 發出溫度轉換命令
LCALL WRITE_1820
MOV R0,#50 		;等待AD轉換結束,12位的話750微秒.
LCALL DELAY
LCALL INIT_1820 	;準備讀溫度前先復位
MOV A,#0CCH 		; 跳過ROM匹配
LCALL WRITE_1820
MOV A,#0BEH 		; 發出讀溫度命令
LCALL WRITE_1820
LCALL READ_18200	; 將讀出的九個字節數據保存到60H-68H
RET
（4）寫DS1820的子程序
WRITE_1820:
MOV R2,#8 			;一共8位數據
CLR C 
WR1:
CLR WDDATA
MOV R3,#6
DJNZ R3,$
RRC A
MOV WDDATA,C
MOV R3,#24
DJNZ R3,$
SETB WDDATA
NOP
DJNZ R2,WR1
SETB WDDATA
RET
（5）讀DS1820的程序
從DS1820中讀出九個字節的數據
READ_18200:
MOV R4,#9
MOV R1,#60H 		; 存入60H開始的九個單元
RE00:
MOV R2,#8
RE01:
CLR C
SETB WDDATA
NOP
NOP
CLR WDDATA
NOP
NOP
NOP
SETB WDDATA
MOV R3,#09
RE10:
DJNZ R3,RE10
MOV C,WDDATA
MOV R3,#23
RE20:
DJNZ R3,RE20
RRC A
DJNZ R2,RE01
MOV @R1,A
INC R1
DJNZ R4,RE00
RET
（6）溫度計算子程序
FORMULA: ; 按公式：T實際=(T整數-0.25)+( M每度-M剩余)/ M每度
;計算出實際溫度，整數部分和小數部分分別存于ZHENGSHU單元和DOT單元
;將61H中的低4位移入60H中的高4位，得到溫度的整數部分，并存于ZHENGSHU單元
MOV 29H,61H
MOV A,60H
MOV C,48H
RRC A
MOV C,49H
RRC A
MOV C,4AH
RRC A
MOV C,4BH
RRC A
MOV ZHENGSHU,A
; ( M每度-M剩余)/ M每度,小數值存于A中
MOV A,67h
SUBB A,66h
MOV B,#64H
MUL AB
MOV R4,B
MOV R5,A
MOV R7,67H
LCALL DIV457
MOV A,R3

;再減去0.25，實際應用中減去25
SUBB A,#19H
MOV DOT,A 			;小數部分存于DOT中
MOV A,ZHENGSHU
SUBB A,#00H 		;整數部分減去來自小數部分的借位
MOV ZHENGSHU,A
MOV C,4BH
JNC ZHENG 			;是否為負數
CPL A
INC A
MOV DIS_1,#2DH 	; 零度以下時,第一位顯示"-"號
MOV ZHENGSHU,A
ZHENG:
MOV DIS_1,#2BH 	;零度以上時,第一位顯示"+"號
RET
（7）串口顯示數據子程序
DISPLAY:
CLR TI
MOV A,DIS_1
MOV SBUF,A
JNB TI,$ 			;發送給PC,通過串口調試助手顯示+/-
CLR TI
MOV A,DIS_2
MOV SBUF,A
JNB TI,$ 			;發送給PC,通過串口調試助手顯示整數第一位
CLR TI
MOV A,DIS_3
MOV SBUF,A
JNB TI,$ 			;發送給PC,通過串口調試助手顯示整數第二位
CLR TI
MOV A,#2EH
MOV SBUF,A
JNB TI,$ 			;發送給PC,通過串口調試助手顯示小數點
CLR TI
MOV A,DIS_4
MOV SBUF,A
JNB TI,$ 			;發送給PC,通過串口調試助手顯示小數第一位
CLR TI
MOV A,DIS_5
MOV SBUF,A
JNB TI,$ 			;發送給PC,通過串口調試助手顯示小數第一位
CLR TI
MOV A,#0DH;換行
MOV SBUF,A
JNB TI,$ 			;發送給PC,通過串口調試助手顯示
CLR TI
MOV A,#0AH			;換行
MOV SBUF,A
JNB TI,$ 			;發送給PC,通過串口調試助手顯示
RET
（8）延時子程序
;為保證DS1820的嚴格I/O時序，需要做較精確的延時
;在DS1820操作中，用到的延時有15 μs，90 μs，270 μs，540 μs
;因這些延時均為15 μs的整數倍，因此可編寫一個DELAY15（n）函數
DELAY: ;11.05962M晶振
LOOP: MOV R1,#06H
LOOP1: DJNZ R1,LOOP1
DJNZ R0,LOOP
RET
;500毫秒延時子程序，占用R4、R5
DELAY500:MOV R4,#248
DA222:MOV R5,#248
DJNZ R5,$
DJNZ R4,DA222
RET
END