/*--化解字符串不能超過8000的方法

	經常有人提到,用動態生成SQL語句的方法處理數據時,處理語句超長,無法處理的問題
	下面就討論這個問題:
--鄒建 2003.9(引用請保留此信息)--*/

/*-- 測試環境

--以系統表 syscolumns 為測試數據,要求按xtype為列字段,name為行字段,統計colid的和
--要求結果

xtype    filedname_1    fieldname_2    .....    fieldname_n
-------- -------------- -------------- -------- --------------
34       0              0              .....    1
--*/

/*--常規處理方法(不加行數限制會因生成的字符串益出而出錯)
set rowcount 10	--因為syscolumns的記錄較,會導致生成的字符串溢出,所以限制一下行數

declare @s nvarchar(4000)
set @s=''
select @s=@s+N','+quotename([name])
	+N'=sum(case name when '+quotename([name],'''')
	+N' then [colid] else 0 end)'
from(select distinct [name] from [syscolumns]) a

set rowcount 0	--取消限制
exec(N'select [xtype]'+@s+N' from [syscolumns] group by [xtype]')

/*--問題
	不加行數限制時,會因生成的字符串益出而出錯
--*/
--*/

/*--方法1. 多個變量處理

--根據查詢結果定義變量(實際處理中,應該是估計需要多少個變量,定義足夠多的變量個數,多定義變量并不影響處理,下面就多定義了一個)
--生成數據處理臨時表
SELECT id=IDENTITY(int,0,1),
	g=0,
	a=CAST(N','	+QUOTENAME([name])
		+N'=SUM(CASE [name] WHEN N'	+QUOTENAME(name,N'''')
		+N' THEN [colid] ELSE 0 END)'
		as nvarchar(4000))
INTO # FROM syscolumns
WHERE name>N''
GROUP BY name

--分組臨時表
UPDATE a SET G=id/i
FROM # a,(SELECT i=3800/MAX(LEN(a)) FROM #)b
SELECT MAX(g)+1 as N'需要的變量個數' FROM #

DECLARE @0 nvarchar(4000),@1 nvarchar(4000),@2 nvarchar(4000),@3 nvarchar(4000),@4 nvarchar(4000)
SELECT @0=N'',@1=N'',@2=N'',@3=N'',@4=N''
SELECT 
	@0=CASE g WHEN 0 THEN @0+a ELSE @0 END,
	@1=CASE g WHEN 1 THEN @1+a ELSE @1 END,
	@2=CASE g WHEN 2 THEN @2+a ELSE @2 END,
	@3=CASE g WHEN 3 THEN @3+a ELSE @3 END,
	@4=CASE g WHEN 4 THEN @4+a ELSE @4 END
FROM #
EXEC(N'SELECT xtype'+@0+@1+@2+@3+@4+N' FROM syscolumns GROUP BY xtype')
DROP TABLE #

/*--方法說明

優點:比較靈活,數據量大時只需要增加變量就行了.不用改動其他部分
缺點:要自行估計處理的數據,估計不足就會出錯
--*/
--*/

