?? wsaa1064.asm
字號(hào):
;參考程序B :WSAA1064.ASM程序功能：向顯示器SAA1064送數(shù)據(jù)
;顯示0,1,2,3四位數(shù)要顯示的數(shù)據(jù)在70H--7BH中.
$include (C8051F020.inc)
SAA1064ADR EQU 070H ; SAA1064芯片的寫地址
;SMBus狀態(tài)(SMB9STA):
SMB_BUS_ERROR EQU 00H ;（所有方式）總線錯(cuò)誤
SMB_START EQU 08H
;（MT＆MR）主收發(fā)器發(fā)送起始位成功.再將從機(jī)寫地址送SMB0DAT
SMB_RP_START EQU 10H
;（MT＆MR）主收發(fā)器重復(fù)發(fā)送起始位成功,再將從機(jī)讀地址送SMB0DAT
SMB_MTADDACK EQU 18H
;（MT）主收發(fā)器發(fā)送從地址＋W成功；收到 ACK(從機(jī)應(yīng)答)
;再將從器件的子地址送入SMB0DAT
SMB_MTADDNACK EQU 20H ;（MT）主收發(fā)器發(fā)送從地址＋W成功；收到 NACK.
SMB_MTDBACK EQU 28H ;（MT）主收發(fā)器發(fā)送數(shù)據(jù)字節(jié)成功；收到ACK(從機(jī)應(yīng)答)
SMB_MTDBNACK EQU 30H ;（MT）主發(fā)送器發(fā)送數(shù)據(jù)成功；收到NACK(從機(jī)無(wú)應(yīng)答).
SMB_MTARBLOST EQU 38H ;（MT）總線競(jìng)爭(zhēng)失敗
SMB_MRADDACK EQU 40H ;（MR）主收發(fā)器發(fā)送從地址＋R成功；收到 ACK(從機(jī)應(yīng)答)
SMB_MRADDNACK EQU 48H ;（MR）主收發(fā)器發(fā)送從地址＋R成功；收到NACK
SMB_MRDBACK EQU 50H ;（MR）主收發(fā)器接收數(shù)據(jù)成功；主機(jī)將AA清另 ,發(fā)送ACK
SMB_MRDBNACK EQU 58H ;（MR）主收發(fā)器接收數(shù)據(jù)成功；主機(jī)發(fā)送NACK ,1'STO
DSEG ; 數(shù)據(jù)段;
ORG 30H;
TRANSMIT_BYTE: DS 1 ;保存SMBus待發(fā)送的字節(jié)
RECEIVE_BYTE: DS 1 ;保存SMBus剛收到的字節(jié)
SLA_ADD: DS 1 ;保存從地址
WRI_ADD: DS 1 ;保存從地址＋ WRITE
READ_ADD: DS 1 ;保存從地址＋ READ
SUBADDR: DS 1 ;要訪問(wèn)器件的子地址
; 用于暫存數(shù)據(jù)的單元
DATA_COUNT: DS 1 ;測(cè)試計(jì)數(shù)器變量
DATA_BYTE: DS 1 ;測(cè)試數(shù)據(jù)
DATA_ADDR: DS 1 ;測(cè)試存儲(chǔ)器地址
BSEG ; 數(shù)據(jù)段;
ORG 00H
RW: DBIT 1 ;R／W命令位。L為READ，0為WRITE
SM_BUSY: DBIT 1 ;SMBus忙標(biāo)志（軟件保存）
BYTE_SENT : DBIT 1
CSEG ;代碼段
ORG 00H ;復(fù)位
LJMP MAIN
ORG 03BH ;SMBus中斷向量
LJMP SMBus_ISR
;主程序
MAIN: MOV SP,#7H
MOV WDTCN,#0DEH ;禁止看門狗定時(shí)器
MOV WDTCN,#0ADH;
LCALL PORT_Init ;初始化I/O端口及時(shí)鐘
CLR SM_BUSY ;為第一次傳輸清除SM_Busy標(biāo)志
SETB EA
MOV R1,#50H
; SAA1064W: 依次連續(xù)寫入5個(gè)數(shù)到SAA1064中去:17H,3FH,06H,5BH,4FH
MOV SUBADDR,#00H ; 裝入SAA1064的子地址（SUBADR=00H）
MOV DATA_COUNT,#6H ; 裝入待寫數(shù)據(jù)塊的長(zhǎng)度
MOV SLA_ADD,#SAA1064ADR ; 裝入從器件的寫地址
MOV R0,#0 ; R0做計(jì)數(shù)器用
LCALL SEND
CLR EA ; 調(diào)用數(shù)據(jù)發(fā)送子程序
SJMP $ ; 運(yùn)行結(jié)束,原地等待.
TAB: DB 17H,4fH,5bH ,06H,3FH;送顯示器SAA1064的數(shù)據(jù)，顯示3,2,1,0四位數(shù)
;發(fā)送子程序SEND;
;SEND子程序執(zhí)行一次向SAA1064寫入六位數(shù)據(jù)（0,17H,4FH,5BH,06H,3FH）的過(guò)程。
;該子程序管理SM_BUSY位，設(shè)置 RW＝WRITE，裝載 SLAW，啟動(dòng)寫操作。
SEND:
PUSH ACC ;保存累加器
JB SM_BUSY,$ ;等待SMBus空閑
CLR RW ; RW＝ 0（寫）
MOV A,SLA_ADD ; 取SLA_ADD到A
MOV WRI_ADD,A ;將SLA_ADD＋ WRITE保存到SLAW
SETB SM_BUSY ; 占用SMBus
SETB STA ; 啟動(dòng)發(fā)送過(guò)程
JB SM_BUSY,$ ;等待發(fā)送結(jié)束（在中斷中處理）
POP ACC
RET
;SMBus 中斷程序 ,處理SMBUS 中斷
SMBus_ISR:
PUSH PSW ; 保護(hù)現(xiàn)場(chǎng)
PUSH ACC ;
PUSH DPH ;
PUSH DPL ;
MOV A,SMB0STA ;將當(dāng)前狀態(tài)(SMB0STA)裝入累加器.每個(gè)狀態(tài)對(duì)應(yīng)一個(gè)地址偏移量 ; ANL A,#7FH ; 屏蔽最高位
MOV @R1,A ;在50H---60H中存放SMB0STA和SMB0DAT,可查看中斷路徑
INC R1
MOV @R1,SMB0DAT;
INC R1
MOV DPTR,#SMB_STATE_TABLE ; DPTR指向狀態(tài)表的起始地址
JMP @A+DPTR ;轉(zhuǎn)移到當(dāng)前狀態(tài)
;SMBuS狀態(tài)表 ;(SMB0STA =00H)
SMB_STATE_TABLE: ; SMB_BUS_ERROR總線錯(cuò)誤(對(duì)所有方式)
ORG SMB_STATE_TABLE+SMB_BUS_ERROR
SETB STO ; 停止位置1,使硬件復(fù)位
JMP SMB_ISR_END ; 中斷返回
;SMB_START ; (SMB0STA =08H)
;主發(fā)送器／接收器發(fā)送起始位成功.再將從機(jī)寫地址送SMB0DAT并清除START位.
ORG SMB_STATE_TABLE+SMB_START
MOV SMB0DAT,WRI_ADD ; 裝載從地址＋ W````
CLR STA ; 清除START位
JMP SMB_ISR_END ; 中斷返回
;SMB_RP_START ;(SMB0STA =10H)
;主發(fā)送器／接收器發(fā)送重復(fù)起始位成功.再將從機(jī)讀地址送SMB0DAT并清除START位.
ORG SMB_STATE_TABLE+SMB_RP_START
MOV SMB0DAT,READ_ADD ;裝載從地址＋ R
CLR STA ; 清除START位
JMP SMB_ISR_END
;SMB_MTADDACK (SMB0STA =18H)
;主發(fā)送器（MT）發(fā)送從地址＋W成功；收到 ACK,再將要發(fā)的子地址送入SMB0DAT.
ORG SMB_STATE_TABLE+SMB_MTADDACK
MOV SMB0DAT,SUBADDR ;裝載從器件的子地址到SMB0DAT.
SETB BYTE_SENT ;BYTE_SENT＝1.在下一次中斷調(diào)用時(shí)存儲(chǔ)器地址剛被發(fā)送
JMP SMB_ISR_END
;SMB_MTADDNACK (SMB0STA =20H)
;主發(fā)送器（MT）發(fā)送從地址＋W成功；收到 NACK,用確認(rèn)查詢重試。發(fā)送 STOP＋START
ORG SMB_STATE_TABLE + SMB_MTADDNACK
SETB STO
SETB STA
JMP SMB_ISR_END
;SMB_MTDBACK (SMB0STA =28H)
;主發(fā)送器（MT）發(fā)送數(shù)據(jù)字節(jié)成功；收到ACK(從機(jī)應(yīng)答)
;檢查BYTE_SENT：如果為1，說(shuō)明剛發(fā)出的是存儲(chǔ)器地址；為0，剛發(fā)出的是數(shù)據(jù)字節(jié)
ORG SMB_STATE_TABLE+SMB_MTDBACK
DJNZ DATA_COUNT,ADDRESS_SENT
JBC BYTE_SENT,ADDRESS_SENT ;如果BYTE_SENT＝1，清除該位并轉(zhuǎn)到
;ADDRESS_SENT去執(zhí)行狀態(tài)表以外的處理程序
JMP DATA_SENT ; 如果BYTE_SENT＝0，數(shù)據(jù)剛被發(fā)出，
; 傳輸過(guò)程完成，轉(zhuǎn)到傳輸結(jié)束
;SMB_MTDBNACK ;(SMB0STA =30H)
;主發(fā)送器（MT）發(fā)送數(shù)據(jù)成功；收到NACK,用確認(rèn)查詢重試。發(fā)送STOP＋START重試
ORG SMB_STATE_TABLE+SMB_MTDBNACK
SETB STO
SETB STA
JMP SMB_ISR_END
; SMB_MTARBLOST ;(SMB0STA =38H);競(jìng)爭(zhēng)失敗.重新啟動(dòng)傳輸.
ORG SMB_STATE_TABLE+SMB_MTARBLOST
SETB STO
SETB STA
JMP SMB_ISR_END
; SMB_MRADDACK ;(SMB0STA =40H)
;（MR）主收發(fā)器發(fā)送從地址＋R成功；收到 ACK(從機(jī)應(yīng)答).主機(jī)發(fā)送ACK.
ORG SMB_STATE_TABLE+SMB_MRADDACK
SETB AA ;主機(jī)發(fā)送ACK,轉(zhuǎn)入SMB_MRDBACK
JMP SMB_ISR_END
; SMB_MRADDNACK ;(SMB0STA =48H)
;（MR）主收發(fā)器發(fā)送從地址＋R成功；收到NACK(從機(jī)無(wú)應(yīng)答),發(fā)送重復(fù)起始位重試
ORG SMB_STATE_TABLE+SMB_MRADDNACK
SETB STA
JMP SMB_ISR_END
;SMB_MRDBACK (SMB0STA =50H)
;（MR）主收發(fā)器接收數(shù)據(jù)成功；主機(jī)發(fā)送ACK .
ORG SMB_STATE_TABLE+SMB_MRDBACK
MOV RECEIVE_BYTE, SMB0DAT
CLR AA ;主機(jī)發(fā)NACK(清除AA),下一次中斷來(lái)時(shí)轉(zhuǎn)入;SMB_MRDBNACK(58H)
CLR SM_BUSY;
JMP SMB_ISR_END
;SMB_MRDBNACK ;(SMB0STA =58H)
;（MR）主收發(fā)器接收數(shù)據(jù)成功；主機(jī)發(fā)送NACK
;讀操作完成。讀數(shù)據(jù)寄存器并發(fā)送STOP
ORG SMB_STATE_TABLE+SMB_MRDBNACK
MOV RECEIVE_BYTE, SMB0DAT
SETB STO
SETB AA ;主機(jī)發(fā)ACK,為下一次傳輸置位AA
CLR SM_BUSY;
JMP SMB_ISR_END
ADDRESS_SENT:
MOV DPTR,#TAB ;查表，找到顯示的數(shù)據(jù)（字型碼）
MOV A,R0
MOVC A,@A+DPTR
MOV DATA_BYTE ,A
INC R0
MOV SMB0DAT,DATA_BYTE ;將要顯示的數(shù)據(jù)（字型碼）送SAA1064
JMP SMB_ISR_END ; 中斷返回
;對(duì)于地址字節(jié)剛發(fā)出的狀態(tài)。重復(fù)發(fā)送START，啟動(dòng)存儲(chǔ)器讀操作
RW_READ:
SETB STA ;重復(fù)發(fā)送START
JMP SMB_ISR_END ;中斷返回
;這是一個(gè)寫操作，數(shù)據(jù)字節(jié)已發(fā)出。傳輸過(guò)程結(jié)束。發(fā)送STOP，釋放總線，中斷返回
DATA_SENT:
SETB STO ;發(fā)送STOP后中斷返回
CLR SM_BUSY ; 釋放 SMBus
JMP SMB_ISR_END ; 中斷返回
;SMBus ISR exit
;恢復(fù)現(xiàn)場(chǎng)，清除SI位，從中斷返回
SMB_ISR_END:
CLR SI
POP DPL
POP DPH
POP ACC
POP PSW
RETI
PORT_Init :
ORL OSCICN,#05H ;內(nèi)部振蕩器頻率設(shè)置為4MHz,選擇內(nèi)部振蕩器頻率作系統(tǒng)時(shí)鐘
MOV P0MDOUT,#00 ;P0口為開(kāi)漏方式
MOV XBR0,#01H ;通過(guò)功能選擇開(kāi)關(guān)將將SDA接P0.0引腳,SCL接P0.1引腳
MOV XBR2 ,#40H; 允許功能選擇開(kāi)關(guān)和弱上拉
; 初始化SMBus程序段
MOV SMB0CN,#04H ; 配置 SMBus在確認(rèn)周期發(fā)送 ACK(SDA線為低電平)
MOV SMB0CR,#0ECH ; 設(shè)置時(shí)鐘速率＝100 kHz (系統(tǒng)時(shí)鐘為4MHZ)
ORL SMB0CN,#40H ; 允許SMBus
ORL EIE1,#02H ; 允許SMBus中斷
RET
END
?? 快捷鍵說(shuō)明
復(fù)制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號(hào)
Ctrl + =
減小字號(hào)
Ctrl + -