!1.1  鉸接桿在外力作用下的變形
! 本程序來源于邢靜忠等編著的《ANSYS分析實例與工程應用》，機械工業出版社（2004年）
FINISH
/CLEAR,NOSTART
! (1) 設置工程的選項, 定義幾何參數
/FileName, EX1.1
/TITLE, EX1.1, DEFLECTION OF A HINGED SUPPORT
*AFUN,DEG
THETA=30
A=10000
B=A/2*TAN(THETA)
! (2) 進入前處理模塊, 定義節點
/PREP7
N,1
N,2,A/2,-B
N,3,A
! (3) 在前處理模塊中,定義單元類型,材料參數和各個單元
ET,1,LINK1
R,1,1000
MP,EX,1,210E3
E,1,2
E,2,3
! (4) 在前處理模塊中,定義位移約束
D,1,ALL,,,3,2
F,2,FY,-1000
OUTPR,,1
FINISH
! (5) 進入求解模塊,開始求解
/SOLU
SOLVE
FINISH
! (6) 進入后處理模塊,顯示節點位移和桿件內力
/POST1
PLDISP,2
MID_NODE = NODE (A/2,-B,0 )

*GET,DISP,NODE,MID_NODE,U,Y
LEFT_EL = ENEARN (MID_NODE)
ETABLE,STRS,LS,1
*GET,STRSS,ELEM,LEFT_EL,ETAB,STRS
! (7) 申明數組,提取計算結果,并比較計算誤差
*DIM,LABEL,CHAR,2
*DIM,VALUE,,2,3
LABEL(1) = 'STRS_MPa','DEF_mm'
*VFILL,VALUE(1,1),DATA,1,-0.05498
*VFILL,VALUE(1,2),DATA,STRSS,DISP
*VFILL,VALUE(1,3),DATA,ABS(STRSS /1 ) ,ABS( DISP /0.05498 )
/OUT,EX1_1,out
/COM
/COM,------------------- EX1.1 RESULTS COMPARISON ---------------------
/COM,
/COM,         |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1),VALUE(1,1),VALUE(1,2),VALUE(1,3),(1X,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,----------------------------------------------------------------
/OUT
FINISH
*LIST,EX1_1,out