Option Explicit

TBBS.AddLang "common|head|foot|error|register"
Call main

Private Sub doGet()
End Sub

Private Sub doPost()
    Select Case MyIO.Form("Type")
    Case "UserName"
        Call CheckUserName
    Case "Email"
        Call CheckEmail
    Case Else
        MyIO.Echo TBBS.Lang("hint_invalid_handle")
    End Select
End Sub

Private Sub CheckUserName()
    Dim ret, strUserName, strSQL
    Dim intNameMinSize, intNameMaxSize
    intNameMinSize = atoi(TBBS.Env("name_min_size"))
    intNameMaxSize = atoi(TBBS.Env("name_max_size"))
    intNameMinSize = IIf(intNameMinSize < 1 Or intNameMinSize > TBBS_NAME_SIZE, 1, intNameMinSize)
    intNameMaxSize = IIf(intNameMaxSize < 1 Or intNameMaxSize > TBBS_NAME_SIZE, TBBS_NAME_SIZE, intNameMaxSize)
    intNameMinSize = IIf(intNameMinSize > intNameMaxSize, 1, intNameMinSize)
    strUserName = Trim(MyIO.Form("Value"))
    If strUserName = "" Then
        ret = TBBS.Lang("hint_empty_username")
    ElseIf LenC(strUserName) < intNameMinSize Then
        ret = TBBS.Lang("hint_username_too_short")
    ElseIf LenC(strUserName) > intNameMaxSize Then
        ret = TBBS.Lang("hint_username_too_long")
    ElseIf Not ValidName(strUserName) Then
        ret = TBBS.Lang("hint_invalid_username")
    Else
        strSQL = MyKernel.DB.GetLimitSQL(1, "SEQID", T_USER, "USERNAME='$(UserName)'", "", "")
        strSQL = Replace(strSQL, "$(UserName)", SafeString(strUserName))
        If MyKernel.DB.HasRow(strSQL) Then
            ret = TBBS.Lang("hint_username_exists")
        Else
            ret = "OK"
        End If
    End If
    MyIO.Echo Replace(atos(ret), "[lang.username]", TBBS.Lang("username"))
End Sub

Private Sub CheckEmail()
    Dim ret, strEmail, strSQL
    strEmail = Trim(MyIO.Form("Value"))
    If strEmail = "" Then
        ret = TBBS.Lang("hint_empty_email")
    ElseIf Not ValidEmail(strEmail) Then
        ret = TBBS.Lang("hint_invalid_email")
    ElseIf Len(strEmail) > 255 Then
        ret = TBBS.Lang("hint_email_too_long")
    ElseIf TBBSBool(TBBS.Env("one_email")) = TBBS_TRUE Then
        strSQL = MyKernel.DB.GetLimitSQL(1, "SEQID", T_USER, "EMAIL='$(Email)'", "", "")
        strSQL = Replace(strSQL, "$(Email)", SafeString(strEmail))
        If MyKernel.DB.HasRow(strSQL) Then
            ret = TBBS.Lang("hint_email_exists")
        Else
            ret = "OK"
        End If
    Else
        ret = "OK"
    End If
    MyIO.Echo Replace(atos(ret), "[lang.email]", TBBS.Lang("email"))
End Sub