!4.3  用實體單元分析變截面桿的拉伸
! 本程序來源于邢靜忠等編著的《ANSYS分析實例與工程應用》，機械工業出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1)設置工程選項,定義分析類型,單元類型和材料參數
/FileName,EX4.3
/PREP7
smrt,off
/TITLE, EX4.3, ELONGATION OF A SOLID BAR WITH VARIED SECTION
/COM    INTROD. TO STRESS ANALYSIS, HARRIS, 1ST ED., PAGE 237, PROB. 4
ANTYPE,STATIC
ET,1,SOLID45
MP,EX,1,70.71E3
MP,NUXY,1,0.3
! (2)定義固定端4個點和自由端4個點，過這8個點定義體，對體劃分單元
/VIEW,1,1,1,1
K,1,25.4,,25.4
K,2,-25.4,,25.4
K,3,-25.4,,-25.4
K,4,25.4,,-25.4
K,5,12.7,254,12.7
K,6,-12.7,254,12.7
K,7,-12.7,254,-12.7
K,8,12.7,254,-12.7
V,1,2,3,4,5,6,7,8
LSEL,S,LINE,,5,11,2
LESIZE,ALL,,,7
LSEL,ALL
ESIZE,,1
/OUT,SCRATCH
VMESH,1
/OUT
! (3)施加位移約束和荷載
OUTPR,BASIC,ALL
NSEL,S,LOC,Y,0
D,ALL,ALL
NSEL,ALL
NSEL,S,LOC,Y,254
SF,,PRES,-68.949
NSEL,ALL
FINISH
! (4)在求解模塊，開始靜力分析的求解
/SOLU
SOLVE
FINISH
! (5)在后處理模塊中，顯示Y方向應力云圖
/POST1
ETABLE,SIGY,S,Y
/VIEW,1,1
/VUP,1,-Y
NSLE,S
PLNSOL,S,Y
ESEL,S,ELEM,,4
PRETAB,SIGY
PRNSOL,S,COMP
ESEL,ALL
NSEL,S,LOC,Y,254
PRNSOL,DOF
NSEL,ALL
! (6)選擇指定位置的節點和單元，并提取它們的位移和應力
/NOPR
MID_NODE = NODE(0,128,0)
MID_ELM = ENEARN(MID_NODE)
BOT_NODE = NODE (0,254,0)
*GET,DEF,NODE,BOT_NODE,U,Y
*GET,STRSS,ELEM,MID_ELM,ETAB,SIGY
! (7)定義數組變量，將計算結果通過數組變量輸出到文件
*DIM,LABEL,CHAR,2,2
*DIM,VALUE_C1,,2,3
LABEL(1,1) = 'MAX DEF ','SIGY MID'
LABEL(1,2) = '(mm)    ','_ELM MPa'
*VFILL,VALUE_C1(1,1),DATA,0.12384,30.644
*VFILL,VALUE_C1(1,2),DATA,DEF,STRSS
*VFILL,VALUE_C1(1,3),DATA,ABS(DEF/0.12384) ,ABS(STRSS/30.644)
/GOPR
FINISH
/COM
/OUT, EX4_3, out
/COM,-------------------  EX4.3 RESULTS COMPARISON ---------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
/COM,RESULTS FOR SOLID45:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,'   ',F12.7,'  ',F12.7,'   ',1F5.3)
/NOPR
/COM,-----------------------------------------------------------
/OUT
FINISH
*LIST, EX4_3, out
/DELETE,SCRATCH
FINISH