/PREP7  !進入前處理模塊PREP7

N, 1, 0, 0  !定義各個結點

N, 2, 3, 0  

N, 3, 6, 0

N, 4, 9, 0  

N, 5, 12, 0

N, 6, 15, 0 

N, 7, 18, 0

N, 8, 21, 0 

N, 9, 24, 0

N, 10, 27, 0    

N, 11, 30, 0    

NPLOT           ! 圖形中不顯示結點號碼

NPLOT, 1    ! 圖形中顯示結點號碼

NLIST           ! 在直角坐標系統下,列出結點資料

DSYS, 1     ! 列出資料時,轉換至圓柱坐標

NLIST           ! 在圓柱坐標系統下,列出結點資料

ET, 1, BEAM3    !定義第一類單元為平面梁單元BEAM3

MP, EX, 1, 207e5    !定義第一類材料的彈性模量EX

R, 1, 1, 0.020833, 0.5  !平面梁的實常數:截面積,抗彎慣性矩和截面高度

E, 1, 2     !定義各個單元兩端結點的連接關系

E, 2, 3

E, 3, 4 

E, 4, 5

E, 5, 6 

E, 6, 7

E, 7, 8 

E, 8, 9

E, 9,10 

E, 10, 11

EPLOT   !在圖形窗口顯示單元

ELIST   !列出單元信息

FINISH  !退出前處理模塊

/SOLU   !進入求解模塊SOLUTION

ANTYPE, STATIC      !申明求解類型是靜力分析

OUTPR, BASIC, ALL            ! 在輸出結果中，列出元素的結果

D, 1, UX, 0, , , , , UY, ROTZ   !定義1號結點約束所有自由度UX,UY和ROTZ 

D, 11, UX, 0, , , , ,UY     !約束11號結點的UX和UY自由度

SFBEAM, 1, 1, PRES, 0, 60   !定義各個單元上的線性分布荷載

SFBEAM, 2, 1, PRES, 60, 120

SFBEAM, 3, 1, PRES, 120, 180

SFBEAM, 4, 1, PRES, 180, 240

SFBEAM, 5, 1, PRES, 240, 300

SFBEAM, 6, 1, PRES, 300, 360

SFBEAM, 7, 1, PRES, 360, 420

SFBEAM, 8, 1, PRES, 420, 480

SFBEAM, 9, 1, PRES, 480, 540

SFBEAM, 10, 1, PRES, 540, 600

F, 6, FY, -1000     !定義在6號結點上的沿-Y方向大小為1000的集中力

SOLVE   !開始求解

FINISH  !退出求解模塊

/POST1  !進入后處理模塊POST1

PRDISP       ! 列出結點位移數據

ETABLE,IMOMENT, SMISC, 6    ! 建立單元結果表，元素I點力矩

ETABLE,JMOMENT, SMISC, 12   ! 建立單元結果表，元素J點力矩

ETABLE, ISHEAR, SMISC, 2    ! 建立單元結果表，元素I點剪力

ETABLE, JSHEAR, SMISC, 8    ! 建立單元結果表，元素J點剪力

PRETAB                    ! 列出單元表計算結果

/TITLE, SHEAR FORCE DIAGRAM !定義圖形窗口標題

PLLS, ISHEAR, JSHEAR               ! 繪制結構剪力分布圖

/TITLE, BENDING MOMENT DIAGRAM  !定義圖形窗口標題

PLLS, IMOMENT, JMOMENT        ! 結構彎矩分布圖

FINISH      !退出后處理模塊POST1