?? iic_a.s43
字號:
;***********************************************************************
; 文件名稱：
; IIC_A.s43
; 文件說明：
; 使用口線模擬IIC操作EEPROM，查看程序運行結(jié)果需具備調(diào)試
; 的基本能力。程序在EEPROM的0x02處寫入放在0x203處的數(shù)據(jù)，然后讀出
; 放到0x204,可在CHECK_POINT 處設(shè)置斷點查看寫入與讀出的數(shù)據(jù)是否相同。
;**********************************************************************
#include "msp430x44x.h "
;************************************************************************
; 端口定義
;************************************************************************
SDA equ 080H ;SDA=P4.7
SCL equ 040H ;SCL=P4.6
;************************************************************************
; 讀寫命令定義
;************************************************************************
SLAW equ 0A0H ;寫命令字
SLAR equ 0A1H ;讀命令字
;************************************************************************
; RAM定義
;************************************************************************
FLAG_F0 equ 200H ;存儲應答信號ACK
BITI2C equ 202H ;位計數(shù)器
WR_I2C_ROM equ 203H ;寫緩沖
RD_I2C_ROM equ 204H ;讀緩沖
ADDR_I2C_ROM equ 205H ;地址緩沖
;************************************************************************
ORG 08000h ; 程序開始處
;************************************************************************
Reset
mov.w #0600h,SP ; 堆棧地址
StopWDT mov.w #WDTPW+WDTHOLD,&WDTCTL ; 禁止看門狗
clr.b &FLAG_F0
clr.b R14
mainloop
mov.b #02H,&ADDR_I2C_ROM ;寫地址02送入
mov.b R14,&WR_I2C_ROM ;送入所寫內(nèi)容
call #RANDOM_WRB ;調(diào)用隨機寫一字節(jié)函數(shù)
nop
nop
mov #0ffh,R15
loop_1122 dec.b R15
jnz loop_1122
mov.b #02H ,&ADDR_I2C_ROM ;讀地址02送入
call #RANDOM_RDB ;調(diào)用隨機讀一字節(jié)函數(shù)
mov.b &RD_I2C_ROM,R9 ;讀出數(shù)據(jù)送入R9，以便校驗讀寫的數(shù)據(jù)
inc.b R14
nop
nop
CHECK_POINT jmp mainloop
;************************************************************************-
;VIIC
;占用R15
;說明：當寫一個字節(jié)時，所寫內(nèi)容送入WR_I2C_ROM,地址送入ADDR_I2C_ROM,然后調(diào)用RANDOM_WRB?
;當隨機讀一個字節(jié)時，地址送入ADDR_I2C_ROM,然后調(diào)用RANDOM_RDB，讀出的數(shù)據(jù)在RD_I2C_ROM中
;相關(guān)變量和常數(shù)定義如下：
;SDA equ 080H ;SDA=P4.7
;SCL equ 040H ;SDA=P4.6
;SLAW equ 0A0H ;寫命令字
;SLAR equ 0A1H ;讀命令字
;FLAG_F0 equ 200H ;存儲應答信號ACK
;BITI2C equ 202H ;位計數(shù)器
;WR_I2C_ROM equ 203H ;寫緩沖
;RD_I2C_ROM equ 204H ;讀緩沖
;ADDR_I2C_ROM equ 205H ;地址緩沖
;****************************************************************************
; 啟動IIC總線子程序
;****************************************************************************
STA
bic.b #SDA+SCL,&P4OUT ;初始化輸出緩沖
bic.b #SDA,&P4DIR ; SDA=1
call #I2C_DELAY
bic.b #SCL,&P4DIR ; SCL=1
call #I2C_DELAY
bis.b #SDA,&P4DIR ; SDA=0
call #I2C_DELAY
bis.b #SCL,&P4DIR ; SCL=0
call #I2C_DELAY
RET
;****************************************************************************
; 停止IIC總線子程序
;****************************************************************************-
STOP
bis.b #SDA,&P4DIR ; SDA=0
call #I2C_DELAY
bic.b #SCL,&P4DIR ; SCL=1
call #I2C_DELAY
bic.b #SDA,&P4DIR ; SDA=1
call #I2C_DELAY
bis.b #SDA,&P4DIR ; SDA=0
call #I2C_DELAY
bis.b #SCL,&P4DIR ; SCL=0
call #I2C_DELAY
RET
;****************************************************************************
; 產(chǎn)生應答信號子程序
;****************************************************************************
MACK
bis.b #SDA,&P4DIR ; SDA=0
call #I2C_DELAY
bic.b #SCL,&P4DIR ; SCL=1
call #I2C_DELAY
bis.b #SCL,&P4DIR ; SCL=0
call #I2C_DELAY
bic.b #SDA,&P4DIR ; SDA=1
call #I2C_DELAY
RET
;****************************************************************************
; 不產(chǎn)生應答信號子程序
;****************************************************************************
MNACK
bic.b #SDA,&P4DIR ; SDA=0
call #I2C_DELAY
bic.b #SCL,&P4DIR ; SCL=0
call #I2C_DELAY
bis.b #SCL,&P4DIR ; SCL=0
call #I2C_DELAY
bis.b #SDA,&P4DIR ; SDA=0
call #I2C_DELAY
RET
;****************************************************************************
; 接收應答信號子程序程序
;****************************************************************************
CACK
bic.b #SDA,&P4DIR ; SDA=1
call #I2C_DELAY
bic.b #SCL,&P4DIR ; SCL=1
mov.b #00H,&FLAG_F0
call #I2C_DELAY
bit.b #SDA,&P4IN
jnc ACK_LOW
mov.b #01H,&FLAG_F0
;****************************************************************************
; 不接收應答信號子程序
;****************************************************************************
ACK_LOW bis.b #SCL,&P4DIR ; SCL=0
call #I2C_DELAY
RET
;****************************************************************************
; 發(fā)送一個字節(jié)
;****************************************************************************
WRBYT
mov.b #08H,&BITI2C
WR_LP
rla.b R15
jc WR1
WR0 bis.b #SDA,&P4DIR ; SDA=0
call #I2C_DELAY
bic.b #SCL,&P4DIR ; SCL=1
call #I2C_DELAY
bis.b #SCL,&P4DIR ; SCL=0
call #I2C_DELAY
jmp C_BITI2C
WR1 bic.b #SDA,&P4DIR ; SDA=1
call #I2C_DELAY
bic.b #SCL,&P4DIR ; SCL=1
call #I2C_DELAY
bis.b #SCL,&P4DIR ; SCL=0
call #I2C_DELAY
bis.b #SDA,&P4DIR ; SDA=0
call #I2C_DELAY
C_BITI2C dec.b &BITI2C
jnz WR_LP
RET
;******************************************************************************
; 讀數(shù)據(jù)
;******************************************************************************
RDBYT
mov.b #08H,&BITI2C
RD_LP
bic.b #SDA,&P4DIR ; SDA=1
call #I2C_DELAY
bic.b #SCL,&P4DIR ; SCL=1
call #I2C_DELAY
bit.b #SDA,&P4IN
rlc.b R15
call #I2C_DELAY
bis.b #SCL,&P4DIR ; SCL=0
call #I2C_DELAY
dec.b &BITI2C
jnz RD_LP
RET
;******************************************************************************-
; 隨機寫入一個字
; WR_I2C_ROM,ADDR_I2C_ROM
;******************************************************************************-
RANDOM_WRB
call #STA
mov.b #SLAW,R15 ;發(fā)送指令
call #WRBYT
call #CACK
cmp #01H,&FLAG_F0
jeq RANDOM_WRB
mov.b &ADDR_I2C_ROM,R15 ;發(fā)地址
call #WRBYT
call #CACK
cmp #01H,&FLAG_F0
jeq RANDOM_WRB
mov.b &WR_I2C_ROM,R15 ;發(fā)送一個字節(jié)
call #WRBYT
call #CACK ;
cmp #01H,&FLAG_F0 ;
jeq RANDOM_WRB ;
call #STOP
RET
;********************************************************************************
; 隨機讀取一個字節(jié)
; RD_I2C_ROM,ADDR_I2C_ROM
;********************************************************************************
RANDOM_RDB
call #STA ; 啟動總線
mov.b #SLAW,R15 ;
call #WRBYT ; 發(fā)送寫命令
call #CACK ; 應答
cmp #01H,FLAG_F0 ; 檢測總線是否空閑
jeq RANDOM_RDB ;
mov.b &ADDR_I2C_ROM,R15 ; 設(shè)置地址
call #WRBYT ; 寫入地址
call #CACK ; 應答
cmp #01H,FLAG_F0 ;
jeq RANDOM_RDB ; 讀
call #STA ; 啟動總線
mov.b #SLAR,R15 ; 設(shè)置讀命令
call #WRBYT ; 發(fā)送讀命令
call #CACK ; 應答
cmp #01H,FLAG_F0 ;
jeq RANDOM_RDB ; 讀
call #RDBYT
mov.b R15,&RD_I2C_ROM
call #MNACK
call #STOP
RET
;********************************************************************************
; 延時子程序
;********************************************************************************
I2C_DELAY
nop ;
nop ; 延遲
nop ;
RET
;********************************************************************************
; 中斷向量表
;********************************************************************************
ORG 0FFFEH
DW Reset
END?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -