@echo off

rem ******************************************************************
rem ** Location where the Emerald C compiler is installed.          **
rem ******************************************************************
set PATH_DSP=C:\Emerald_compiler

rem ******************************************************************
rem ** Location of the DSP source files.                            **
rem ******************************************************************
set PATH_DSP_SOURCE=%CD%

rem ******************************************************************
rem ** Location to which the target file is copied.                 **
rem ******************************************************************
set PATH_DSP_TARGET=%CD%

rem ******************************************************************
rem ** Tools provided together with the Emerald C compiler.         **
rem ******************************************************************
set DSP_CC=%PATH_DSP%\build_win32
set DSP_PERL=%PATH_DSP%\Perl\bin\perl
set EMERALDCC=%PATH_DSP%\compiler\16_bit_win32\driver\bin\emeraldcc
set MAPREADER=%PATH_DSP%\compiler\16_bit_win32\driver\lib\mapreader
set RDIMAGE=%PATH_DSP%\Archelon\bin_win32\rdimage

rem ******************************************************************
rem ** Tool needed for converting generated DSP code into a h-file. **
rem ******************************************************************
set GAWK="C:\Program Files\GnuWin32\bin\gawk"
set HEX2CHAR=%PATH_DSP_SOURCE%\hex2char.awk

rem ******************************************************************
rem ** DSP Source files.                                            **
rem ******************************************************************
set DSP_MAIN=%PATH_DSP_SOURCE%\mainfile.c
set DSP_CFG=%PATH_DSP_SOURCE%\emecfg.h

rem ******************************************************************
rem ** Name used for target.                                        **
rem ******************************************************************
set DSP_TARGET=emeacc

rem ******************************************************************
rem ** Name and location of directory holding the intermediate files *
rem ******************************************************************
set DSP_OUT=shinwa_dsp_out
set DSP_OUT_LOCATION=%PATH_DSP_SOURCE%\..\..\..\Project
set DSP_TMP_DRIVE=C:



rem ******************************************************************
rem ** All intermediate results in temporary directory.             **
rem ******************************************************************
echo Creating tempory directory C:\%DSP_OUT%
echo =================================================================
if exist %DSP_TMP_DRIVE%\%DSP_OUT% rmdir /s/q %DSP_TMP_DRIVE%\%DSP_OUT%
mkdir C:\%DSP_OUT%
cd /D C:\%DSP_OUT%

rem ******************************************************************
rem ** Compile.                                                     **
rem ******************************************************************
echo Compiling DSP code using %EMERALDCC%
echo =================================================================
%DSP_PERL% %EMERALDCC% -C %DSP_CFG% -m 16 -k -b -o %DSP_TARGET% %DSP_MAIN%

rem ******************************************************************
rem ** Generate target header file.                                 **
rem ******************************************************************
echo Generate hex-file using %RDIMAGE%
echo =================================================================
%RDIMAGE% %DSP_TARGET%.P > %DSP_TARGET%.32
echo Generate %DSP_TARGET%.h
echo =================================================================
%GAWK% -f %HEX2CHAR% %DSP_TARGET%.32 > %DSP_TARGET%.h

rem ******************************************************************
rem ** Generate text version of the map file.                       **
rem ******************************************************************
echo Generating map-file %DSP_TARGET%.map.txt
echo =================================================================
%DSP_PERL% %MAPREADER% %3.map -ALL -PROG_SIZE=1792 -DATA_SIZE=256 > %DSP_TARGET%.map.txt

rem ******************************************************************
rem ** Move target header file to target location                   **
rem ******************************************************************
echo Move target (%DSP_TARGET%.h) to target directory (%PATH_DSP_TARGET%)
echo =================================================================
move %DSP_TARGET%.h %PATH_DSP_TARGET%

rem ******************************************************************
rem ** Move intermediate to final destination                       **
rem ******************************************************************
echo Move intermediate files to %DSP_OUT_LOCATION%\%DSP_OUT%
echo =================================================================
cd /D %PATH_DSP_SOURCE%
if exist %DSP_OUT_LOCATION%\%DSP_OUT% rmdir /q/s %DSP_OUT_LOCATION%\%DSP_OUT%
mkdir %DSP_OUT_LOCATION%\%DSP_OUT%
xcopy /y/s %DSP_TMP_DRIVE%\%DSP_OUT% %DSP_OUT_LOCATION%\%DSP_OUT%

echo Press Enter to exit
set /p a=