/*--方法2. bcp+isql

--因為要用到bcp+isql,所以需要這些信息
declare @servername sysname,@username sysname,@pwd sysname
select @servername=@@servername  --服務器名
	,@username=N''           --用戶名
	,@pwd=N''                --密碼

declare @tbname sysname,@s nvarchar(4000)

--創建數據處理臨時表
set @tbname=quotename(N'##temp_'+cast(newid() as varchar(36)))
set @s=N'create table '+@tbname+'(a nvarchar(4000))
insert into '+@tbname+N'
select N''create view '
	+stuff(@tbname,2,2,N'')
	+N' as 
select [xtype]''
union all
select N'',''+quotename([name])+''=sum(case [name] when N''
	+quotename([name],'''''''')
	+'' then [colid] else 0 end)''
	from(select distinct [name] from [syscolumns] where name<>N''xtype'')a
union all
select N''from [syscolumns] group by [xtype]'''
exec(@s)

--生成創建視圖的文件,注意使用了文件:c:\temp.txt
set @s=N'bcp "'+@tbname+N'" out "c:\'+@tbname+N'" /S"'
	+@servername+N'" /U"'+@username+N'" /P"'+@pwd+N'" /w'
exec master..xp_cmdshell @s,no_output

--調用isql生成數據處理視圖
set @s=N'osql /S"'+@servername
	+case 
		when @username=N'' then N'" /E' 
		else N'" /U"'+@username+N'" /P"'+@pwd+N'"'
	end
	+N' /d"'+db_name()+N'" /i"c:\'+@tbname+'"'
exec master..xp_cmdshell @s,no_output

--刪除臨時文件
set @s=N'del "c:\'+@tbname+'"'
exec master..xp_cmdshell @s,no_output

--調用視圖,顯示處理結果
set @s=N'drop table '+@tbname+N'
select * from '+stuff(@tbname,2,2,N'')+N'
drop view '+stuff(@tbname,2,2,N'')
exec(@s)

/*--方法總結

	優點:程序自動處理,不存在判斷錯誤的問題
	缺點:復雜,經過的步驟多,容易出錯,而且需要一定的操作員權限
--*/
--*/

--/*-- 方法3. 多個變量處理,綜合了方法1,2的優點,解決了方法1中需要人為判斷,增加變量的問題,排除了方法2,需要權限和過程復雜的問題
DECLARE @sqlhead nvarchar(4000),@sqlend nvarchar(4000)
	,@sql1 nvarchar(4000),@sql2 nvarchar(4000),@sql3 nvarchar(4000),@sql4 nvarchar(4000)
	,@i int,@ic nvarchar(10)

--生成數據處理臨時表
SELECT id=IDENTITY(int,0,1),
	g=0,
	a=CAST(N','
		+QUOTENAME([name])
		+N'=SUM(CASE [name] WHEN N'
		+QUOTENAME(name,N'''')
		+N' THEN [colid] ELSE 0 END)'
		as nvarchar(4000))
INTO # FROM(
	SELECT DISTINCT name FROM [syscolumns] WHERE name>N'')a

--分組臨時表
UPDATE a SET @i=id/i,g=@i
FROM # a,(SELECT i=3800/MAX(LEN(a)) FROM #)b
SET @ic=@i

--生成數據處理語句
SELECT 
	@sqlhead=N''''
		+REPLACE(N'SELECT [xtype]',N'''',N'''''')
		+'''',
	@sqlend=N''''
		+REPLACE(N' FROM [syscolumns] GROUP BY [xtype]',N'''',N'''''')
		+N'''',
	@sql1=N'',@sql2=N'',@sql3=N'',@sql4=N''
WHILE @ic>=0
	SELECT 
		@sql1=N',@'+@ic+N' nvarchar(4000)'+@sql1,
		@sql2=N',@'+@ic+N'=N'''''+@sql2,
		@sql3=N',@'+@ic
			+N'=CASE g WHEN '+@ic
			+N' THEN @'+@ic+N'+a ELSE @'+@ic
			+N' END'+@sql3,
		@sql4=N'+@'+@ic+@sql4,
		@ic=@ic-1
SELECT 
	@sql1=STUFF(@sql1,1,1,N''),
	@sql2=STUFF(@sql2,1,1,N''),
	@sql3=STUFF(@sql3,1,1,N''),
	@sql4=STUFF(@sql4,1,1,N'')

--執行
EXEC(N'DECLARE '+@sql1+N'
SELECT '+@sql2+N'
SELECT '+@sql3+N' FROM #
EXEC(N'+@sqlhead+N'+'+@sql4+N'+N'+@sqlend+N')')
--刪除臨時表
DROP TABLE #

/*--方法總結
	
	總結了前兩種方法的優點，自動判斷需要處理的變量數
--*/
--*/