--1．查詢區(qū)分全角與半角字符
--測試數(shù)據(jù)
DECLARE @t TABLE(col varchar(10))
INSERT @t SELECT 'aa'
UNION ALL SELECT 'Aa'
UNION ALL SELECT 'ＡＡ'  	--全角Ａ
UNION ALL SELECT 'Ａ,Ａ'		--全角Ａ,半角逗號(,)
UNION ALL SELECT 'Ａ，Ａ'	--全角Ａ,全角逗號(，)

--1.查大寫字母
SELECT * FROM @t
WHERE col COLLATE Chinese_PRC_CS_AS_WS like '%A%'

--2.查全角字母
SELECT * FROM @t
WHERE col COLLATE Chinese_PRC_CS_AS_WS like '%Ａ%'

--3.查半角逗號(,)
SELECT * FROM @t
WHERE col COLLATE Chinese_PRC_CS_AS_WS like '%,%'

--3.查全角逗號(，)
SELECT * FROM @t
WHERE col COLLATE Chinese_PRC_CS_AS_WS like '%，%'
GO


/*=============================================*/


--2 實(shí)現(xiàn)全角與半角字符轉(zhuǎn)換的處理函數(shù)
CREATE FUNCTION f_Convert(
@str NVARCHAR(4000), --要轉(zhuǎn)換的字符串
@flag bit              --轉(zhuǎn)換標(biāo)志,0轉(zhuǎn)換成半角,1轉(zhuǎn)換成全角
)RETURNS nvarchar(4000)
AS
BEGIN
	DECLARE @pat nvarchar(8),@step int,@i int,@spc int
	IF @flag=0
		SELECT @pat=N'%[！-～]%',@step=-65248,
			@str=REPLACE(@str,N'　',N' ')
	ELSE
		SELECT @pat=N'%[!-~]%',@step=65248,
			@str=REPLACE(@str,N' ',N'　')
	SET @i=PATINDEX(@pat COLLATE LATIN1_GENERAL_BIN,@str)
	WHILE @i>0
		SELECT @str=REPLACE(@str,
				SUBSTRING(@str,@i,1),
				NCHAR(UNICODE(SUBSTRING(@str,@i,1))+@step))
			,@i=PATINDEX(@pat COLLATE LATIN1_GENERAL_BIN,@str)
	RETURN(@str)
END
GO