#/*
# * File:       flash.lcf
# * Purpose:    Linker file for the M5213EVB
# *
# * Notes:      Project running in external Flash
# *
# */

MEMORY
{
    rom     (RX) : ORIGIN = 0x00000000,  LENGTH = 0x00020000
    ram     (RW) : ORIGIN = 0x20000400,  LENGTH = 0x00003C00
}

SECTIONS 
{
    ___IPSBAR           = 0x40000000;

    ___SRAM             = 0x20000000;
    ___SRAM_SIZE        = (16 * 1024);

    ___FLASH            = 0x00000000;
    ___FLASH_SIZE       = (128 * 1024);

    ___VECTOR_RAM       = ___SRAM;
    
    .text :
    {
        .               = ALIGN(0x10);
        vectors.s (.text)
        *(.text)
        *(.rodata)
         .              = ALIGN(0x10);
        ___DATA_ROM     = .;
    } > rom

    .data_bss : AT(___DATA_ROM)
    {
        ___DATA_RAM     = .;
        *(.data)
        *(.sdata)
        ___DATA_END     = .;
        .               = ALIGN(0x10);
        ___BSS_START    = .;
        *(.sbss)
        *(SCOMMON)
        *(.bss)
        *(COMMON)
        ___BSS_END      = .;
        .               = ALIGN(0x10);
        ___HEAP_START   = .;
        .               = . + (1 * 1024);
        ___HEAP_END     = .;
        ___SP_END       = .;
        ___SP_INIT      = ___SRAM + ___SRAM_SIZE;
    } > ram
}