!6.2  懸臂長板的大撓度彎曲
! 本程序來源于邢靜忠等編著的《ANSYS分析實例與工程應(yīng)用》，機械工業(yè)出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1)設(shè)置工程參數(shù),分析類型,單元類型,實常數(shù)和材料參數(shù)
/FILNAM, EX6.2
/PREP7
/TITLE, EX6.2  LARGE DEFLECTION OF A CANTILEVERED PLATE
/COM   REF: BATHE AND DVORKIN, " A FORMULATION OF GENERAL SHELL ELEMENTS... "
/COM        IJNME, VOL 22, NO. 3 (1986) PAGE 720
/NOPR
SMRT,OFF
ANTYPE,STATIC
NLGEOM,ON
ET,1,SHELL43
R,1,1
MP,EX,1,1800
MP,NUXY,,0
! (2)定義關(guān)鍵點,線和面,并劃分為面單元
K,1
K,2,12
K,3,12,1
K,4,,1
L,1,2
L,3,4
LESIZE,ALL,,,2
ESIZE,,1
A,1,2,3,4
/VIEW,1,0.61,-0.64,0.47
/VUP,1,Z
AMESH,1
! (3)施加位移約束和荷載力
NSEL,S,LOC,X
D,ALL,ALL
NSEL,S,LOC,X,12
CP,1,ROTY,ALL
TORQ=15.708
F,2,MY,TORQ
NSEL,ALL
FINISH
! (4)進入求解選模塊,設(shè)置求解選項后,開始求解
/SOLU
AUTOTS,ON
NSUBST,20
LNSRCH,ON
OUTPR,BASIC,LAST
OUTRES,ALL,ALL
SOLVE
FINISH
! (5)在后處理模塊,顯示應(yīng)力和位移計算結(jié)果
/POST1
RSYS,SOLU
SET,1
SHELL,TOP
PRNSOL,S,COMP
PRNSOL,DOF
! (6)提取結(jié)果后存入變量
*GET,UX_N4,NODE,4,U,X
*GET,UZ_N4,NODE,4,U,Z
*GET,ROTY_N4,NODE,4,ROT,Y
*GET,STRSS_N1,NODE,1,S,X
! (7)定義數(shù)組變量,保存計算結(jié)果后輸出到文件
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'UX,NODE ','UZ,NODE ','ROTY,NOD','STS_X,N_'
LABEL(1,2) = '4 (mm)  ','4 (mm)  ','E 4(rad)','1 N/mm^2'
*VFILL,VALUE(1,1),DATA,-2.92,-6.60,1.26,94.25
*VFILL,VALUE(1,2),DATA,UX_N4,UZ_N4,ROTY_N4,STRSS_N1
*VFILL,VALUE(1,3),DATA,ABS(UX_N4/2.92),ABS(UZ_N4/6.60),ABS(ROTY_N4/1.26),ABS(STRSS_N1/94.25)
SAVE, TABLE_1
FINISH
! (8)重用改用有限應(yīng)變層合殼單元SHELL181計算
/CLEAR,NOSTART
/FILNAM, EX6.2
/PREP7
/TITLE, EX6.2  LARGE DEFLECTION OF A CANTILEVERED PLATE(SHELL181)
/PREP7
smrt,off
/NOPR
ANTYPE,STATIC
NLGEOM,ON
ET,1,SHELL181
R,1,1
RMORE,,,,,10.0
MP,EX,1,1800
MP,NUXY,,0
! (9)定義關(guān)鍵點,線和面,并將面劃分為面單元
K,1
K,2,12
K,3,12,1
K,4,,1
L,1,2
L,3,4
LESIZE,ALL,,,2
ESIZE,,1
A,1,2,3,4
AMESH,1
! (10) 施加位移約束和荷載力
NSEL,S,LOC,X
D,ALL,ALL
NSEL,S,LOC,X,12
CP,1,ROTY,ALL
TORQ=7.854
F,2,MY,TORQ
NSEL,ALL
FINISH
! (11) 進入求解選模塊,設(shè)置求解選項后,開始求解
/SOLU
AUTOTS,ON
NSUBST,10
LNSRCH,ON
OUTPR,BASIC,LAST
OUTRES,ALL,ALL
SOLVE
FINISH
! (12)在求解模塊重啟動分析
/SOLU
ANTYPE,,REST
F,2,MY,TORQ*2
SOLVE
FINISH
! (13)在后處理模塊,顯示計算結(jié)果
/POST1
RSYS,SOLU
SET,2
SHELL,TOP
PRNSOL,S,COMP
PRNSOL,DOF
*GET,UX_N4,NODE,4,U,X
*GET,UZ_N4,NODE,4,U,Z
*GET,ROTY_N4,NODE,4,ROT,Y
*GET,STRSS_N1,NODE,1,S,X
! (14) 定義數(shù)組變量,保存計算結(jié)果后輸出到文件
*DIM,LABEL,CHAR,4,2
*DIM,VALUE,,4,3
LABEL(1,1) = 'UX,NODE','UZ,NODE','ROTY,NOD','STS_X,N_'
LABEL(1,2) = '4 (mm) ','4 (mm) ','E 4(rad)','1 N/mm^2'
*VFILL,VALUE(1,1),DATA,-2.92,-6.60,1.26,94.25
*VFILL,VALUE(1,2),DATA,UX_N4,UZ_N4,ROTY_N4,STRSS_N1
*VFILL,VALUE(1,3),DATA,ABS(UX_N4/2.9),ABS(UZ_N4/6.5),ABS(ROTY_N4/1.26),ABS(STRSS_N1/94.25)
SAVE, TABLE_2
! (15)從數(shù)據(jù)庫中恢復(fù)數(shù)據(jù)后,保存到文件
RESUME,TABLE_1
/COM
/COM
/OUT, EX6_2, out
/COM,-------------------  EX6.2 RESULTS COMPARISON ---------------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
/COM,SHELL43:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.2,'  ',F10.2,'   ',1F5.2)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM,SHELL181:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F10.2,'  ',F10.2,'   ',1F5.2)
/COM,-----------------------------------------------------------------
/OUT
FINISH
/DELETE,TABLE_1
/DELETE,TABLE_2
FINISH
*LIST, EX6_2, out