<!--#include file = "Startup.asp"-->
<%

' ======================
' 功能：修改信息保存頁
' 描述：對(duì)modify.asp文件提交過來的表單數(shù)據(jù)進(jìn)行保存操作，有保存信息標(biāo)題，信息內(nèi)容，信息標(biāo)題圖片；
'       同時(shí)保存所有此篇信息所有相關(guān)的上傳或遠(yuǎn)程獲取的文件信息，有源文件名，保存文件名，保存路徑文件名。
' ======================

Call Header("修改信息保存")
Call Content()
Call Footer()


' 本頁內(nèi)容區(qū)
Sub Content()
	Dim i

	' 傳入?yún)?shù)：信息ID
	Dim sNewsID
	sNewsID = Trim(Request("id"))

	' 信息ID有效性驗(yàn)證，防止有些人惡意的破壞此演示程序
	If IsNumeric(sNewsID) = False Then
		GoError "請(qǐng)通過頁面上的鏈接進(jìn)行操作，不要試圖破壞此演示系統(tǒng)。"
	End If

	' 取提交過來的數(shù)據(jù)
	' 注意取信息內(nèi)容的方法，因?yàn)閷?duì)大表單的自動(dòng)處理，一定要使用循環(huán)，否則大于100K的內(nèi)容將取不到，單個(gè)表單項(xiàng)的限制為102399字節(jié)（100K左右）
	Dim sTitle, sContent, sPicture
	sTitle = Request.Form("d_title")
	sPicture = Request.Form("d_picture")


	' 開始：eWebEditor編輯區(qū)取值-----------------
	sContent = ""
	For i = 1 To Request.Form("d_content").Count
		sContent = sContent & Request.Form("d_content")(i)
	Next
	' 結(jié)束：eWebEditor編輯區(qū)取值-----------------	


	' 以下為所有通過編輯器上傳的所有文件相關(guān)信息，包括編輯區(qū)手動(dòng)上傳的和自動(dòng)遠(yuǎn)程上傳的
	' GetSafeStr函數(shù)為過濾一些特殊字符，防止有些人惡意的破壞此演示程序
	' 上傳或遠(yuǎn)程獲取前的原文件名，多個(gè)以"|"分隔
	Dim sOriginalFileName
	' 上傳后保存到本地服務(wù)器的文件名（不帶路徑），多個(gè)以"|"分隔
	Dim sSaveFileName
	' 上傳后保存到本地服務(wù)器的路徑文件名，多個(gè)以"|"分隔
	Dim sSavePathFileName
	sOriginalFileName = GetSafeStr(Request.Form("d_originalfilename"))
	sSaveFileName = GetSafeStr(Request.Form("d_savefilename"))
	sSavePathFileName = GetSafeStr(Request.Form("d_savepathfilename"))


	' 修改指定信息內(nèi)容
	sSql = "SELECT * FROM NewsData WHERE D_ID=" & sNewsID
	oRs.Open sSql, oConn, 1, 3
	If Not oRs.Eof Then
		oRs("D_Title") = sTitle
		oRs("D_Content") = sContent
		oRs("D_Picture") = sPicture
		oRs("D_OriginalFileName") = sOriginalFileName
		oRs("D_SaveFileName") = sSaveFileName
		oRs("D_SavePathFileName") = sSavePathFileName
		oRs.Update
	Else
		GoError "無效的信息ID，請(qǐng)點(diǎn)頁面上的鏈接進(jìn)行操作！"
	End If
	oRs.Close

	' 輸出成功保存信息
	Response.Write "信息（ID：" & sNewsID & "）修改保存成功！"

End Sub

%>