;********************************************************************************
;999999計數器。開機后顯示000000，一直往上累加.數碼管數據p0,數碼管控制p2口       *
;********************************************************************************
;*  日期:  2007-3-25                                                            *
;*  版本:  3.0                                                                  *
;*  作者:  深圳學林電子有限公司     專業8051單片機教學站                        *
;*  郵箱: sxj1974@163.com                                                       *
;*  網站： http://www.51c51.com     http://www.8951.com    更多例程請登陸網站   *
;********************************************************************************
;*  硬件：此程序在本公司xlisp系列單片機實驗儀運行通過                           *
;********************************************************************************
;* 【版權】 Copyright(C)深圳學林電子有限公司 www.51c51.com  All Rights Reserved *
;* 【聲明】 此程序僅用于學習與參考，引用請注明版權和作者信息！                  *
;********************************************************************************
	org 00h
	a_bit equ 30h         	;個位數存放處
	b_bit equ 31h         	;十位數存放處
	c_bit equ 32h         	;百位數存放處
	d_bit equ 33h         	;千位數存放處
	e_bit equ 34h         	;萬位數存放處
	f_bit equ 35h         	;十萬位數存放處 
	ajmp	star
	org	0030h
star:
	mov	a,#00h   	;清0
	mov	a_bit,a
	mov	b_bit,a
	mov	c_bit,a
	mov	d_bit,a
	mov	e_bit,a
	mov	f_bit,a
stlop:  acall display    	;顯示
        inc a_bit
        mov	a,a_bit  
        cjne	a,#10,stlop
        mov	a_bit,#00h
        inc b_bit
        mov	a,b_bit
        cjne	a,#10,stlop
        mov	b_bit,#00h
        inc c_bit
        mov	a,c_bit
        cjne	a,#10,stlop
        mov	c_bit,#00h
        inc d_bit
        mov	a,d_bit
        cjne	a,#10,stlop
        mov	d_bit,#00h
        inc e_bit
        mov	a,e_bit
        cjne	a,#10,stlop
        mov	e_bit,#00h
        inc f_bit
        mov	a,f_bit
        cjne	a,#10,stlop
        mov	f_bit,#00h
	ajmp	stlop

				;顯示子程序
display: 
         mov dptr,#numtab 	;指定查表啟始地址
         mov r0,#4 
dpl1:    mov r1,#250     	;顯示1000次
dplop:   mov a,a_bit     	;取個位數
         MOVC A,@A+DPTR  	;查個位數的7段代碼
         mov p0,a        	;送出個位的7段代碼
         clr p2.6        	;開個位顯示
         acall d1ms       	;顯示1ms
         setb p2.6

         mov a,b_bit 		;取十位數
         MOVC A,@A+DPTR 	;查十位數的7段代碼
         mov p0,a 		;送出十位的7段代碼
         clr p2.5 		;開十位顯示
         acall d1ms 		;顯示1ms
         setb p2.5

         mov a,c_bit 		;取百位數
         MOVC A,@A+DPTR 	;查百位數的7段代碼
         mov p0,a 		;送出百位的7段代碼
         clr p2.4 		;開百位顯示
         acall d1ms 		;顯示1ms
         setb p2.4

         mov a,d_bit 		;取千位數
         MOVC A,@A+DPTR 	;查千位數的7段代碼
         mov p0,a 		;送出千位的7段代碼
         clr p2.3 		;開千位顯示
         acall d1ms 		;顯示1ms
         setb p2.3

         mov a,e_bit 		;取萬位數
         MOVC A,@A+DPTR 	;查萬位數的7段代碼
         mov p0,a 		;送出萬位的7段代碼
         clr p2.2 		;開萬位顯示
         acall d1ms	        ;顯示1ms
         setb p2.2

         mov a,f_bit 		;取十萬位數
         MOVC A,@A+DPTR 	;查十萬位數的7段代碼
         mov p0,a 		;送出十萬位的7段代碼
         clr p2.1 		;開十萬位顯示
         acall d1ms 		;顯示1ms
         setb p2.1

         djnz r1,dplop 		;100次沒完循環
         djnz r0,dpl1 		;4個100次沒完循環
         ret
				;1MS延時(按12MHZ算)
;====================================================
D1MS: MOV R7,#2 
      DJNZ R7,$
      RET
				;7段數碼管各劃的數字排列表
numtab: db 28h,7eh,0a2h,62h,74h,61h,21h,7ah,20h,60h
;0 1 2 3 4 5 6 7 8 9
end