//=======================================================================
//	The information contained herein is the exclusive property of
//	Sunnnorth Technology Co. And shall not be distributed, reproduced,
//	or disclosed in whole in part without prior written permission.
//	(C) COPYRIGHT 2003 SUNNORTH TECHNOLOGY CO.
//	ALL RIGHTS RESERVED
//	The entire notice above must be reproduced on all authorized copies.
//=======================================================================

//=======================================================================
//	工程名稱：	ex12_asm_IRQ5
//	功能描述：	《實驗儀實驗指導書》基礎應用實驗
//              IRQ5中斷
//				使用IRQ5的2Hz、4Hz中斷按照設定頻率使LED閃爍
//  IDE環境：   SUNPLUS u'nSPTM  IDE 2.0.0（or later）
//	涉及的庫：	CMacro1016.lib
//	組成文件：	main.asm
//	硬件連接：	LED_SEG的IOA0~7分別與a~h連接
//				LED_DIG的IOB6連接DIG5
//	維護記錄：	2005-09-12	v1.0
//
//=======================================================================

//=======================================================================
//	文件名稱：	main.asm
//	功能描述：	使用IRQ5的2Hz、4Hz中斷按照設定頻率使LED閃爍
//	維護記錄：	2005-09-12	v1.0
//=======================================================================
.DEFINE	P_IOA_Data			0x7000
.DEFINE	P_IOA_Buffer		0x7001
.DEFINE P_IOA_Dir			0x7002
.DEFINE P_IOA_Attrib		0x7003
.DEFINE	P_IOB_Data			0x7005
.DEFINE	P_IOB_Buffer		0x7006
.DEFINE P_IOB_Dir			0x7007
.DEFINE P_IOB_Attrib		0x7008

.DEFINE P_INT_Ctrl			0x7010
.DEFINE P_INT_Clear			0x7011
.DEFINE P_Watchdog_Clear	0x7012

.DEFINE C_IRQ5_2Hz			0x0004
.DEFINE C_IRQ5_4Hz			0x0008

.CODE

//=======================================================================
//	匯編格式：	_main
//	C格式：		int main(void);
//	實現功能：	使用IRQ5的2Hz、4Hz中斷按照設定頻率使LED閃爍
//	入口參數：	無
//	出口參數：	無
//	破壞寄存器：r1,r2
//=======================================================================

.PUBLIC	_main
_main:
	int off							//關閉中斷

	r1 = 0x00ff						//設置IOA7~0為同相高電平輸出
	[P_IOA_Dir] = r1
	[P_IOA_Attrib] = r1
	[P_IOA_Data] = r1
	 
	r1 = 0x0040						//IOB輸出高電平
	[P_IOB_Dir] = r1
	[P_IOB_Attrib] = r1
	[P_IOB_Data] = r1

	r1 = C_IRQ5_2Hz | C_IRQ5_4Hz
	[P_INT_Ctrl] = r1				//打開IRQ5的2Hz、4Hz時基中斷
	
	int irq							//打開IRQ中斷總使能，同時關閉FIQ中斷
?Loop:
	r1 = 0x0001
	[P_Watchdog_Clear] = r1         //清看門狗
	jmp ?Loop

.TEXT
//=========================================================================
//	匯編格式：	_IRQ5
//	C格式：		無
//	實現功能：	IRQ5中斷服務程序
//	入口參數：	無
//	出口參數：	無
//	破壞寄存器：無
//=========================================================================
.PUBLIC _IRQ5
_IRQ5:
	push r1,r5 to [sp]
	r1 = C_IRQ5_4Hz
	test r1,[P_INT_Ctrl]			//判斷是否為IRQ5的4Hz中斷？
	jnz ?L_IRQ5_4Hz					//是，則轉向?L_IRQ5_4Hz	
?L_IRQ5_2Hz:						//2Hz時基中斷
	r1 = [P_IOA_Buffer]
	r1 ^= 0x000f					//異或0x000f，即IOA口低四位數據取反
	[P_IOA_Data] = r1               //輸出
	r1 = C_IRQ5_2Hz
	[P_INT_Clear] = r1              //清2Hz中斷標志
	pop r1,r5 from [sp]
	reti
	
?L_IRQ5_4Hz:						//4Hz時基中斷
	r1 = [P_IOA_Buffer]
	r1 ^= 0x00f0                    //IOA7~4數據取反
	[P_IOA_Data] = r1               //輸出
	r1 = C_IRQ5_4Hz                  
	[P_INT_Clear] = r1              //清4Hz中斷標志
	pop r1,r5 from [sp]
	reti