/*--示例說明
	下面的示例演示了如何把規則綁定到列和用戶定義的數據類型
	并且演示了修改綁定于列和用戶定義的數據類型的規則時，這兩者之間的差異。
--*/
--定義數據類型
EXEC sp_addtype 'ut_age','int','null'
GO

--為ut_age定義規則
CREATE RULE r_ut_age
AS
@age between 0 and 200
GO

--將規則綁定到用戶定義的數據類型
EXEC sp_bindrule 'r_ut_age','ut_age'
GO

--使用定義的數據類型
CREATE TABLE tb(
Name nvarchar(20),
AGE_u ut_age,
AGE int)
GO

--直接將規則綁定到列
EXEC sp_bindrule 'r_ut_age','tb.AGE'
GO

--插入數據
INSERT tb VALUES('AA',10,0)
INSERT tb VALUES('BB',10,210)
/*--這條記錄違反了規則,所以會收到錯誤信息
服務器: 消息 513，級別 16，狀態 1，行 1
列的插入或更新與先前的 CREATE RULE 語句所強制的規則沖突。該語句已終止。沖突發生于數據庫 'tempdb'，表 'tb'，列 'AGE'。
--*/
GO

--創建一個新規則
CREATE RULE r_ut_age1
AS
@age between 20 and 300
GO

--將新規則綁定到列
EXEC sp_bindrule 'r_ut_age1','tb.AGE'
INSERT tb VALUES('BB',10,210)
--綁定新規則到列時,新規則在插入數據時立即生效
GO

--使用futureonly選項將新規則綁定到定義的數據類型
EXEC sp_bindrule 'r_ut_age1','ut_age',futureonly
INSERT tb VALUES('CC',10,210)
INSERT tb VALUES('DD',210,210)
SELECT * FROM tb
/*--結果
綁定新規則到定義的數據類型時,如果指定 futureonly 參數,則已經表中已經定義的列不使用新規則
所以第二條插入語句收到如何錯誤信息:
服務器: 消息 513，級別 16，狀態 1，行 1
列的插入或更新與先前的 CREATE RULE 語句所強制的規則沖突。該語句已終止。沖突發生于數據庫 'tempdb'，表 'tb'，列 'AGE_u'。

表中的現有數據為:
Name                 AGE_u       AGE         
-------------------- ----------- ----------- 
AA                   10          0
BB                   10          210
CC                   10          210
--*/
GO

--刪除定義的規則
DROP RULE r_ut_age,r_ut_age1
/*--由于規則已經綁定到用戶定義的數據類型和列,所以收到如下錯誤信息
服務器: 消息 3716，級別 16，狀態 1，行 3
無法除去 規則 'r_ut_age'，因為它綁定到了一個或多個 列 上。
服務器: 消息 3716，級別 16，狀態 1，行 3
無法除去 規則 'r_ut_age1'，因為它綁定到了一個或多個 列 上。
--*/
GO

--按順序刪除就可以了
DROP TABLE tb
EXEC sp_droptype 'ut_age'
DROP RULE r_ut_age,r_ut_age1