;/* 這是被CALL7705.C調用的AD7705匯編程序，文件名為AD7705A.ASM      */
;/* 功能：本程序主要是讀出AD7705芯片輸入通道CH0(或CH1)的模數轉換   */
;/*    值,轉換值放在寄存器R6,R7中,R6放高位。AD7705芯片的2個通道    */
;/*    可編程為單極性/雙極性和差動/單端工作, 這里采用單端\單極性   */
;/*    輸入。本例中AD7705連接的晶振為4MHZ,參考電壓為5V，選擇通道   */
;/*    增益為1，采用自校準方式 。                                  */

   NAME AD7705A
   ?PR?_a_func?AD7705A     SEGMENT CODE
   ?DT?_a_func?AD7705A     SEGMENT DATA OVERLAYABLE
   ?DT?AD7705A             SEGMENT DATA

   PUBLIC   chai
   PUBLIC   ?_a_func?BYTE
   PUBLIC    _a_func
   RSEG  ?DT?_a_func?AD7705A
	 ?_a_func?BYTE:
	 data_addr:DS 2
   RSEG  ?DT?AD7705A
	 chai:     DS 2
   RSEG  ?PR?_a_func?AD7705A
	 _a_func:
DRDY             BIT  P1.3
CS               BIT  P1.4
SO               BIT  P1.5
SCK              BIT  P1.6
SI               BIT  P1.7

     MOV data_addr,R7   ;R6和R7中放傳遞進來的整型參數
     MOV data_addr+1,R6

     MOV A,data_addr+1 ;AD7705初始化
    ; MOV A,#20H;
     LCALL WRADC
     MOV A,#04H;
     LCALL WRADC
     MOV A,data_addr
    ; MOV A,#10H;
     LCALL WRADC
     MOV A,#44H;#4CH，#54H
     LCALL WRADC
     JB DRDY,$      ;等待DRDY變低
     MOV A,#38H
     LCALL WRADC
     LCALL RDADC
     MOV R7,A       ;R7中放返回轉換值低8位
     MOV A,B
     MOV R6,A       ;R6中放返回轉換值高8位。
     RET

WRADC:             ;寫一個字節子程序
     NOP
     SETB SCK
     CLR CS
     MOV R0,#08H
WRADC1:
     CLR SCK
     RLC A
     MOV SI,C
     SETB SCK
     DJNZ R0,WRADC1
     CLR SI
     SETB CS
     RET
RDADC:            ;讀轉換數據子程序
     NOP
     JB DRDY,$    ;等待DRDY變低
     CLR CS
     MOV R0,#08H
RDADC1:
     SETB SCK
     CLR SCK
     MOV C,SO
     RLC A
     DJNZ R0,RDADC1
     MOV B,A     ;高字節在寄存器B中
     MOV R0,#08H
RDADC2:
     SETB SCK
     CLR SCK
     MOV C,SO
     RLC A       ;低字節在寄存器A中
     DJNZ R0,RDADC2
     SETB CS
     RET
     END