;/****************************************Copyright (c)**************************************************
;**                               廣州周立功單片機(jī)發(fā)展有限公司
;**                                     研    究    所
;**                                        產(chǎn)品一部 
;**
;**                                 http://www.zlgmcu.com
;**
;**--------------文件信息--------------------------------------------------------------------------------
;**文   件   名: os_cpu_s.s
;**創(chuàng)   建   人: 陳明計(jì)
;**最后修改日期: 2003年6月19日
;**描        述: μCOS-II在LPC210x上的移植代碼匯編代碼部分，用ADS1.2編譯
;**
;**--------------歷史版本信息----------------------------------------------------------------------------
;** 創(chuàng)建人: 陳明計(jì)
;** 版  本: V1.0
;** 日　期: 2003年6月5日
;** 描　述: 原始版
;**
;**------------------------------------------------------------------------------------------------------
;** 修改人: 陳明計(jì)
;** 版  本: V1.1
;** 日　期: 2003年6月11日
;** 描　述: 配合Vectors.s更正IRQ嵌套的BUG而作相應(yīng)的修改
;**
;**------------------------------------------------------------------------------------------------------
;** 修改人: 陳明計(jì)
;** 版  本: V1.2
;** 日　期: 2003年6月13日
;** 描　述: 按照μCOS-II V2.52的要求修改（以前是基于μCOS-II V2.0）
;**
;**------------------------------------------------------------------------------------------------------
;** 修改人: 陳明計(jì)
;** 版  本: V1.3
;** 日　期: 2003年6月19日
;** 描　述: 不完全按照μCOS-II V2.52的要求以提高效率
;**
;**--------------當(dāng)前版本修訂------------------------------------------------------------------------------
;** 修改人: 
;** 日　期:
;** 描　述:
;**
;**------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
;定義系統(tǒng)模式堆棧的大小
SVC_STACK_LEGTH     EQU         32

NoInt       EQU 0x80

USR32Mode   EQU 0x10
SVC32Mode   EQU 0x13
SYS32Mode   EQU 0x1f
IRQ32Mode   EQU 0x12
FIQ32Mode   EQU 0x11

;T_bit用于檢測(cè)進(jìn)入異常前cpu是否處于THUMB狀態(tài)
T_bit               EQU         0x20

    CODE32

    AREA    |subr|, CODE, READONLY

            IMPORT  OSTCBCur                    ;指向當(dāng)前任務(wù)TCB的指針
            IMPORT  OSTCBHighRdy                ;指向?qū)⒁\(yùn)行的任務(wù)TCB的指針
            IMPORT  OSPrioCur                   ;當(dāng)前任務(wù)的優(yōu)先級(jí)
            IMPORT  OSPrioHighRdy               ;將要運(yùn)行的任務(wù)的優(yōu)先級(jí)
            IMPORT  OSTaskSwHook                ;任務(wù)切換的鉤子函數(shù)
            IMPORT  OSRunning                   ;uC/OS-II運(yùn)行標(biāo)志

            IMPORT  OsEnterSum                  ;關(guān)中斷計(jì)數(shù)器（關(guān)中斷信號(hào)量）
            IMPORT  SWI_Exception               ;軟中斷異常處理程序
            
            EXPORT  __OSStartHighRdy            
            EXPORT  OSIntCtxSw                  ;中斷退出時(shí)的入口，參見(jiàn)startup.s中的IRQ_Handler
            EXPORT  SoftwareInterrupt           ;軟中斷入口


;/*********************************************************************************************************
;** 函數(shù)名稱: SoftwareInterrupt
;** 功能描述: 軟件中斷，用于提供一些系統(tǒng)服務(wù)，功能參考o(jì)s_cpu_c.c文件
;** 輸　入:   依功能而定
;** 輸　出 :  依功能而定
;** 全局變量: 無(wú)
;** 調(diào)用模塊: SWI_Exception
;** 
;** 作　者: 陳明計(jì)
;** 日　期: 2003年6月5日
;**-------------------------------------------------------------------------------------------------------
;** 修　改: 陳明計(jì)
;** 日　期: 2003年6月11日
;**-------------------------------------------------------------------------------------------------------
;** 修　改: 陳明計(jì)
;** 日　期: 2003年6月13日
;**-------------------------------------------------------------------------------------------------------
;** 修　改: 陳明計(jì)
;** 日　期: 2003年6月19日
;**-------------------------------------------------------------------------------------------------------
;********************************************************************************************************/

