?? 3.asm
字號:
; *************************
; * 電子屏字符顯示器 *
; * "電子設計" *
; * 2001.10.23 *
; *************************
; 四個顯示字符數據表放在50H-6FH單元內，字符用8*8點陣，R4（30H）用于
; 控制顯示靜止字的時間，R5（31H）靜止字顯示跳轉地址步距，B內放顯示首址
;
;************;
;中斷入口程序;
;************;
;
ORG 0000H ;程序執行開始地址
LJMP START ;跳至START執行
ORG 0003H ;外中斷0中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 000BH ;定時器T0中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 0013H ;外中斷1中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 001BH ;定時器T1中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 0023H ;串行口中斷入口地址
RETI ;中斷返回（不開中斷）
ORG 002BH ;定時器T2中斷入口地址
RETI ;中斷返回（不開中斷）
;
;初始化程序
CLEARMEN: MOV A,#0FFH ;四端口置1
MOV P1,A ;
MOV P2,A ;
MOV P3,A ;
MOV P0,A ;
MOV DPTR,#TAB ;取"電子設計"字符表首址值
CLR A ;
MOV 21H,A ;21H-24H內存單元清0
MOV 22H,A ;
MOV 23H,A ;
MOV 24H,A ;
MOV R3,A ;R3寄存器清0
MOV R1,#50H ;設字符表移入內存單元首址
MOV R2,#20H ;設查表次數（32次）
CLLOOP: MOVC A,@A+DPTR ;查表將"電子設計"字符數據移入內存單元
MOV @R1,A ;
MOV A,R3 ;
INC A ;
MOV R3,A ;
INC R1 ;
DJNZ R2,CLLOOP ;查表32次，不到轉CLLOOP再查
RET ;子程序返回
;
;主體程序
START: MOV 20H,#00H ;20H內存單元清0
SETB 00H ;20H.0位置1
START1: LCALL CLEARMEN ;調用上電初始化子程序
JB 00H,FUN0 ;20H.0位為1，執行FUN0
JB 01H,FUN1 ;20H.1位為1，執行FUN1
JB 02H,FUN2 ;20H.2位為1，執行FUN2
AJMP START1 ;跳回START1循環
;
;鍵掃描子程序
KEYWORK: MOV P1,#0FFH ;置輸入狀態
JNB P1.0,KEY1 ;P1.0為0（鍵按下）轉KEY1
JNB P1.1,KEY2 ;P1.1為0（鍵按下）轉KEY2
JNB P1.2,KEY3 ;P1.2為0（鍵按下）轉KEY3
KEYRET: RET ;無鍵按下，子程序返回
;按鍵1功能處理
KEY1: LCALL DL10MS ;延時10MS削抖動
JB P1.0,KEYRET ;是干擾轉KEYRET結束
SETB 00H ;置逐字顯示方式標志（20H.0=1）
CLR 01H ;
CLR 02H ;
RET ;子程序返回
; 按鍵2功能處理
KEY2: LCALL DL10MS ;
JB P1.1,KEYRET ;
SETB 01H ;置上移顯示方式標志（20H.1=1）
CLR 00H ;
CLR 02H ;
RET ;
; 按鍵3功能處理
KEY3: LCALL DL10MS ;
JB P1.2,KEYRET ;
SETB 02H ;置左移顯示方式標志（20H.2=1）
CLR 01H ;
CLR 00H ;
RET
;
;逐字顯示功能程序
FUN0: MOV 30H,#80H ;1幀顯示時間控制（約1秒）
MOV 31H,#08H ;換幀跳轉步距為8
LJMP DISP1 ;轉顯示子程序DISP1
; 上移顯示功能程序
FUN1: MOV 30H,#0AH ;1幀顯示時間控制（約80毫秒）
MOV 31H,#01H ;換幀跳轉步距為1
LJMP DISP1 ;轉顯示子程序DISP1
;左移顯示功能程序
FUN2: LJMP DISP2 ;
;
;顯示控制程序
DISP1: MOV B,#50H ;顯示數據首址
MOV R4,30H ;放入1幀顯示時間控制數據
MOV R5,31H ;放入跳轉步距控制數據
LOOP: LCALL DISPLAY ;調用顯示子程序一次
DJNZ R4,LOOP ;1幀顯示時間未到再轉LOOP循環
MOV R4,30H ;1幀顯示時間到，重裝初值
MOV A,B ;
CJNE A,#68H,CONT ;不是末地址轉CONT
AJMP START1 ;是末地址，一次顯示結束跳回START1
CONT: ADD A,R5 ;次幀掃描首址調整
MOV B,A ;
AJMP LOOP ;轉LOOP進行次幀掃描
;
;顯示子程序，字符數據從P0口輸出，掃描控制字從P2口輸出，顯示1幀約需8MS
DISPLAY: MOV A,#0FFH ;
MOV P0,A ;關顯示數據
MOV P2,A ;關掃描
MOV R6,#0FEH ;賦掃描字
MOV R0,B ;賦顯示數據首地址
MOV R7,#08H ;一次掃描8行
DISLOOP: MOV A,@R0 ;取顯示數據
MOV P0,A ;放入P0口
MOV P2,R6 ;掃描輸出（顯示某一行）
LCALL DL1MS ;亮1毫秒
INC R0 ;指向下一行數據地址
MOV A,R6 ;掃描字移入A
RL A ;循環左移一位
MOV R6,A ;放回R6
DJNZ R7,DISLOOP ;8行掃描未完轉DISLOOP繼續
RET ;8行掃描結束
;
;左移顯示控制程序
DISP2: MOV R5,#32 ; 左移32次
DISP22: LCALL DISPP ;調用左移顯示控制子程序
LCALL MOVH ;調用高位移出處理子程序MOVH
LCALL MOVH1 ;調用高位移出處理子程序MOVH1
DJNZ R5,DISP22 ;左移顯示32次控制
LJMP START1 ;跳回主程序
;
; 左移顯示控制子程序
DISPP: MOV B,#50H ;第一顯示字符首址
MOV R4,#25H ;1幀顯示時間控制
DISPP1: LCALL DISPLAY ;調用顯示子程序一次
DJNZ R4,DISPP1 ;1幀顯示時間不到轉DISPP再循環
RET
;
; 高位移出處理子程序。將"電子設計"四個字符數據的最高位移出至21H-24H單元內
MOVH: MOV R1,#21H ;最高位移出存放單元首址
MOV R0,#50H ;"電子設計"字符數據首址
MOV R2,#08H ;每"字"移8次
MOV1: MOV A,@R0 ;取"電子設計"字符數據
CLR C ;清進位C
RLC A ;帶進位循左移
MOV @R0,A ;放回原單元
MOV A,@R1 ;存放單元數據入A
RRC A ;帶進位循右移
MOV @R1,A ;放回存放單元
INC R0 ;字符數據地址加1
DJNZ R2,MOV1 ;移8次未完轉MOV1再移
MOV R2,#08H ;8次移完賦初值
INC R1 ;存放單元地址加1
MOV A,R1 ;判斷地址是否小于25H
SUBB A,#25H ;
JZ OUT ;等于25H退出
AJMP MOV1 ;小于25H轉MOV1繼續
OUT: RET ;子程序結束
;
;高位移出處理子程序。
MOVH1: MOV A,21H ;21H與22H、23H、24H單元數據循交換
XCH A,24H ;21H與24H全交換
XCH A,23H ;23H與24H全交換
XCH A,22H ;23H與22H全交換
MOV 21H,A ;22H與21H全交換
MOV R1,#21H ;以下是重新組成顯示字符數據表程序
MOV R0,#50H ;將21H-24H的各位分別移入50H-6FH的低位
MOV R2,#08H ;移位次數
MOV2: MOV A,@R0 ;取字符數據
RR A ;右移
MOV @R0,A ;放回原單元
MOV A,@R1 ;取原移出最高位存放單元數
CLR C ;清C
RRC A ;帶進位循環右移
MOV @R1,A ;放回原單元
MOV A,@R0 ;取字符數據
RLC A ;帶進位循環左移
MOV @R0,A ;放回字符數據
INC R0 ;字符數據地址加1
DJNZ R2,MOV2 ;8次未完轉MOV2再繼續
MOV R2,#08H ;8次完賦初值
INC R1 ;原移出最高位存放單元地址加1
MOV A,R1 ;判斷地址是否小于25H
SUBB A,#25H ;
JZ OUT ;等于25H轉OUT退出
AJMP MOV2 ;小于25H轉MOV2繼續
;
;1毫秒延時子程序，采用調用掃鍵子程序延時，可快速讀出按紐的狀態
DL1MS: MOV R3,#64H ;100*（10+2）us
LOOPK: LCALL KEYWORK
DJNZ R3,LOOPK
RET
;
;0.5毫秒延時子程序
DL512: MOV R2,#0FFH
LOOP1: DJNZ R2,LOOP1
RET
;
; 10毫秒延時子程序
DL10MS: MOV R3,#14H
LOOP2: LCALL DL512
DJNZ R3,LOOP2
RET
;
;"電子設計"顯示用ROM數據表
TAB: DB 0EFH,83H,0ABH,83H,0ABH,83H,0EEH,0E0H ; 電
DB 0FFH,0C7H,0EFH,83H,0EFH,0EFH,0CFH,0EFH ; 子
DB 0B1H,0B5H,04H,0BFH,0B1H,0B5H,9BH,0A4H ; 設
DB 0BBH,0BBH,1BH,0A0H,0BBH,0BBH,9BH,0BBH ; 計
DB 00H,00H,00H,00H
END ;程序結束
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -