!8.3  有軸向壓力作用的簡支梁的自由振動
! 本程序來源于邢靜忠等編著的《ANSYS分析實例與工程應用》，機械工業出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 定義工程選項,分析類型,單元類型,實常數和材料參數
/FileName, EX8.3
/PREP7
/TITLE, EX8.3, LATERAL VIBRATION OF AN AXIALLY LOADED BAR
C***    VIBRATION PROBS. IN ENGR., TIMOSHENKO, 3RD. ED., PAGE 374, ART. 59
ANTYPE,STATIC
PSTRES,ON
ET,1,BEAM4
R,1,25.81E-4,55.493E-8,55.493E-8,50.8E-3,50.8E-3     度50.8E-3 m.
MP,EX,1,207E9
MP,DENS,1,7781
MP,PRXY,,0.3
! (2) 定義節點位置和單元連接
N,1
N,14,2.032
FILL
E,1,2
EGEN,13,1,1
! (3) 施加位移約束和荷載
D,1,UY,,,14,,ROTX,ROTZ
D,1,UX,,,,,UZ
D,14,UZ
F,14,FX,-177932
M,2,UZ,13
FINISH
! (4) 進入求解模塊,指定求解選項并求解
/SOLU
OUTPR,BASIC,1
SOLVE
FINISH
! (5) 進入一般后處理模塊,提取頻率計算結果
/POST1
ETABLE,STRS,LS,1
*GET,STRSS,ELEM,13,ETAB,STRS
*GET,DEF,NODE,14,U,X
! (6) 重新進入求解模塊,用另外一種模態求解方法求解
/SOLU
ANTYPE,MODAL
PSTRES,ON
MXPAND,3
MODOPT,LANB,3
SOLVE
! (7) 提取頻率計算結果
*GET,FREQ1,MODE,1,FREQ
*GET,FREQ2,MODE,2,FREQ
*GET,FREQ3,MODE,3,FREQ
! (8) 定義數組變量,將計算結果輸出到文本文件
*DIM,LABEL,CHAR,5,2
*DIM,VALUE,,5,3
LABEL(1,1) = 'DEFLECTI','SIGMA,  ','f1,     ','f2,     ','f3,     '
LABEL(1,2) = 'ON, (mm)','   (MPa)','    (Hz)','    (Hz)','    (Hz)'
*VFILL,VALUE(1,1),DATA,-0.67674,-68.94,17.069,105.352,249.446
*VFILL,VALUE(1,2),DATA,DEF*1000,STRSS/1e6,FREQ1,FREQ2,FREQ3
*VFILL,VALUE(1,3),DATA,ABS(DEF*1000/0.67674),ABS(STRSS*1e-6/68.94),ABS(FREQ1/17.069)
*VFILL,VALUE(4,3),DATA,ABS(FREQ2/105.352),ABS(FREQ3/249.446)
/COM
/OUT, EX8_3, out
/COM,-------------------  EX8.3 RESULTS COMPARISON ---------------
/COM,
/COM,                     |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F14.3,'  ',F14.3,'   ',1F5.3)
/COM,-----------------------------------------------------------
/COM,
/OUT
FINISH
*LIST, EX8_3, out