<!--#include file = "Startup.asp"-->
<%

' ======================
' 功能：增加信息保存頁
' 描述：對add.asp文件提交過來的表單數據進行保存操作，有保存信息標題，信息內容，信息標題圖片；
'       同時保存所有此篇信息所有相關的上傳或遠程獲取的文件信息，有源文件名，保存文件名，保存路徑文件名。
' ======================

Call Header("增加信息保存")
Call Content()
Call Footer()


' 本頁內容區
Sub Content()
	Dim i

	' 取提交過來的數據
	' 注意取信息內容的方法，因為對大表單的自動處理，一定要使用循環，否則大于100K的內容將取不到，單個表單項的限制為102399字節（100K左右）
	Dim sTitle, sContent, sPicture
	sTitle = Request.Form("d_title")
	sPicture = Request.Form("d_picture")

	' 開始：eWebEditor編輯區取值-----------------
	sContent = ""
	For i = 1 To Request.Form("d_content").Count
		sContent = sContent & Request.Form("d_content")(i)
	Next
	' 結束：eWebEditor編輯區取值-----------------
	

	' 以下為所有通過編輯器上傳的所有文件相關信息，包括編輯區手動上傳的和自動遠程上傳的
	' GetSafeStr函數為過濾一些特殊字符，防止有些人惡意的破壞此演示程序
	' 上傳或遠程獲取前的原文件名，多個以"|"分隔
	Dim sOriginalFileName
	' 上傳后保存到本地服務器的文件名（不帶路徑），多個以"|"分隔
	Dim sSaveFileName
	' 上傳后保存到本地服務器的路徑文件名，多個以"|"分隔
	Dim sSavePathFileName
	sOriginalFileName = GetSafeStr(Request.Form("d_originalfilename"))
	sSaveFileName = GetSafeStr(Request.Form("d_savefilename"))
	sSavePathFileName = GetSafeStr(Request.Form("d_savepathfilename"))

	' 保存信息內容，同時取出自增的信息ID
	Dim sNewsID
	sSql = "SELECT * FROM NewsData WHERE D_ID=0"
	oRs.Open sSql, oConn, 1, 3
	oRs.AddNew
	oRs("D_Title") = sTitle
	oRs("D_Content") = sContent
	oRs("D_Picture") = sPicture
	oRs("D_OriginalFileName") = sOriginalFileName
	oRs("D_SaveFileName") = sSaveFileName
	oRs("D_SavePathFileName") = sSavePathFileName
	oRs.Update
	sNewsID = oRs("D_ID")
	oRs.Close
	
	' 輸出成功保存信息
	Response.Write "信息（ID：" & sNewsID & "）增加保存成功！"

End Sub

%>