!2.4  懸臂梁的雙向彎曲
! 本程序來源于邢靜忠等編著的《ANSYS分析實例與工程應用》，機械工業(yè)出版社（2004年）
Finish
/CLEAR, START
/FileName,EX2.4
/PREP7
/TITLE, EX2.4(1), STRAIGHT CANTILEVER BEAM BY SOLID5 ELEMENT.
! (1) 利用SOLID5單元計算懸臂梁的組合變形
C***  USING SOLID5 HEXAHEDRONS
ANTYPE,STATIC
ET,1,SOLID5,2
MP,EX,1,69E3
MP,NUXY,1,0.3
! (2) 定義懸臂梁上的8個的關鍵點
K,1
K,2,152.4
! 用關鍵點生成命令KGEN, ITIME, NP1, NP2, NINC, DX, DY, DZ, KINC 生成其它關鍵點
KGEN,2,1,2,1,,5.08
KGEN,2,1,4,1,,,2.54
! 上面兩行命令完成了節(jié)點3到4的定義和節(jié)點5到8的位置定義
! (3) 定義一條邊線，制定這條線劃分單元的個數和一般單元的尺寸
L,1,2
smrt,off
LESIZE,ALL,,,10
ESIZE,25.4
V,1,2,4,3,5,6,8,7
VMESH,1
! (4) 選擇左側截面處的所有節(jié)點，并固定這些節(jié)點。在右側的所有節(jié)點上施加集中力
NSEL,S,LOC,X,0
D,ALL,ALL
NSEL,ALL
FK,2,FX,4.4483/4
*REPEAT,4,2
NOORDER
FINISH
! (5) 求解在自由端拉力作用下懸臂梁的變形，主要是拉壓變形
/SOLU
SOLVE
! (6) 改變荷載，計算在Y方向的集中力作用下的情形
FKDELE,ALL,FX
FK,2,FY,4.4483/4
*REPEAT,4,2
SOLVE
! (7) 改變荷載，計算在Z方向的集中力作用下的情形
FKDELE,ALL,FY
FK,2,FZ,4.4483/4
*REPEAT,4,2
SOLVE
FINISH
! (8) 進入一般后處理模塊
/POST1
CSYS,0
! (9) 定義宏程序，完成自由端位移計算結果的處理
*CREATE,MAC
SET,ARG1,1
LCDEF,ARG1,ARG1
NSEL,S,LOC,X,152.4
PRNSOL,U,COMP
LCFACT,ARG1,ARG2
LCASE,ARG1
PRNSOL,U,COMP
*END
! (10) 使用上面定義的宏程序處理所有的3個工況
/COM            ***
*USE,MAC,1,(1/7.6E-4)
SET,1,1
LCSEL,S,0,0
N1=NODE(152.4 , 0, 0)
*GET,UX1,NODE,N1,U,X
! (11) 處理第2個荷載步的計算結果
*USE,MAC,2,(1/2.4712)
SET,2,1
LCSEL,S,0,0
*GET,UY1,NODE,N1,U,Y
! (12) 處理第3個荷載步的計算結果
*USE,MAC,3,(1/10.9646)
SET,3,1
LCSEL,S,0,0
*GET,UZ1,NODE,N1,U,Z
! (13) 定義字符串變量和相應的理論計算結果
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DEFL X ','DEFL Y ','DEFL Z '
LABEL(1,2) = 'mm','mm','mm'
*VFILL,VALUE(1,1),DATA,7.6E-4,2.471,10.965
*VFILL,VALUE(1,2),DATA,UX1,UY1,UZ1
*VFILL,VALUE(1,3),DATA,ABS(UX1/(7.6E-4)),ABS(UY1/2.471),ABS(UZ1/10.965)
SAVE, TABLE_1
FINISH
!
! (14) 改變單元類型，重新分析矩形截面懸臂梁在端部集中力作用下的變形
/CLEAR, NOSTART
/PREP7
/TITLE, EX2.4(2), STRAIGHT CANTILEVER BEAM by SOLID92 ELEMENT.
smrt,off
MOPT,VMESH,MAIN
MOPT,AMESH,ALTE
! (15) 使用10節(jié)點四面體單元SOLID92
ANTYPE,STATIC
ET,1,SOLID92
MP,EX,1,69E3
MP,PRXY,1,0.3
K,1
K,2,,5.08
KGEN,2,1,2,1,,,2.54
KGEN,2,1,4,1,152.4/9
ESIZE,25.4
V,1,2,4,3,5,6,8,7
VMESH,1
! (16) 利用第1塊體的單元模式，生成其余的8部分單元，定義固定端部的約束
VGEN,9,1,1,1,152.4/9,,,4
NSEL,S,LOC,X,0
D,ALL,ALL
SAVE
! (17) 獲取相應節(jié)點的編號，并在這些節(jié)點上施加荷載
/COM             *** GET NODE NUMBERS FOR LOAD APPLICATION ***
NSEL,S,LOC,X,152.4
NSEL,R,LOC,Y,2.54
NSEL,R,LOC,Z,1.27
*GET,MIDD,NDMX
NSEL,S,LOC,X,152.4
NSEL,R,LOC,Y,5.08
NSEL,R,LOC,Z,1.27
*GET,TOPP,NDMX
NSEL,S,LOC,X,152.4
NSEL,R,LOC,Y,0.0
NSEL,R,LOC,Z, 1.27
*GET,BOTT,NDMX
NSEL,S,LOC,X, 152.4
NSEL,R,LOC,Y, 2.54
NSEL,R,LOC,Z, 2.54
*GET,LFT,NDMX
NSEL,S,LOC,X,152.4
NSEL,R,LOC,Y, 2.54
NSEL,R,LOC,Z,.00
*GET,RGHT,NDMX
NSEL,ALL
! (18) 給上面選擇出的這些節(jié)點施加沿著X方向的軸向荷載
/COM         *** APPLY LOADS TO PARAMETRIC NODE NUMBERS ***
F,RGHT,FX, 4.4483/6
F,LFT,FX, 4.4483/6
F,TOPP,FX, 4.4483/6
F,BOTT,FX, 4.4483/6
F,MIDD,FX, 4.4483/3
FINISH
! (19) 對這種荷載情況進行計算
/SOLU
SOLVE
! (20) 改變荷載，給上面選擇出的這些節(jié)點施加沿著Y方向的軸向荷載，重新計算
FDELE,ALL
F,RGHT,FY, 4.4483/6
F,LFT,FY, 4.4483/6
F,TOPP,FY, 4.4483/6
F,BOTT,FY, 4.4483/6
F,MIDD,FY, 4.4483/3
SOLVE
! (21) 改變荷載，給上面選擇出的這些節(jié)點施加沿著Z方向的軸向荷載，重新計算
FDELE,ALL
F,RGHT,FZ, 4.4483/6
F,LFT,FZ, 4.4483/6
F,TOPP,FZ, 4.4483/6
F,BOTT,FZ, 4.4483/6
F,MIDD,FZ, 4.4483/3
SOLVE
FINISH
! (22) 在后處理模塊中，顯示位移計算結果和理論結果的比值
/POST1
/COM                   *** USE MACRO TO PROCESS ALL 3 LOADCASES  ***
! (23) 利用前面定義的宏，處理前面計算的3中荷載工況
*USE,MAC,1,(1/7.6E-4)
SET,1,1
LCSEL,S,0,0
N1=NODE(152.4,0,0)
*GET,UX2,NODE,N1,U,X
!
*USE,MAC,2,(1/2.4712)
SET,2,1
LCSEL,S,0,0
*GET,UY2,NODE,N1,U,Y
!
*USE,MAC,3,(1/.432)
SET,3,1
LCSEL,S,0,0
*GET,UZ2,NODE,N1,U,Z
!
! (24) 定義字符變量，比較理論結果和有限元結果的比值
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DEFL X ','DEFL Y ','DEFL Z '
LABEL(1,2) = 'in','in','in'
*VFILL,VALUE(1,1),DATA,7.6E-4,2.4712,10.9646
*VFILL,VALUE(1,2),DATA,UX2,UY2,UZ2
*VFILL,VALUE(1,3),DATA,ABS(UX2/(7.6E-4)),ABS(UY2/2.4712),ABS(UZ2/10.9646)
SAVE, TABLE_2
FINISH
!
! (25) 改變?yōu)?0節(jié)點四面體耦合場單元SOLID98，重新計算懸臂梁在端部集中力作用下的雙向彎曲
/CLEAR, NOSTART
/PREP7
/TITLE, EX2.4(3), STRAIGHT CANTILEVER BEAM by SOLID98 ELEMENT.
smrt,off
MOPT,VMESH,MAIN
MOPT,AMESH,ALTE
/COM                   *** REPEAT USING SOLID98 TETRAHEDRONS ***
RESUME
ET,1,SOLID98,2
! (26) 選擇邊界上的某些節(jié)點，施加約束和荷載
/COM         *** GET NODE NUMBERS FOR LOAD APPLICATION ***
NSEL,S,LOC,X,152.4
NSEL,R,LOC,Y,2.54
NSEL,R,LOC,Z,1.27
*GET,MIDD,NDMX
!
NSEL,S,LOC,X,152.4
NSEL,R,LOC,Y,5.08
NSEL,R,LOC,Z,1.27
*GET,TOPP,NDMX
!
NSEL,S,LOC,X,152.4
NSEL,R,LOC,Y,0.0
NSEL,R,LOC,Z, 1.27
*GET,BOTT,NDMX
!
NSEL,S,LOC,X, 152.4
NSEL,R,LOC,Y, 2.54
NSEL,R,LOC,Z, 2.54
*GET,LFT,NDMX
!
NSEL,S,LOC,X,152.4
NSEL,R,LOC,Y, 2.54
NSEL,R,LOC,Z,.00
*GET,RGHT,NDMX
NSEL,ALL
! (27) 給上面選擇出的這些節(jié)點施加沿著X方向的軸向荷載
/COM          *** APPLY LOADS TO PARAMETRIC NODE NUMBERS ***
F,RGHT,FX, 4.4483/6
F,LFT,FX, 4.4483/6
F,TOPP,FX, 4.4483/6
F,BOTT,FX, 4.4483/6
F,MIDD,FX, 4.4483/3
FINISH
! (28) 改變荷載，給上面選擇出的這些節(jié)點施加沿著Y方向的軸向荷載，重新計算
/SOLU
SOLVE
FDELE,ALL
F,RGHT,FY, 4.4483/6
F,LFT,FY, 4.4483/6
F,TOPP,FY, 4.4483/6
F,BOTT,FY, 4.4483/6
F,MIDD,FY, 4.4483/3
! (29) 改變荷載，給上面選擇出的這些節(jié)點施加沿著Z方向的軸向荷載，重新計算
SOLVE
FDELE,ALL
F,RGHT,FZ, 4.4483/6
F,LFT,FZ, 4.4483/6
F,TOPP,FZ, 4.4483/6
F,BOTT,FZ, 4.4483/6
F,MIDD,FZ, 4.4483/3
SOLVE
FINISH
! (30) 在后處理模塊中，顯示位移計算結果和理論結果的比值
/POST1
/COM                   *** USE MACRO TO PROCESS ALL 3 LOADCASES  ***
! (31) 利用前面定義的宏，處理前面計算的3中荷載工況
*USE,MAC,1,(1/7.6E-4)
SET,1,1
LCSEL,S,0,0
N1=NODE(152.4,0,0)
*GET,UX3,NODE,N1,U,X
!
*USE,MAC,2,(1/2.4712)
SET,2,1
LCSEL,S,0,0
*GET,UY3,NODE,N1,U,Y
!
*USE,MAC,3,(1/.432)
SET,3,1
LCSEL,S,0,0
*GET,UZ3,NODE,N1,U,Z
! (32) 定義字符變量，比較理論結果和有限元結果的比值
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DEFL X ','DEFL Y ','DEFL Z '
LABEL(1,2) = 'mm','mm','mm'
*VFILL,VALUE(1,1),DATA,7.6E-4,2.471,10.965
*VFILL,VALUE(1,2),DATA,UX3,UY3,UZ3
*VFILL,VALUE(1,3),DATA,ABS(UX3/(7.6E-4)),ABS(UY3/2.471),ABS(UZ3/10.965)
SAVE, TABLE_3
FINISH
!
! (33) 改變?yōu)?0節(jié)點四面體3D單元SOLID147，重新計算懸臂梁在端部集中力作用下的雙向彎曲
/CLEAR,NOSTART
/PREP7
/TITLE, EX2.4(4), STRAIGHT CANTILEVER BEAM by SOLID147 ELEMENT.
smrt,off
MOPT,VMESH,ALTE
MOPT,AMESH,ALTE
ANTYPE,STATIC
ET,1,SOLID147
MP,EX,1,69E3
MP,NUXY,1,0.3
! (34) 定義梁上的8個關鍵點
K,1
K,2,152.4
KGEN,2,1,2,1,,5.08
KGEN,2,1,4,1,,,2.54
! (35) 定義一條邊線，制定這條線劃分單元的個數和一般單元的尺寸
L,1,2
LESIZE,ALL,,,10
ESIZE, 25.4
V,1,2,4,3,5,6,8,7
VMESH,1
! (36) 選擇左側截面處的所有節(jié)點，并固定這些節(jié)點。在右側的所有節(jié)點上施加集中力
NSEL,S,LOC,X,0
D,ALL,ALL
NSEL,ALL
FK,2,FX,4.4483/4
*REPEAT,4,2
NOORDER
FINISH
! (37) 求解在自由端拉力作用下懸臂梁的變形，主要是拉壓變形
/SOLU
SOLVE
FKDELE,ALL,FX
FK,2,FY,1.1121
*REPEAT,4,2
SOLVE
FKDELE,ALL,FY
FK,2,FZ, 1.1121
*REPEAT,4,2
SOLVE
FINISH
! (38) 在后處理模塊中，列表顯示有限元計算結果和理論解的差別
/POST1
CSYS,0
! (39) 定義宏程序，完成自由端位移計算結果的處理
*CREATE,MAC
SET,ARG1,1
LCDEF,ARG1,ARG1
NSEL,S,LOC,X,152.4
PRNSOL,U,COMP
LCFACT,ARG1,ARG2
LCASE,ARG1
PRNSOL,U,COMP
*END
! (40) 使用上面定義的宏程序處理所有的3個工況
/COM             *** USE MACRO TO PROCESS ALL 3 LOADCASES  ***
*USE,MAC,1,(1/7.6E-4)
SET,1,1
LCSEL,S,0,0
N1=NODE(152.4 , 0, 0)
*GET,UX1,NODE,N1,U,X
! (41) 提取第二步結果
*USE,MAC,2,(1/2.4712)
SET,2,1
LCSEL,S,0,0
*GET,UY1,NODE,N1,U,Y
! (42) 提取第三步結果
*USE,MAC,3,(1/10.9646)
SET,3,1
LCSEL,S,0,0
*GET,UZ1,NODE,N1,U,Z
! (43) 定義字符串變量和相應的理論計算結果
*DIM,LABEL,CHAR,3,2
*DIM,VALUE,,3,3
LABEL(1,1) = 'DEFL X ','DEFL Y ','DEFL Z '
LABEL(1,2) = 'mm','mm','mm'
*VFILL,VALUE(1,1),DATA,7.6E-4,2.471,10.965
*VFILL,VALUE(1,2),DATA,UX1,UY1,UZ1
*VFILL,VALUE(1,3),DATA,ABS(UX1/(7.6E-4)),ABS(UY1/2.471),ABS(UZ1/10.965)
SAVE, TABLE_4
! (44) 從第1個表中恢復數據，繪制單元應力云圖
RESUME,TABLE_1
/COM       *** CLIPPED AND CAPPED DISPLAY OF STRESS CONTOURS  ***
NSEL,ALL
/VIEW,1,2,1,1
EPLOT
/TYPE,1,CAP
/DIST,1,5.08
/FOCUS,1,.3,.15,.09
/Auto
PLNSOL,S,X
! (45) 形成計算結果文本文件
/COM
/OUT, EX2_4, out
/COM,-------------------  EX2.4  RESULTS COMPARISON ------------
/COM,
/COM,                      TARGET   |    ANSYS   |    RATIO
/COM, SOLID5
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F11.6,'  ',F11.6,'   ',1F6.3)
/NOPR
RESUME,TABLE_2
/GOPR
/COM,
/COM, SOLID92
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F11.6,'  ',F11.6,'   ',1F6.3)
/NOPR
RESUME,TABLE_3
/GOPR
/COM,
/COM, SOLID98
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F11.6,'  ',F11.6,'   ',1F6.3)
/NOPR
RESUME,TABLE_4
/GOPR
/COM
/COM, SOLID147
/COM,
*VWRITE,LABEL(1,1),LABEL(1,2),VALUE(1,1),VALUE(1,2),VALUE(1,3)
(1X,A8,A8,'   ',F11.6,'  ',F11.6,'   ',1F6.3)
/COM,---------------------------------------------------- -
/OUT
FINISH
! (46) 刪除宏文件，臨時表文件TABLE_*
/DELETE,MAC
/DELETE,TABLE_1
/DELETE,TABLE_2
/DELETE,TABLE_3
/DELETE,TABLE_4
*LIST, EX2_4, out