--創(chuàng)建一個測試的數(shù)據(jù)庫
CREATE DATABASE db
GO

--創(chuàng)建兩個登錄
EXEC sp_addlogin 'aa'
EXEC sp_addlogin 'bb'

--設(shè)置登錄的默認(rèn)數(shù)據(jù)庫為測試數(shù)據(jù)庫 db
EXEC sp_defaultdb 'aa','db'
EXEC sp_defaultdb 'bb','db'
GO

--授予登錄訪問數(shù)據(jù)庫的權(quán)限(將登錄設(shè)置為數(shù)據(jù)庫的用戶)
USE db
EXEC sp_grantdbaccess 'aa'
EXEC sp_grantdbaccess 'bb'

--創(chuàng)建一個屬于用戶bb的表
CREATE TABLE bb.tb(id int)
GO

--至此,測試環(huán)境已經(jīng)創(chuàng)建好了,使用用戶aa或者bb從查詢分析器登錄,驗(yàn)證用戶的可用性

--用戶驗(yàn)證完成后,備份并刪除測試數(shù)據(jù)庫,演示孤立用戶的產(chǎn)生過程
USE master
BACKUP DATABASE db TO DISK='c:\db.bak' WITH FORMAT
DROP DATABASE db
GO

--刪除登錄,用以模擬目標(biāo)服務(wù)器沒有事先創(chuàng)建登錄時的情況
EXEC sp_droplogin 'aa'
EXEC sp_droplogin 'bb'
GO

--還原測試數(shù)據(jù)庫
RESTORE DATABASE db FROM DISK='c:\DB.bak'
GO

--查看還原后的測試數(shù)據(jù)庫的用戶
USE db
EXEC sp_helpuser
/*--結(jié)果
UserName GroupName   LoginName DefDBName UserID SID
-------- --------- -------- -------- ----- --------------------------------------------
aa   public    NULL   NULL   5  0x71BA40BA3C89FA43A5DFD74620E81FDA
bb   public    NULL   NULL   6  0xDE41BBF527C4F545AFFA0EBAE864DE40
dbo  db_owner  NULL   NULL   1  0x010500000000000515000000BE604AE3EA4BA8F3E9CE046BF4010000
--*/

--可以看到用戶aa,bb在還原后的數(shù)據(jù)庫中確實(shí)存在,但使用aa或者bb登錄時,會提示"用戶'aa'登錄失敗"
GO

--下面重新建立登錄aa,bb
EXEC sp_addlogin 'aa'
EXEC sp_addlogin 'bb'

--這次可以使用aa,bb登錄,但登錄后無法訪問測試數(shù)據(jù)庫db
GO

--將登錄設(shè)置為測試數(shù)據(jù)庫的用戶
USE db
EXEC sp_grantdbaccess 'aa'
EXEC sp_grantdbaccess 'bb'
/*--將收到錯誤信息
服務(wù)器: 消息 15023，級別 16，狀態(tài) 1，過程 sp_grantdbaccess，行 147
當(dāng)前數(shù)據(jù)庫中已存在用戶或角色 'aa'。
服務(wù)器: 消息 15023，級別 16，狀態(tài) 1，過程 sp_grantdbaccess，行 147
當(dāng)前數(shù)據(jù)庫中已存在用戶或角色 'bb'。
--*/
GO

--嘗試刪除測試數(shù)據(jù)庫中的用戶
EXEC sp_revokedbaccess 'aa'
/* 用戶aa可以正常刪除,因?yàn)橛脩鬭a在測試數(shù)據(jù)庫中沒有對象 */
EXEC sp_revokedbaccess 'bb'
/*--將收到錯誤信息
服務(wù)器: 消息 15183，級別 16，狀態(tài) 1，過程 sp_MScheck_uid_owns_anything，行 17
該用戶擁有數(shù)據(jù)庫中的對象，無法除去該用戶。
name        type
----------- -------
tb          U 
--*/

--再次授予登錄aa訪問測試數(shù)據(jù)庫的權(quán)限
EXEC sp_grantdbaccess 'aa'

--這次可以順利授權(quán),并且用aa登錄也可以正常訪問測試數(shù)據(jù)庫.


/*=================================================================*/
--解決孤立用戶bb

--1. 報告孤立用戶
USE db
EXEC sp_change_users_login 'Report'
GO


--2. 處理孤立用戶
USE db
EXEC sp_change_users_login 'Auto_Fix','bb',null,'bb'