!12.1  四邊簡支方形層合板在均布外載作用下的變形
! 本程序來源于邢靜忠等編著的《ANSYS分析實例與工程應用》，機械工業出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 設置工程選項,分析類型,單元類型和材料參數
/FILENAME,EX12.1
/PREP7
SMRT,OFF
/TITLE, EX12.1, SIMPLY SUPPORTED LAMINATED PLATE UNDER PRESSURE(SHELL99)
C***    EXACT SOLUTIONS OF MODERATELY THICK LAMINATED SHELLS,
C***    J.N. REDDY, JNL. OF ENGR. MECHANICS, VOL 110, NO.5, MAY'84.
ANTYPE,STATIC
ET,1,SHELL99,,,,,,,1
R,1,4,1
RMORE
RMORE,1,0,.025,1,90,.025
MP,EX,1,25E6
MP,EY,1,1E6
MP,EZ,1,1E6
MP,GXY,1,5E5
MP,GYZ,1,2E5
MP,GXZ,1,5E5
MP,PRXY,1,0.01
MP,PRYZ,1,0.25
MP,PRXZ,1,0.01
! (2) 定義關鍵點,面,并將面劃分成面單元
K,1
K,2,5
K,3,5,5
K,4,,5
A,1,2,3,4
ESIZE,,3
/PNUM,NODE,1
AMESH,1
! (3) 選擇邊界點,施加位移邊界條件
NSEL,S,LOC,X,0
DSYM,SYMM,X
NSEL,S,LOC,Y,0
DSYM,SYMM,Y
NSEL,S,LOC,X,5
D,ALL,UZ,,,,,UY
NSEL,S,LOC,Y,5
D,ALL,UZ,,,,,UX
NSEL,ALL
SFE,ALL,2,PRES,,1
OUTPR,,1
FINISH
! (4) 在求解模塊求解
/SOLU
SOLVE
FINISH
! (5) 在后處理模塊顯示計算結果
/POST1
NSEL,S,LOC,X
NSEL,R,LOC,Y
PRNSOL,U,Z
*GET,DEF99,NODE,1,U,Z
! (6) 定義數組,將計算結果保存到這些數組
*DIM,LABEL_1,CHAR,1,2
*DIM,VALUE_1,,1,3
LABEL_1(1,1) = 'DEF,m (S'
LABEL_1(1,2) = 'ELL99)  '
*VFILL,VALUE_1(1,1),DATA,0.0683
*VFILL,VALUE_1(1,2),DATA,ABS(DEF99)
*VFILL,VALUE_1(1,3),DATA,ABS(DEF99/0.0683)
SAVE,INF1
FINISH
! (7) 改用8節點層合固體單元SOLID46重新計算
/CLEAR, NOSTART
/FILENAME,EX12.1B
/PREP7
SMRT,OFF
/TITLE, EX12.1B, SIMPLY SUPPORTED LAMINATED PLATE UNDER PRESSURE(SOLID46)
C***    EXACT SOLUTIONS OF MODERATELY THICK LAMINATED SHELLS,
C***    J.N. REDDY, JNL. OF ENGR. MECHANICS, VOL 110, NO.5, MAY'84.
ANTYPE,STATIC
ET,1,SOLID46,,,,,,,1
R,1,4,1
RMORE
RMORE,1,0,.025,1,90,.025
MP,EX,1,25E6
MP,EY,1,1E6
MP,EZ,1,1E6
MP,GXY,1,5E5
MP,GYZ,1,2E5
MP,GXZ,1,5E5
MP,PRXY,1,0.25
MP,PRYZ,1,0.25
MP,PRXZ,1,0.01
! (8) 定義關鍵點,面,并將面劃分成面單元
K,1
K,2,5
K,3,5,5
K,4,,5
KGEN,2,1,4,1,,,0.1
L,1,5
*REPEAT,4,1,1
LESIZE,ALL,,,1
/PNUM,NODE,1
/View,1,1,1,1
V,1,2,3,4,5,6,7,8
ESIZE,,6
VMESH,1
! (9) 選擇邊界點,施加位移邊界條件
NSEL,S,LOC,X,0
DSYM,SYMM,X
NSEL,S,LOC,Y,0
DSYM,SYMM,Y
NSEL,S,LOC,X,5
D,ALL,UZ,,,,,UY
NSEL,S,LOC,Y,5
D,ALL,UZ,,,,,UX
NSEL,ALL
SFE,ALL,6,PRES,,1
OUTPR,,1
FINISH
! (10) 在求解模塊求解
/SOLU
SOLVE
FINISH
! (11) 在后處理模塊顯示計算結果
/POST1
NSEL,S,LOC,X
NSEL,R,LOC,Y
PRNSOL,U,Z
*GET,DEF46,NODE,1,U,Z
! (12) 定義數組,將計算結果保存到這些數組
*DIM,LABEL_2,CHAR,1,2
*DIM,VALUE_2,,1,3
LABEL_2(1,1) = 'DEF,m (S'
LABEL_2(1,2) = 'OLID46)  '
*VFILL,VALUE_2(1,1),DATA,0.0683
*VFILL,VALUE_2(1,2),DATA,ABS(DEF46)
*VFILL,VALUE_2(1,3),DATA,ABS(DEF46/0.0683)
SAVE,INF2
FINISH
! (13) 改用8節點層合固體單元SOLID191重新計算
/CLEAR, NOSTART
/FILENAME,EX12.1C
/PREP7
SMRT,OFF
/TITLE, EX12.1C, SIMPLY SUPPORTED LAMINATED PLATE UNDER PRESSURE(SOLID191)
C***    EXACT SOLUTIONS OF MODERATELY THICK LAMINATED SHELLS,
C***    J.N. REDDY, JNL. OF ENGR. MECHANICS, VOL 110, NO.5, MAY'84.
ANTYPE,STATIC
ET,1,SOLID191,,,,,,,1
R,1,4,1
RMORE
RMORE,1,0,0.25,1,90,0.25
MP,EX,1,25E6
MP,EY,1,1E6
MP,EZ,1,1E6
MP,GXY,1,5E5
MP,GYZ,1,2E5
MP,GXZ,1,5E5
MP,PRXY,1,0.25
MP,PRYZ,1,0.25
MP,PRXZ,1,0.01
! (14) 定義板邊的關鍵點
K,1
K,2,5
K,3,5,5
K,4,,5
KGEN,2,1,4,1,,,0.1
L,1,5
*REPEAT,4,1,1
LESIZE,ALL,,,1
/PNUM,NODE,1
/View,1,1,1,1
V,1,2,3,4,5,6,7,8
ESIZE,,6
VMESH,1
! (15) 選擇邊界點,施加位移邊界條件
NSEL,S,LOC,X,0
DSYM,SYMM,X
NSEL,S,LOC,Y,0
DSYM,SYMM,Y
NSEL,S,LOC,X,5
D,ALL,UZ,,,,,UY
NSEL,S,LOC,Y,5
D,ALL,UZ,,,,,UX
NSEL,ALL
SFE,ALL,6,PRES,,1
OUTPR,,1
FINISH
! (16) 在求解模塊求解
/SOLU
SOLVE
FINISH
! (17) 在后處理模塊顯示計算結果
/POST1
NSEL,S,LOC,X
NSEL,R,LOC,Y
PRNSOL,U,Z
*GET,DEF191,NODE,1,U,Z
! (18) 定義數組,將計算結果保存到這些數組
*DIM,LABEL_2,CHAR,1,2
*DIM,VALUE_2,,1,3
LABEL_2(1,1) = 'DEF,m (S'
LABEL_2(1,2) = 'OLID191)  '
*VFILL,VALUE_2(1,1),DATA,0.0683
*VFILL,VALUE_2(1,2),DATA,ABS(DEF191)
*VFILL,VALUE_2(1,3),DATA,ABS(DEF191/0.0683)
SAVE,INF3
! (19) 從數據庫中恢復數據,輸出到文件
RESUME,INF1
/COM
/OUT,EX12_1,out
/COM,------------------- EX12.1 RESULTS COMPARISON --------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
*VWRITE,LABEL_1(1,1),LABEL_1(1,2),VALUE_1(1,1),VALUE_1(1,2),VALUE_1(1,3)
(1X,A8,A8,'   ',F10.4,'  ',F10.4,'   ',1F5.3)
/NOPR
RESUME,INF2
/GOPR
/NOPR
/COM.
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,'   ',F10.4,'  ',F10.4,'   ',1F5.3)
RESUME, INF3
/GOPR
*VWRITE,LABEL_2(1,1),LABEL_2(1,2),VALUE_2(1,1),VALUE_2(1,2),VALUE_2(1,3)
(1X,A8,A8,'   ',F10.4,'  ',F10.4,'   ',1F5.3)
/COM,----------------------------------------------------------
/OUT
FINISH
*LIST,EX12_1,out