?? text_idct_mmx.c
字號:
#define DEFAULT_FUNCTION_NAME Fast_IDCT
#ifndef MMX_IDCT_NAME
#define MMX_IDCT_NAME DEFAULT_FUNCTION_NAME
#endif
#define int16_t short
#define int32_t int
#define uint64_t unsigned __int64
#define MPTR qword ptr
#define SHORT4_TO_QWORD(A, B, C, D) ( \
( ( ((uint64_t)(A)) & ((uint64_t)(0xffff)) ) << 0 ) | \
( ( ((uint64_t)(B)) & ((uint64_t)(0xffff)) ) << 16 ) | \
( ( ((uint64_t)(C)) & ((uint64_t)(0xffff)) ) << 32 ) | \
( ( ((uint64_t)(D)) & ((uint64_t)(0xffff)) ) << 48 ) )
#define INT2_TO_QWORD(A, B) ( \
( ( ((uint64_t)(A)) & ((uint64_t)(0xffffffff)) ) << 0 ) | \
( ( ((uint64_t)(B)) & ((uint64_t)(0xffffffff)) ) << 32 ) )
#define BITS_INV_ACC 5
#define SHIFT_INV_ROW (16 - BITS_INV_ACC)
#define SHIFT_INV_COL (1 + BITS_INV_ACC)
#define RND_INV_ROW (1024 * (6 - BITS_INV_ACC))
#define RND_INV_COL (16 * (BITS_INV_ACC - 3))
#define RND_INV_CORR (RND_INV_COL - 1)
#define BITS_FRW_ACC 3
#define SHIFT_FRW_COL BITS_FRW_ACC
#define SHIFT_FRW_ROW (BITS_FRW_ACC + 17)
#define RND_FRW_ROW (262144 * (BITS_FRW_ACC - 1))
static const uint64_t tg_1_16 = SHORT4_TO_QWORD( 13036, 13036, 13036, 13036 );
static const uint64_t tg_2_16 = SHORT4_TO_QWORD( 27146, 27146, 27146, 27146 );
static const uint64_t tg_3_16 = SHORT4_TO_QWORD(-21746, -21746, -21746, -21746 );
static const uint64_t ocos_4_16 = SHORT4_TO_QWORD( 23170, 23170, 23170, 23170 );
#if SHIFT_INV_ROW == 12
static const uint64_t rounder[8] = {
INT2_TO_QWORD( 65536, 65536),
INT2_TO_QWORD( 7195, 7195),
INT2_TO_QWORD( 4520, 4520),
INT2_TO_QWORD( 2407, 2407),
INT2_TO_QWORD( 0, 0),
INT2_TO_QWORD( 240, 240),
INT2_TO_QWORD( 1024, 1024),
INT2_TO_QWORD( 1024, 1024)
};
#elif SHIFT_INV_ROW == 11
static const uint64_t rounder[2*8] = {
INT2_TO_QWORD( 65536, 65536),
INT2_TO_QWORD( 3597, 3597),
INT2_TO_QWORD( 2260, 2260),
INT2_TO_QWORD( 1203, 1203),
INT2_TO_QWORD( 0, 0),
INT2_TO_QWORD( 120, 120),
INT2_TO_QWORD( 512, 512),
INT2_TO_QWORD( 512, 512)
};
#endif
static const uint64_t tab_i_04[8*8] = {
SHORT4_TO_QWORD( 16384, 16384, 16384, -16384 ),
SHORT4_TO_QWORD( 21407, 8867, 8867, -21407 ),
SHORT4_TO_QWORD( 16384, -16384, 16384, 16384 ),
SHORT4_TO_QWORD( -8867, 21407, -21407, -8867 ),
SHORT4_TO_QWORD( 22725, 12873, 19266, -22725 ),
SHORT4_TO_QWORD( 19266, 4520, -4520, -12873 ),
SHORT4_TO_QWORD( 12873, 4520, 4520, 19266 ),
SHORT4_TO_QWORD(-22725, 19266, -12873, -22725 ),
SHORT4_TO_QWORD( 22725, 22725, 22725, -22725 ),
SHORT4_TO_QWORD( 29692, 12299, 12299, -29692 ),
SHORT4_TO_QWORD( 22725, -22725, 22725, 22725 ),
SHORT4_TO_QWORD(-12299, 29692, -29692, -12299 ),
SHORT4_TO_QWORD( 31521, 17855, 26722, -31521 ),
SHORT4_TO_QWORD( 26722, 6270, -6270, -17855 ),
SHORT4_TO_QWORD( 17855, 6270, 6270, 26722 ),
SHORT4_TO_QWORD(-31521, 26722, -17855, -31521 ),
SHORT4_TO_QWORD( 21407, 21407, 21407, -21407 ),
SHORT4_TO_QWORD( 27969, 11585, 11585, -27969 ),
SHORT4_TO_QWORD( 21407, -21407, 21407, 21407 ),
SHORT4_TO_QWORD(-11585, 27969, -27969, -11585 ),
SHORT4_TO_QWORD( 29692, 16819, 25172, -29692 ),
SHORT4_TO_QWORD( 25172, 5906, -5906, -16819 ),
SHORT4_TO_QWORD( 16819, 5906, 5906, 25172 ),
SHORT4_TO_QWORD(-29692, 25172, -16819, -29692 ),
SHORT4_TO_QWORD( 19266, 19266, 19266, -19266 ),
SHORT4_TO_QWORD( 25172, 10426, 10426, -25172 ),
SHORT4_TO_QWORD( 19266, -19266, 19266, 19266 ),
SHORT4_TO_QWORD(-10426, 25172, -25172, -10426 ),
SHORT4_TO_QWORD( 26722, 15137, 22654, -26722 ),
SHORT4_TO_QWORD( 22654, 5315, -5315, -15137 ),
SHORT4_TO_QWORD( 15137, 5315, 5315, 22654 ),
SHORT4_TO_QWORD(-26722, 22654, -15137, -26722 ),
SHORT4_TO_QWORD( 16384, 16384, 16384, -16384 ),
SHORT4_TO_QWORD( 21407, 8867, 8867, -21407 ),
SHORT4_TO_QWORD( 16384, -16384, 16384, 16384 ),
SHORT4_TO_QWORD(-8867, 21407, -21407, -8867 ),
SHORT4_TO_QWORD( 22725, 12873, 19266, -22725 ),
SHORT4_TO_QWORD( 19266, 4520, -4520, -12873 ),
SHORT4_TO_QWORD( 12873, 4520, 4520, 19266 ),
SHORT4_TO_QWORD(-22725, 19266, -12873, -22725 ),
SHORT4_TO_QWORD( 19266, 19266, 19266, -19266 ),
SHORT4_TO_QWORD( 25172, 10426, 10426, -25172 ),
SHORT4_TO_QWORD( 19266, -19266, 19266, 19266 ),
SHORT4_TO_QWORD(-10426, 25172, -25172, -10426 ),
SHORT4_TO_QWORD( 26722, 15137, 22654, -26722 ),
SHORT4_TO_QWORD( 22654, 5315, -5315, -15137 ),
SHORT4_TO_QWORD( 15137, 5315, 5315, 22654 ),
SHORT4_TO_QWORD(-26722, 22654, -15137, -26722 ),
SHORT4_TO_QWORD( 21407, 21407, 21407, -21407 ),
SHORT4_TO_QWORD( 27969, 11585, 11585, -27969 ),
SHORT4_TO_QWORD( 21407, -21407, 21407, 21407 ),
SHORT4_TO_QWORD(-11585, 27969, -27969, -11585 ),
SHORT4_TO_QWORD( 29692, 16819, 25172, -29692 ),
SHORT4_TO_QWORD( 25172, 5906, -5906, -16819 ),
SHORT4_TO_QWORD( 16819, 5906, 5906, 25172 ),
SHORT4_TO_QWORD(-29692, 25172, -16819, -29692 ),
SHORT4_TO_QWORD( 22725, 22725, 22725, -22725 ),
SHORT4_TO_QWORD( 29692, 12299, 12299, -29692 ),
SHORT4_TO_QWORD( 22725, -22725, 22725, 22725 ),
SHORT4_TO_QWORD(-12299, 29692, -29692, -12299 ),
SHORT4_TO_QWORD( 31521, 17855, 26722, -31521 ),
SHORT4_TO_QWORD( 26722, 6270, -6270, -17855 ),
SHORT4_TO_QWORD( 17855, 6270, 6270, 26722 ),
SHORT4_TO_QWORD(-31521, 26722, -17855, -31521 ),
};
uint64_t tempMatrix[64/4];
#define INP eax
#define ROUNDER ebx
#define TABLE ecx
#define OUTP edx
void MMX_IDCT_NAME
(int16_t *block) {
__asm {
push eax
push ebx
push ecx
push edx
push edi
mov INP, block
lea OUTP, [tempMatrix]
lea TABLE, [tab_i_04]
lea ROUNDER, [rounder]
mov edi, -8; ; i=-8
align 16
rowloop:
movq mm0, MPTR [INP] ; 0 ; x3 x2 x1 x0
movq mm1, MPTR [INP+8] ; 1 ; x7 x6 x5 x4
movq mm2, mm0 ; 2 ; x3 x2 x1 x0
movq mm3, MPTR [TABLE] ; 3 ; w06 w04 w02 w00
punpcklwd mm0, mm1 ; x5 x1 x4 x0
movq mm5, mm0 ; 5 ; x5 x1 x4 x0
punpckldq mm0, mm0 ; x4 x0 x4 x0
movq mm4, MPTR [TABLE+8] ; 4 ; w07 w05 w03 w01
punpckhwd mm2, mm1 ; 1 ; x7 x3 x6 x2
pmaddwd mm3, mm0 ; x4*w06+x0*w04 x4*w02+x0*w00
movq mm6, mm2 ; 6 ; x7 x3 x6 x2
movq mm1, MPTR [TABLE+32] ; 1 ; w22 w20 w18 w16
punpckldq mm2, mm2 ; x6 x2 x6 x2
pmaddwd mm4, mm2 ; x6*w07+x2*w05 x6*w03+x2*w01
punpckhdq mm5, mm5 ; x5 x1 x5 x1
pmaddwd mm0, MPTR [TABLE+16] ; x4*w14+x0*w12 x4*w10+x0*w08
punpckhdq mm6, mm6 ; x7 x3 x7 x3
movq mm7, MPTR [TABLE+40] ; 7 ; w23 w21 w19 w17
pmaddwd mm1, mm5 ; x5*w22+x1*w20 x5*w18+x1*w16
paddd mm3, MPTR [ROUNDER] ; +rounder
pmaddwd mm7, mm6 ; x7*w23+x3*w21 x7*w19+x3*w17
pmaddwd mm2, MPTR [TABLE+24] ; x6*w15+x2*w13 x6*w11+x2*w09
paddd mm3, mm4 ; 4 ; a1=sum(even1) a0=sum(even0)
pmaddwd mm5, MPTR [TABLE+48] ; x5*w30+x1*w28 x5*w26+x1*w24
movq mm4, mm3 ; 4 ; a1 a0
pmaddwd mm6, MPTR [TABLE+56] ; x7*w31+x3*w29 x7*w27+x3*w25
paddd mm1, mm7 ; 7 ; b1=sum(odd1) b0=sum(odd0)
paddd mm0, MPTR [ROUNDER] ; +rounder
psubd mm3, mm1 ; a1-b1 a0-b0
psrad mm3, SHIFT_INV_ROW ; y6=a1-b1 y7=a0-b0
paddd mm1, mm4 ; 4 ; a1+b1 a0+b0
paddd mm0, mm2 ; 2 ; a3=sum(even3) a2=sum(even2)
psrad mm1, SHIFT_INV_ROW ; y1=a1+b1 y0=a0+b0
paddd mm5, mm6 ; 6 ; b3=sum(odd3) b2=sum(odd2)
movq mm4, mm0 ; 4 ; a3 a2
paddd mm0, mm5 ; a3+b3 a2+b2
psubd mm4, mm5 ; 5 ; a3-b3 a2-b2
psrad mm0, SHIFT_INV_ROW ; y3=a3+b3 y2=a2+b2
psrad mm4, SHIFT_INV_ROW ; y4=a3-b3 y5=a2-b2
packssdw mm1, mm0 ; 0 ; y3 y2 y1 y0
packssdw mm4, mm3 ; 3 ; y6 y7 y4 y5
movq mm7, mm4 ; 7 ; y6 y7 y4 y5
psrld mm4, 16 ; 0 y6 0 y4
pslld mm7, 16 ; y7 0 y5 0
movq MPTR [OUTP], mm1 ; 1 ; save y3 y2 y1 y0
por mm7, mm4 ; 4 ; y7 y6 y5 y4
movq MPTR [OUTP+8], mm7 ; 7 ; save y7 y6 y5 y4
add INP, 16 ; add 1 row to input pointer
add ROUNDER, 8 ; go to next rounding values
add OUTP, 16 ; add 1 row to output pointer
add TABLE,64 ; move to next section of table
add edi, 1
jne rowloop;
lea INP, [tempMatrix]
mov OUTP, block
mov edi, -2; ; i=-2
align 16
colloop:
movq mm0, tg_3_16
movq mm3, MPTR [INP+16*3]
movq mm1, mm0 ; tg_3_16
movq mm5, MPTR [INP+16*5]
pmulhw mm0, mm3 ; x3*(tg_3_16-1)
movq mm4, tg_1_16
pmulhw mm1, mm5 ; x5*(tg_3_16-1)
movq mm7, MPTR [INP+16*7]
movq mm2, mm4 ; tg_1_16
movq mm6, MPTR [INP+16*1]
pmulhw mm4, mm7 ; x7*tg_1_16
paddsw mm0, mm3 ; x3*tg_3_16
pmulhw mm2, mm6 ; x1*tg_1_16
paddsw mm1, mm3 ; x3+x5*(tg_3_16-1)
psubsw mm0, mm5 ; x3*tg_3_16-x5 = tm35
movq mm3, ocos_4_16
paddsw mm1, mm5 ; x3+x5*tg_3_16 = tp35
paddsw mm4, mm6 ; x1+tg_1_16*x7 = tp17
psubsw mm2, mm7 ; x1*tg_1_16-x7 = tm17
movq mm5, mm4 ; tp17
movq mm6, mm2 ; tm17
paddsw mm5, mm1 ; tp17+tp35 = b0
psubsw mm6, mm0 ; tm17-tm35 = b3
psubsw mm4, mm1 ; tp17-tp35 = t1
paddsw mm2, mm0 ; tm17+tm35 = t2
movq mm7, tg_2_16
movq mm1, mm4 ; t1
; movq MPTR [SCRATCH+0], mm5 ; save b0
movq MPTR [OUTP+3*16], mm5 ; save b0
paddsw mm1, mm2 ; t1+t2
; movq MPTR [SCRATCH+8], mm6 ; save b3
movq MPTR [OUTP+5*16], mm6 ; save b3
psubsw mm4, mm2 ; t1-t2
movq mm5, MPTR [INP+2*16]
movq mm0, mm7 ; tg_2_16
movq mm6, MPTR [INP+6*16]
pmulhw mm0, mm5 ; x2*tg_2_16
pmulhw mm7, mm6 ; x6*tg_2_16
; slot
pmulhw mm1, mm3 ; ocos_4_16*(t1+t2) = b1/2
; slot
movq mm2, MPTR [INP+0*16]
pmulhw mm4, mm3 ; ocos_4_16*(t1-t2) = b2/2
psubsw mm0, mm6 ; t2*tg_2_16-x6 = tm26
movq mm3, mm2 ; x0
movq mm6, MPTR [INP+4*16]
paddsw mm7, mm5 ; x2+x6*tg_2_16 = tp26
paddsw mm2, mm6 ; x0+x4 = tp04
psubsw mm3, mm6 ; x0-x4 = tm04
movq mm5, mm2 ; tp04
movq mm6, mm3 ; tm04
psubsw mm2, mm7 ; tp04-tp26 = a3
paddsw mm3, mm0 ; tm04+tm26 = a1
paddsw mm1, mm1 ; b1
paddsw mm4, mm4 ; b2
paddsw mm5, mm7 ; tp04+tp26 = a0
psubsw mm6, mm0 ; tm04-tm26 = a2
movq mm7, mm3 ; a1
movq mm0, mm6 ; a2
paddsw mm3, mm1 ; a1+b1
paddsw mm6, mm4 ; a2+b2
psraw mm3, SHIFT_INV_COL ; dst1
psubsw mm7, mm1 ; a1-b1
psraw mm6, SHIFT_INV_COL ; dst2
psubsw mm0, mm4 ; a2-b2
; movq mm1, MPTR [SCRATCH+0] ; load b0
movq mm1, MPTR [OUTP+3*16] ; load b0
psraw mm7, SHIFT_INV_COL ; dst6
movq mm4, mm5 ; a0
psraw mm0, SHIFT_INV_COL ; dst5
movq MPTR [OUTP+1*16], mm3
paddsw mm5, mm1 ; a0+b0
movq MPTR [OUTP+2*16], mm6
psubsw mm4, mm1 ; a0-b0
; movq mm3, MPTR [SCRATCH+8] ; load b3
movq mm3, MPTR [OUTP+5*16] ; load b3
psraw mm5, SHIFT_INV_COL ; dst0
movq mm6, mm2 ; a3
psraw mm4, SHIFT_INV_COL ; dst7
movq MPTR [OUTP+5*16], mm0
paddsw mm2, mm3 ; a3+b3
movq MPTR [OUTP+6*16], mm7
psubsw mm6, mm3 ; a3-b3
movq MPTR [OUTP+0*16], mm5
psraw mm2, SHIFT_INV_COL ; dst3
movq MPTR [OUTP+7*16], mm4
psraw mm6, SHIFT_INV_COL ; dst4
movq MPTR [OUTP+3*16], mm2
movq MPTR [OUTP+4*16], mm6
lea INP, [tempMatrix]
mov OUTP, block
add INP, 8 ; add 4 cols to input pointer
add OUTP, 8 ; add 4 cols to output pointer
add edi, 1
jne colloop
pop edi
pop edx
pop ecx
pop ebx
pop eax
emms
};
};
?? 快捷鍵說明
復制代碼
Ctrl + C
搜索代碼
Ctrl + F
全屏模式
F11
切換主題
Ctrl + Shift + D
顯示快捷鍵
?
增大字號
Ctrl + =
減小字號
Ctrl + -