源程序如下：
DATA     SEGMENT 
BUFFER DB  1H,0H,3H,0H                       ;要顯示的非壓縮BCD碼
TAB    DB  3FH,06H,5BH,4FH,66H,6DH,7DH,07H   ;定義段碼表
       DB  7FH,6FH,77H,7CH ,39H,5EH,79H,71H       
DATA   ENDS
CODE   SEGMENT
ASSUME CS:CODE,DS:DATA
MAIN   PROC   FAR
START: PUSH   DS                              ;保存程序返回地址
       MOV    AX,0
       PUSH   AX
       MOV    AX,DATA
       MOV    DS,AX                           ;設置數據段寄存器
REPEAT:CALL   DISPLAY                         ;調用顯示程序
       JMP    REPEAT
       MAIN   ENDP     
DISPLAY PROC  NEAR
        MOV   AL,80H
        OUT   63H,AL                          ;初始化A,全部輸出
        MOV   AH,0F7H                         ;字位控制碼
DISP1:  LEA   SI,BUFFER                       ;設置指針
        MOV   CH,4                            ;顯示位數計數器
DISP2:  MOV   BL,[SI]                         ;取顯示字符
        AND   BX,000FH
        MOV   AL,TAB[BX]                      ;字模碼輸出到端口A
        OUT   60H,AL
        MOV   AL,AH
        OUT   62H,AL                          ;輸出字位碼 
        INC   SI                              ;調整指針準備下一個數據
        ROR   AH,1                            ;調整字位控制字
        CALL  DELAY                           ;延時
        DEC   CH                              ;全部顯示完嗎?
        JNZ   DISP2                           ;沒有顯示完,繼續顯示
        RET                                   ;顯示完,子程序返回
DISPLAY ENDP
DELAY   PROC   NEAR                           ;延時子程序
        PUSH   BX                             ;保護現場
        PUSH   CX
        MOV    BX,1                         ;可以調整BX值改變延時時間
        MOV    CX,5  
DELAY1: LOOP   DELAY1
        DEC    BX
        JNZ    DELAY1
        POP    CX                           ;恢復現場
        POP    BX
        RET
DELAY   ENDP
CODE    ENDS
        END   START