!6.1  簡支和固支圓板的在不同荷載作用下的彎曲
! 本程序來源于邢靜忠等編著的《ANSYS分析實例與工程應用》，機械工業出版社（2004年）
FINISH
/CLEAR, NOSTART
! (1) 設置工程參數,分析類型,單元類型,實常數和材料參數
/FileName, EX6.1
/PREP7
/TITLE, EX6.1, BENDING OF A CIRCULAR PLATE USING AXISYMMETRIC SHELL ELEMENTS
C***  CASE 1 - STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 96, ART. 19
C***  CASE 2 - STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 103, ART. 21
C***  CASE 3 - STR. OF MATLS., TIMOSHENKO, PART 2, 3RD ED., PAGE 97, ART. 19
ANTYPE,STATIC
ET,1,SHELL51
R,1,25.4
MP,EX,1,207E3
MP,NUXY,1,0.3
! (2) 定義關鍵點,線和面,并劃分為面單元
K,1
K,2,1016
K,3,508
L,1,3
L,3,2
LESIZE,1,,,5,20
LESIZE,2,,,5,.05
LMESH,ALL
/PNUM,ELEM,1
EPLOT
FINISH
! (3)按第1種情況計算:均布荷載,固定端
C***  CASE 1 - UNIFORM LOADING - CLAMPED EDGE
/SOLU
OUTPR,,1
DK,1,UX,,,,ROTZ
DK,2,ALL
SFE,ALL,1,PRES,,0.041370
SOLVE
! (4)按第2種情況計算:中心集中荷載,簡支邊
C***  CASE 2 - CONCENTRATED CENTER LOADING - CLAMPED EDGE
FK,1,FY,33539
SFE,ALL,1,PRES,,0
SOLVE
! (5) 按第3種情況計算:均布荷載,簡支邊
C***  CASE 3 - UNIFORM LOADING - SIMPLY SUPPORTED EDGE
DKDELE,2,ROTZ
FK,1,FY
SFE,ALL,1,PRES,,0.010343
SOLVE
FINISH
! (6)在后處理模塊中顯示變形情況
/POST1
/DSCALE,1,35
/WINDOW,1,-1,1,-1,-.333
SET,1,1
PLDISP,1
MID_NODE = NODE (0,0,0)
*GET,DEF_C1,NODE,MID_NODE,U,Y
ETABLE,STRS,LS,9
*GET,STRSS_C1,ELEM,10,ETAB,STRS
! (7)讀入第2荷載步的計算結果,顯示變形圖
/WINDOW,1,OFF
/WINDOW,2,-1,1,-.333,.333,1
/NOERASE
SET,2,1
PLDISP
*GET,DEF_C2,NODE,MID_NODE,U,Y
ETABLE,STRS,LS,9
*GET,STRSS_C2,ELEM,10,ETAB,STRS
! (8) 讀入第3荷載步的計算結果,顯示變形圖
/WINDOW,2,OFF
/WINDOW,3,-1,1,.333,1,1
SET,3,1
PLDISP
*GET,DEF_C3,NODE,MID_NODE,U,Y
ETABLE,STRS,LS,9
*GET,STRSS_C3,ELEM,1,ETAB,STRS
! (9) 定義數組變量,保存計算結果后輸出到文件
*DIM,LABEL,CHAR,2,2
*DIM,VALUE_C1,,2,3
*DIM,VALUE_C2,,2,3
*DIM,VALUE_C3,,2,3
LABEL(1,1) = 'DEFLECTI','MAX STRS'
LABEL(1,2) = 'ON (mm) ','S (MPa) '
*VFILL,VALUE_C1(1,1),DATA,-2.217,49.644
*VFILL,VALUE_C1(1,2),DATA,DEF_C1,ABS(STRSS_C1)
*VFILL,VALUE_C1(1,3),DATA,ABS(DEF_C1/2.217),ABS(STRSS_C1/49.644)
*VFILL,VALUE_C2(1,1),DATA,-2.217,24.82
*VFILL,VALUE_C2(1,2),DATA,DEF_C2,ABS(STRSS_C2)
*VFILL,VALUE_C2(1,3),DATA,ABS(DEF_C2/2.217),ABS(STRSS_C2/24.82)
*VFILL,VALUE_C3(1,1),DATA,-2.26,20.48
*VFILL,VALUE_C3(1,2),DATA,DEF_C3,ABS(STRSS_C3)
*VFILL,VALUE_C3(1,3),DATA,ABS(DEF_C3/2.26),ABS(STRSS_C3/20.48)
/COM
/OUT, EX6_1, out
/COM,-------------------  EX6.1 RESULTS COMPARISON ---------------------
/COM,
/COM,                 |   TARGET   |   ANSYS   |   RATIO
/COM,
/COM,RESULTS FOR CASE 1:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C1(1,1),VALUE_C1(1,2),VALUE_C1(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,
/COM,RESULTS FOR CASE 2:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C2(1,1),VALUE_C2(1,2),VALUE_C2(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,
/COM,RESULTS FOR CASE 3:
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE_C3(1,1),VALUE_C3(1,2),VALUE_C3(1,3)
(1X,A8,A8,'   ',F10.3,'  ',F10.3,'   ',1F5.3)
/COM,-----------------------------------------------------------------
/OUT
FINISH
*LIST, EX6_1, out