;/****************************************Copyright (c)**************************************************
;********************************************************************************************************/

;定義堆棧的大小，根據(jù)需要改變
FIQ_STACK_LEGTH     EQU         0
IRQ_STACK_LEGTH     EQU         64
ABT_STACK_LEGTH     EQU         0
UND_STACK_LEGTH     EQU         0
VICVectAddr         EQU         0xFFFFF030
NoInt       EQU 0x80


;引入的外部標(biāo)號(hào)在這聲明
        IMPORT  FIQ_Exception                   ;快速中斷異常處理程序
        IMPORT  SoftwareInterrupt               ;軟中斷入口
        IMPORT  Reset                           ;復(fù)位向量入口
        IMPORT  OSIntCtxSw                      ;中斷中任務(wù)切換函數(shù)
        IMPORT  OSIntExit                       ;中斷退出函數(shù)
        IMPORT  OSTCBCur                        ;指向當(dāng)前任務(wù)TCB的指針
        IMPORT  OSTCBHighRdy                    ;指向?qū)⒁\(yùn)行的任務(wù)TCB的指針
  
        IMPORT  OSIntNesting                    ;中斷嵌套計(jì)數(shù)器


;給外部使用的標(biāo)號(hào)在這聲明，InitStack是必須的
        EXPORT  InitStack                       
        EXPORT  Vectors


    CODE32

    AREA    StartUp,CODE,READONLY

    ENTRY
;中斷向量表
Vectors
        LDR     PC, ResetAddr
        LDR     PC, UndefinedAddr
        LDR     PC, SWI_Addr
        LDR     PC, PrefetchAddr
        LDR     PC, DataAbortAddr
        DCD     0xb9205f80
        LDR     PC, [PC, #-0xff0]
        LDR     PC, FIQ_Addr

ResetAddr           DCD     Reset
UndefinedAddr       DCD     Undefined
SWI_Addr            DCD     SoftwareInterrupt
PrefetchAddr        DCD     PrefetchAbort
DataAbortAddr       DCD     DataAbort
nouse               DCD     0
IRQ_Addr            DCD     IRQ_Handler
FIQ_Addr            DCD     FIQ_Handler


    MACRO
$IRQ_Label HANDLER $IRQ_Exception

        EXPORT  $IRQ_Label                      ; 輸出的標(biāo)號(hào)
        IMPORT  $IRQ_Exception                  ; 引用的外部標(biāo)號(hào)

$IRQ_Label
        SUB     LR, LR, #4                      ; 計(jì)算返回地址
        STMFD   SP!, {R0-R3, R12, LR}           ; 保存任務(wù)環(huán)境
        MRS     R3, SPSR                        ; 保存狀態(tài)
        STMFD   SP!, {R3}

        LDR     R2,  =OSIntNesting              ; OSIntNesting++
        LDRB    R1, [R2]
        ADD     R1, R1, #1
        STRB    R1, [R2]
        
        BL      $IRQ_Exception                  ; 調(diào)用c語(yǔ)言的中斷處理程序

        MSR     CPSR_c, #0x92
        BL      OSIntExit

        LDR     R0, =OSTCBHighRdy
        LDR     R0, [R0]
        LDR     R1, =OSTCBCur
        LDR     R1, [R1]
        CMP     R0, R1
        
        LDMFD   SP!, {R3}
        MSR     SPSR_cxsf, R3

        LDMEQFD SP!, {R0-R3, R12, PC}^          ; 不進(jìn)行任務(wù)切換
        LDR     PC, =OSIntCtxSw                 ; 進(jìn)行任務(wù)切換
    MEND

;未定義指令
Undefined
        b       Undefined

;取指令中止
PrefetchAbort
        b       PrefetchAbort

;取數(shù)據(jù)中止
DataAbort
        b       DataAbort

;中斷
IRQ_Handler	HANDLER IRQ_Exception

;快速中斷
FIQ_Handler
        STMFD   SP!, {R0-R3, LR}
        BL      FIQ_Exception
        LDMFD   SP!, {R0-R3, LR}
        SUBS    PC,  LR,  #4

;定時(shí)器0中斷
Timer0_Handler  HANDLER Timer0

;/*********************************************************************************************************
;** 函數(shù)名稱: InitStack
;** 功能描述: 初始化堆棧
;********************************************************************************************************/
InitStack    
        MOV     R0, LR
;設(shè)置中斷模式堆棧
        MSR     CPSR_c, #0xd2
        LDR     SP, StackIrq
;設(shè)置快速中斷模式堆棧
        MSR     CPSR_c, #0xd1
        LDR     SP, StackFiq
;設(shè)置中止模式堆棧
        MSR     CPSR_c, #0xd7
        LDR     SP, StackAbt
;設(shè)置未定義模式堆棧
        MSR     CPSR_c, #0xdb
        LDR     SP, StackUnd
;設(shè)置系統(tǒng)模式堆棧
        MSR     CPSR_c, #0xdf
        LDR     SP, StackIrq
        MOV     PC, R0

StackIrq           DCD     (IrqStackSpace + IRQ_STACK_LEGTH * 4 - 4)
StackFiq           DCD     (FiqStackSpace + FIQ_STACK_LEGTH * 4 - 4)
StackAbt           DCD     (AbtStackSpace + ABT_STACK_LEGTH * 4 - 4)
StackUnd           DCD     (UndtStackSpace + UND_STACK_LEGTH * 4 - 4)

;/* 分配堆棧空間 */
        AREA    MyStacks, DATA, NOINIT
IrqStackSpace      SPACE   IRQ_STACK_LEGTH * 4  ;中斷模式堆棧空間
FiqStackSpace      SPACE   FIQ_STACK_LEGTH * 4  ;快速中斷模式堆棧空間
AbtStackSpace      SPACE   ABT_STACK_LEGTH * 4  ;中止義模式堆棧空間
UndtStackSpace     SPACE   UND_STACK_LEGTH * 4  ;未定義模式堆棧




    END
;/*********************************************************************************************************
;**                            End Of File
;********************************************************************************************************/