;軟件中斷
SoftwareInterrupt
        LDR     SP, StackSvc            ; 重新設(shè)置堆棧指針
        STMFD   SP!, {R0-R3, R12, LR}
        MOV     R1, SP                  ; R1指向參數(shù)存儲(chǔ)位置

        MRS     R3, SPSR
        TST     R3, #T_bit              ; 中斷前是否是Thumb狀態(tài)
        LDRNEH  R0, [LR,#-2]            ; 是: 取得Thumb狀態(tài)SWI號(hào)
        BICNE   R0, R0, #0xff00
        LDREQ   R0, [LR,#-4]            ; 否: 取得arm狀態(tài)SWI號(hào)
        BICEQ   R0, R0, #0xFF000000
                                        ; r0 = SWI號(hào)，R1指向參數(shù)存儲(chǔ)位置
        CMP     R0, #1
        LDRLO   PC, =OSIntCtxSw
        LDREQ   PC, =__OSStartHighRdy   ; SWI 0x01為第一次任務(wù)切換

        BL      SWI_Exception
        
        LDMFD   SP!, {R0-R3, R12, PC}^
        
StackSvc           DCD     (SvcStackSpace + SVC_STACK_LEGTH * 4 - 4)

;/*********************************************************************************************************
;** 函數(shù)名稱: OSIntCtxSw
;** 功能描述: 中斷退出時(shí)的入口
;** 輸　入:   R3    :當(dāng)前任務(wù)的狀態(tài)寄存器CPSR（即SPSR的值）
;**           R4-R12:當(dāng)前任務(wù)的R4-R11
;**           當(dāng)前處理器模式的堆棧結(jié)構(gòu)（出棧次序）：R0-R3、R12、PC（當(dāng)前任務(wù)的）
;** 輸　出 :  無(wú)
;** 全局變量: OSPrioCur,OSPrioHighRdy,OSPrioCur,OSPrioHighRdy
;** 調(diào)用模塊: 無(wú)
;** 
;** 作　者: 陳明計(jì)
;** 日　期: 2003年6月5日
;**-------------------------------------------------------------------------------------------------------
;** 修　改: 陳明計(jì)
;** 日　期: 2003年6月11日
;**-------------------------------------------------------------------------------------------------------
;** 修　改: 陳明計(jì)
;** 日　期: 2003年6月13日
;**-------------------------------------------------------------------------------------------------------
;** 修　改: 陳明計(jì)
;** 日　期: 2003年6月19日
;**-------------------------------------------------------------------------------------------------------
;********************************************************************************************************/
OSIntCtxSw
                                                    ;下面為保存任務(wù)環(huán)境
        LDR     R2, [SP, #20]                       ;獲取PC
        LDR     R12, [SP, #16]                      ;獲取R12
        MRS     R0, CPSR

        MSR     CPSR_c, #(NoInt | SYS32Mode)
        MOV     R1, LR
        STMFD   SP!, {R1-R2}                        ;保存LR,PC
        STMFD   SP!, {R4-R12}                       ;保存R4-R12

        MSR     CPSR_c, R0
        LDMFD   SP!, {R4-R7}                        ;獲取R0-R3
        ADD     SP, SP, #8                          ;出棧R12,PC
        
        MSR     CPSR_c, #(NoInt | SYS32Mode)
        STMFD   SP!, {R4-R7}                        ;保存R0-R3
        
        LDR     R1, =OsEnterSum                     ;獲取OsEnterSum
        LDR     R2, [R1]
        STMFD   SP!, {R2, R3}                       ;保存CPSR,OsEnterSum

                                                    ;保存當(dāng)前任務(wù)堆棧指針到當(dāng)前任務(wù)的TCB
        LDR     R1, =OSTCBCur
        LDR     R1, [R1]
        STR     SP, [R1]

        BL      OSTaskSwHook                        ;調(diào)用鉤子函數(shù)
                                                    ;OSPrioCur <= OSPrioHighRdy
        LDR     R4, =OSPrioCur
        LDR     R5, =OSPrioHighRdy
        LDRB    R6, [R5]
        STRB    R6, [R4]
                                                    ;OSTCBCur <= OSTCBHighRdy
        LDR     R6, =OSTCBHighRdy
        LDR     R6, [R6]
        LDR     R4, =OSTCBCur
        STR     R6, [R4]
OSIntCtxSw_1
                                                    ;獲取新任務(wù)堆棧指針
        LDR     R4, [R6]
        ADD     SP, R4, #68                         ;17寄存器CPSR,OsEnterSum,R0-R12,LR,SP
        LDR     LR, [SP, #-8]
        MSR     CPSR_c, #(NoInt | SVC32Mode)        ;進(jìn)入管理模式
        MOV     SP, R4                              ;設(shè)置堆棧指針

        LDMFD   SP!, {R4, R5}                       ;CPSR,OsEnterSum
                                                    ;恢復(fù)新任務(wù)的OsEnterSum
        LDR     R3, =OsEnterSum
        STR     R4, [R3]
    
        MSR     SPSR_cxsf, R5                       ;恢復(fù)CPSR
        LDMFD   SP!, {R0-R12, LR, PC }^             ;運(yùn)行新任務(wù)

;/*********************************************************************************************************
;** 函數(shù)名稱: __OSStartHighRdy
;** 功能描述: uC/OS-II啟動(dòng)時(shí)使用OSStartHighRdy運(yùn)行第一個(gè)任務(wù),
;**           OSStartHighRdy會(huì)調(diào)用__OSStartHighRdy
;** 輸　入:   無(wú)
;** 輸　出 :  無(wú)
;** 全局變量: OSRunning,OSTCBCur,OSTCBHighRdy,OsEnterSum
;** 調(diào)用模塊: OSTaskSwHook
;** 
;** 作　者: 陳明計(jì)
;** 日　期: 2003年6月5日
;**-------------------------------------------------------------------------------------------------------
;** 修　改: 陳明計(jì)
;** 日　期: 2003年6月13日
;**-------------------------------------------------------------------------------------------------------
;********************************************************************************************************/

__OSStartHighRdy
        MSR     CPSR_c, #(NoInt | SYS32Mode)
                                                ;告訴uC/OS-II自身已經(jīng)運(yùn)行
        LDR     R4, =OSRunning
        MOV     R5, #1
        STRB    R5, [R4]

        BL      OSTaskSwHook                    ;調(diào)用鉤子函數(shù)

        LDR     R6, =OSTCBHighRdy
        LDR     R6, [R6]
        B       OSIntCtxSw_1

        AREA    SWIStacks, DATA, NOINIT
;,ALIGN=2
SvcStackSpace      SPACE   SVC_STACK_LEGTH * 4  ;管理模式堆棧空間

    END
;/*********************************************************************************************************
;**                            End Of File
;********************************************************************************************************/