!------------------------------------------------------
!EX8.27 鋼筋混凝土簡支梁數值分析
!整體式模型,打開壓碎,keyopt(1)=0,keyopt(7)=1
!力加載,位移收斂準則，誤差1.5%,1/4模型分析
!--------------------------------------------
finish
/clear
/config,nres,2000
/prep7
!1.定義單元與材料性質--------------------
et,1,solid65,,,,,,,1
mp,ex,1,13585
mp,prxy,1,0.2
mp,ex,2,2.0e5
mp,prxy,2,0.3
fc=14.3
ft=1.43
tb,concr,1
tbdata,,0.5,0.95,ft,fc
tb,miso,1,,11
tbpt,,0.0002,fc*0.19
tbpt,,0.0004,fc*0.36
tbpt,,0.0006,fc*0.51
tbpt,,0.0008,fc*0.64
tbpt,,0.001,fc*0.75
tbpt,,0.0012,fc*0.84
tbpt,,0.0014,fc*0.91
tbpt,,0.0016,fc*0.96
tbpt,,0.0018,fc*0.99
tbpt,,0.002,fc
tbpt,,0.0033,fc*0.85
tb,biso,2
tbdata,,300,0
pi=acos(-1)
v1=0.25*pi*22*22*1.5/(75*60)
v2=0.25*pi*10*10/(75*60)
v3=0.25*pi*10*10*9.5/(1000*75)
v4=0.25*pi*10*10*9.5/(1000*60)
r,1,2,v1,0,90,2,v4
rmore,0,0,2,v3,90,0
r,2,2,v2,0,90,2,v4
rmore,0,0,2,v3,90,0
r,3,2,v3,90,0
!2.創建幾何模型
blc4,,,150/2,300,2000/2
wprota,,-90
wpoff,,,60
vsbw,all
wpoff,,,180
vsbw,all
wpcsys,-1
wpoff,,,50
vsbw,all
wpoff,,,850
vsbw,all
wpcsys,-1
!3.定義屬性劃分網格
elemsiz=50
vsel,s,loc,y,0,60
vatt,1,1,1
vsel,s,loc,y,240,300
vatt,1,2,1
vsel,s,loc,y,60,240
vatt,1,3,1
vsel,all
mshkey,1
esize,elemsiz
vmesh,all
!device,vector,on
!/eshape,1
!eplot
!4.施加荷載和約束
lsel,s,loc,y,0
lsel,r,loc,z,900
dl,all,,uy
asel,s,loc,z,0
da,all,symm
asel,s,loc,x,75
da,all,symm
!-----------------
p0=180000
q0=p0/150/100
asel,s,loc,z,0,50
asel,r,loc,y,300
sfa,all,1,pres,q0
allsel,all
!5.求解控制設置
/solu
antype,0
nsubst,50
outres,all,all
autos,on
neqit,50
cnvtol,u,,0.015
solve

!6.進入POST1查看結果
/post1
set,last
pldisp,1
etable,reb1,smisc,2
pletab,reb1
/device,vector,on
plcrack
!7.進入時程后處理
/post26
nsol,2,69,u,y
prod,3,2,,,,,,-1
prod,4,1,,,,,,p0/1000
xvar,3
plvar,4